실행 그룹

문제 신고 소스 보기

실행 그룹을 사용하면 단일 대상 내에서 여러 실행 플랫폼을 사용할 수 있습니다. 각 실행 그룹에는 자체 도구 모음 종속 항목이 있으며 자체 도구 모음 확인을 수행합니다.

배경

실행 그룹을 사용하면 규칙 작성자가 각각 다른 실행 플랫폼을 가진 작업 세트를 정의할 수 있습니다. 여러 실행 플랫폼에서는 작업을 다르게 실행할 수 있습니다. 예를 들어 원격(Linux) 작업자에서 iOS 앱을 컴파일한 후 로컬 Mac worker에서 링크/코드 서명하는 경우를 예로 들 수 있습니다.

작업 그룹을 정의할 수 있으면 작업 지정을 위한 프록시로 작업 연상 기호를 사용하는 경감도 줄어듭니다. 니모닉은 고유하지 않을 수 있으며 단일 작업만 참조할 수 있습니다. 이 기능은 특히 추가 리소스를 특정 메모리에 할당하고 덜 까다로운 작업에 과도하게 할당하지 않고 C++ 빌드에서 연결과 같은 집약적인 작업을 처리하는 데 유용합니다.

실행 그룹 정의

규칙을 정의하는 동안 규칙 작성자는 실행 그룹 집합을 선언할 수 있습니다. 각 실행 그룹에서 규칙 작성자는 실행 그룹의 실행 플랫폼을 선택하는 데 필요한 모든 항목, 즉 exec_compatible_with를 통한 제약 조건과 toolchain를 통한 도구 모음 유형을 지정할 수 있습니다.

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        “link”: exec_group(
            exec_compatible_with = [ "@platforms//os:linux" ]
            toolchains = ["//foo:toolchain_type"],
        ),
        “test”: exec_group(
            toolchains = ["//foo_tools:toolchain_type"],
        ),
    },
    attrs = {
        "_compiler": attr.label(cfg = config.exec("link"))
    },
)

위의 코드 스니펫에서 도구 종속 항목이 cfg 속성 매개변수와 config 모듈을 사용하여 exec 그룹의 전환을 지정할 수도 있음을 알 수 있습니다. 모듈은 종속 항목이 빌드되어야 하는 exec 그룹의 이름인 단일 문자열 매개변수를 사용하는 exec 함수를 노출합니다.

네이티브 규칙과 마찬가지로 Starlark 테스트 규칙에는 test 실행 그룹이 기본적으로 있습니다.

실행 그룹 액세스

규칙 구현에서 작업이 실행 그룹의 실행 플랫폼에서 실행되어야 한다고 선언할 수 있습니다. 이렇게 하려면 작업 생성 메서드의 exec_group 매개변수, 특히 ctx.actions.runctx.actions.run_shell를 사용하면 됩니다.

# foo.bzl
def _impl(ctx):
  ctx.actions.run(
     inputs = [ctx.attr._some_tool, ctx.srcs[0]]
     exec_group = "compile",
     # ...
  )

규칙 작성자는 대상의 확인된 도구 모음에 액세스하는 방법과 마찬가지로 실행 그룹의 확인된 도구 모음에 액세스할 수도 있습니다.

# foo.bzl
def _impl(ctx):
  foo_info = ctx.exec_groups["link"].toolchains["//foo:toolchain_type"].fooinfo
  ctx.actions.run(
     inputs = [foo_info, ctx.srcs[0]]
     exec_group = "link",
     # ...
  )

실행 그룹을 사용하여 실행 속성 설정

실행 그룹은 모든 규칙에 있는 exec_properties 속성과 통합되며, 타겟 작성자가 속성의 문자열 사전을 지정한 후 실행 기계로 전달할 수 있습니다. 예를 들어 타겟에 메모리와 같은 일부 속성을 설정하고 특정 작업에 더 높은 메모리 할당을 부여하려면 다음과 같이 실행 그룹 보강 키를 사용하여 exec_properties 항목을 작성하세요.

# BUILD
my_rule(
    name = 'my_target',
    exec_properties = {
        'mem': '12g',
        'link.mem': '16g'
    }
    …
)

exec_group = "link"가 있는 모든 작업은 exec 속성 사전을 {"mem": "16g"}로 보게 됩니다. 여기에서 볼 수 있듯이 실행 그룹 수준 설정이 대상 수준 설정을 재정의합니다.

기본 규칙의 실행 그룹

기본 규칙에서 정의한 작업에는 다음 실행 그룹을 사용할 수 있습니다.

  • test: 테스트 실행기 작업입니다.
  • cpp_link: C++ 연결 작업입니다.

실행 그룹 및 플랫폼 실행 속성

알 수 없는 실행 그룹의 속성이 거부되는 타겟에 직접 설정된 exec_properties와 달리 플랫폼 타겟의 임의 실행 그룹에 exec_properties를 정의할 수 있습니다. 그러면 대상은 기본 실행 그룹 및 기타 관련 실행 그룹에 영향을 미치는 실행 플랫폼의 exec_properties를 상속합니다.

예를 들어 C++ 테스트를 실행하려면 사용할 수 있는 리소스가 필요하지만 컴파일 및 링크에는 필요하지 않은 경우 다음과 같이 모델링할 수 있습니다.

constraint_setting(name = "resource")
constraint_value(name = "has_resource", constraint_setting = ":resource")

platform(
    name = "platform_with_resource",
    constraint_values = [":has_resource"],
    exec_properties = {
        "test.resource": "...",
    },
)

cc_test(
    name = "my_test",
    srcs = ["my_test.cc"],
    exec_compatible_with = [":has_resource"],
)

타겟에 직접 정의된 exec_properties은 실행 플랫폼에서 상속된 것보다 우선합니다.