Android 규칙

규칙

• android_binary
• aar_import
• android_library
• android_ instrumentation_test
• android_local_test
• android_device
• android_ndk_repository
• android_sdk_repository

android_binary

android_binary(name, deps, srcs, assets, assets_dir, compatible_with, crunch_png, custom_package, debug_key, debug_signing_keys, debug_signing_lineage_file, densities, deprecation, dex_shards, dexopts, distribs, enable_data_binding, exec_compatible_with, exec_properties, features, incremental_dexing, instruments, javacopts, key_rotation_min_sdk, licenses, main_dex_list, main_dex_list_opts, main_dex_proguard_specs, manifest, manifest_values, multidex, nocompress_extensions, package_id, plugins, proguard_apply_dictionary, proguard_apply_mapping, proguard_generate_mapping, proguard_specs, resource_configuration_filters, resource_files, restricted_to, shrink_resources, tags, target_compatible_with, testonly, visibility)

Android 애플리케이션 패키지 파일 (.apk)을 생성합니다.

암시적 출력 타겟

• name.apk: 디버그 키로 서명되고 zipaligned인 Android 애플리케이션 패키지 파일로, 애플리케이션을 개발하고 디버그하는 데 사용할 수 있습니다. 디버그 키로 서명한 경우 애플리케이션을 출시할 수 없습니다.
• name_unsigned.apk: 출시 전 서명 키로 공개될 수 있는 위 파일의 서명되지 않은 버전입니다.
• name_deploy.jar: 이 타겟의 전이적 클로저가 포함된 자바 보관 파일입니다.

  배포 jar에는 이 대상의 런타임 클래스 경로를 처음부터 끝까지 검색한 클래스 로더가 찾을 수 있는 모든 클래스가 포함되어 있습니다.

• name_proguard.jar: name_deploy.jar에서 ProGuard를 실행한 결과를 포함하는 자바 보관 파일입니다. 이 출력은 proguard_specs 속성이 지정된 경우에만 생성됩니다.
• name_proguard.map: name_deploy.jar에서 ProGuard를 실행한 매핑 파일 결과입니다. 이 출력은 proguard_specs 속성이 지정되고 proguard_generate_mapping 또는 shrink_resources가 설정된 경우에만 생성됩니다.

예

Android 규칙의 예는 Bazel 소스 트리의 examples/android 디렉터리에서 찾을 수 있습니다.

인수

          android/support/multidex/MultiDex$V19.class
          android/support/multidex/MultiDex.class
          android/support/multidex/MultiDexApplication.class
          com/google/common/base/Objects.class
                    

aar_import

aar_import(name, deps, data, aar, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, exports, features, licenses, restricted_to, srcjar, tags, target_compatible_with, testonly, visibility)

이 규칙은 .aar 파일을 android_library 및 android_binary 규칙의 라이브러리로 사용하도록 허용합니다.

예

    aar_import(
        name = "google-vr-sdk",
        aar = "gvr-android-sdk/libraries/sdk-common-1.10.0.aar",
    )

    android_binary(
        name = "app",
        manifest = "AndroidManifest.xml",
        srcs = glob(["**.java"]),
        deps = [":google-vr-sdk"],
    )

인수

Android 라이브러리

android_library(name, deps, srcs, data, assets, assets_dir, compatible_with, custom_package, deprecation, distribs, enable_data_binding, exec_compatible_with, exec_properties, exported_plugins, exports, exports_manifest, features, idl_import_root, idl_parcelables, idl_preprocessed, idl_srcs, javacopts, licenses, manifest, neverlink, plugins, proguard_specs, resource_files, restricted_to, tags, target_compatible_with, testonly, visibility)

이 규칙은 소스를 컴파일하여 .jar 파일로 보관처리합니다. Android 런타임 라이브러리 android.jar는 컴파일 클래스 경로에 암시적으로 배치됩니다.

암시적 출력 타겟

• libname.jar: 자바 보관 파일입니다.
• libname-src.jar: 소스가 포함된 보관 파일('소스 jar')
• name.aar: 이 타겟의 자바 보관 파일 및 리소스가 포함된 Android 'aar' 번들입니다. 임시 휴업은 포함되어 있지 않습니다.

예

Android 규칙의 예는 Bazel 소스 트리의 examples/android 디렉터리에서 찾을 수 있습니다.

다음 예는 idl_import_root를 설정하는 방법을 보여줍니다. //java/bazel/helloandroid/BUILD에 다음을 포함합니다.

android_library(
    name = "parcelable",
    srcs = ["MyParcelable.java"], # bazel.helloandroid.MyParcelable

    # MyParcelable.aidl will be used as import for other .aidl
    # files that depend on it, but will not be compiled.
    idl_parcelables = ["MyParcelable.aidl"] # bazel.helloandroid.MyParcelable

    # We don't need to specify idl_import_root since the aidl file
    # which declares bazel.helloandroid.MyParcelable
    # is present at java/bazel/helloandroid/MyParcelable.aidl
    # underneath a java root (java/).
)

android_library(
    name = "foreign_parcelable",
    srcs = ["src/android/helloandroid/OtherParcelable.java"], # android.helloandroid.OtherParcelable
    idl_parcelables = [
        "src/android/helloandroid/OtherParcelable.aidl" # android.helloandroid.OtherParcelable
    ],

    # We need to specify idl_import_root because the aidl file which
    # declares android.helloandroid.OtherParcelable is not positioned
    # at android/helloandroid/OtherParcelable.aidl under a normal java root.
    # Setting idl_import_root to "src" in //java/bazel/helloandroid
    # adds java/bazel/helloandroid/src to the list of roots
    # the aidl compiler will search for imported types.
    idl_import_root = "src",
)

# Here, OtherInterface.aidl has an "import android.helloandroid.CallbackInterface;" statement.
android_library(
    name = "foreign_interface",
    idl_srcs = [
        "src/android/helloandroid/OtherInterface.aidl" # android.helloandroid.OtherInterface
        "src/android/helloandroid/CallbackInterface.aidl" # android.helloandroid.CallbackInterface
    ],

    # As above, idl_srcs which are not correctly positioned under a java root
    # must have idl_import_root set. Otherwise, OtherInterface (or any other
    # interface in a library which depends on this one) will not be able
    # to find CallbackInterface when it is imported.
    idl_import_root = "src",
)

# MyParcelable.aidl is imported by MyInterface.aidl, so the generated
# MyInterface.java requires MyParcelable.class at compile time.
# Depending on :parcelable ensures that aidl compilation of MyInterface.aidl
# specifies the correct import roots and can access MyParcelable.aidl, and
# makes MyParcelable.class available to Java compilation of MyInterface.java
# as usual.
android_library(
    name = "idl",
    idl_srcs = ["MyInterface.aidl"],
    deps = [":parcelable"],
)

# Here, ServiceParcelable uses and thus depends on ParcelableService,
# when it's compiled, but ParcelableService also uses ServiceParcelable,
# which creates a circular dependency.
# As a result, these files must be compiled together, in the same android_library.
android_library(
    name = "circular_dependencies",
    srcs = ["ServiceParcelable.java"],
    idl_srcs = ["ParcelableService.aidl"],
    idl_parcelables = ["ServiceParcelable.aidl"],
)

인수

Android_계측_테스트

android_instrumentation_test(name, data, args, compatible_with, deprecation, distribs, env, env_inherit, exec_compatible_with, exec_properties, features, flaky, licenses, local, restricted_to, shard_count, size, support_apks, tags, target_compatible_with, target_device, test_app, testonly, timeout, toolchains, visibility)

android_instrumentation_test 규칙은 Android 계측 테스트를 실행합니다. 에뮬레이터를 시작하고 테스트 중인 애플리케이션, 테스트 애플리케이션, 기타 필요한 애플리케이션을 설치하고 테스트 패키지에 정의된 테스트를 실행합니다.

test_app 속성은 테스트가 포함된 android_binary를 지정합니다. 이 android_binary는 계측 속성을 통해 테스트 중인 android_binary 애플리케이션을 지정합니다.

예

# java/com/samples/hello_world/BUILD

android_library(
    name = "hello_world_lib",
    srcs = ["Lib.java"],
    manifest = "LibraryManifest.xml",
    resource_files = glob(["res/**"]),
)

# The app under test
android_binary(
    name = "hello_world_app",
    manifest = "AndroidManifest.xml",
    deps = [":hello_world_lib"],
)

# javatests/com/samples/hello_world/BUILD

android_library(
    name = "hello_world_test_lib",
    srcs = ["Tests.java"],
    deps = [
      "//java/com/samples/hello_world:hello_world_lib",
      ...  # test dependencies such as Espresso and Mockito
    ],
)

# The test app
android_binary(
    name = "hello_world_test_app",
    instruments = "//java/com/samples/hello_world:hello_world_app",
    manifest = "AndroidManifest.xml",
    deps = [":hello_world_test_lib"],
)

android_instrumentation_test(
    name = "hello_world_uiinstrumentation_tests",
    target_device = ":some_target_device",
    test_app = ":hello_world_test_app",
)

인수

android_local_test

android_local_test(name, deps, srcs, data, args, compatible_with, custom_package, densities, deprecation, enable_data_binding, env, env_inherit, exec_compatible_with, exec_properties, features, flaky, javacopts, jvm_flags, licenses, local, manifest, manifest_values, nocompress_extensions, plugins, resource_configuration_filters, resource_jars, resource_strip_prefix, restricted_to, runtime_deps, shard_count, size, stamp, tags, target_compatible_with, test_class, testonly, timeout, toolchains, use_launcher, visibility)

이 규칙은 기기가 아닌 로컬에서 android_library 규칙의 단위 테스트에 적용됩니다. Android Robolectric 테스트 프레임워크와 호환됩니다. Robolectric 테스트 작성에 관한 자세한 내용은 Android Robolectric 사이트를 참고하세요.

암시적 출력 타겟

• name.jar: 테스트의 자바 보관 파일입니다.
• name-src.jar: 소스가 포함된 보관 파일('소스 jar')
• name_deploy.jar: 배포에 적합한 자바 배포 보관 파일입니다 (명시적으로 요청된 경우에만 빌드됨).

예

android_local_test와 함께 Robolectric을 사용하려면 Robolectric 저장소를 WORKSPACE 파일에 추가합니다.

http_archive(
    name = "robolectric",
    urls = ["https://github.com/robolectric/robolectric-bazel/archive/<COMMIT>.tar.gz"],
    strip_prefix = "robolectric-bazel-<COMMIT>",
    sha256 = "<HASH>",
)
load("@robolectric//bazel:robolectric.bzl", "robolectric_repositories")
robolectric_repositories()

android_local_test(
    name = "SampleTest",
    srcs = [
        "SampleTest.java",
    ],
    manifest = "LibManifest.xml",
    deps = [
        ":sample_test_lib",
        "@robolectric//bazel:android-all",
    ],
)

android_library(
    name = "sample_test_lib",
    srcs = [
         "Lib.java",
    ],
    resource_files = glob(["res/**"]),
    manifest = "AndroidManifest.xml",
)

인수

Android_기기

android_device(name, cache, compatible_with, default_properties, deprecation, distribs, exec_compatible_with, exec_properties, features, horizontal_resolution, licenses, platform_apks, ram, restricted_to, screen_density, system_image, tags, target_compatible_with, testonly, vertical_resolution, visibility, vm_heap)

이 규칙은 지정된 사양으로 구성된 Android 에뮬레이터를 만듭니다. 이 에뮬레이터는 bazel 실행 명령어를 통해 또는 생성된 스크립트를 직접 실행하여 시작할 수 있습니다. 직접 정의하지 말고 기존 android_device 규칙을 활용하는 것이 좋습니다.

이 규칙은 bazel 테스트 및 실행 실행을 위한 --run_under 플래그에 적합한 대상입니다. 에뮬레이터를 시작하고 테스트/실행 중인 타겟을 에뮬레이터에 복사하고 테스트하거나 적절하게 실행합니다.

android_device는 기본 system_image가 X86 기반이고 최대 I686 CPU 아키텍처에 최적화된 경우 KVM 이미지 생성을 지원합니다. KVM을 사용하려면 tags = ['requires-kvm'] 를 android_device 규칙에 추가합니다.

암시적 출력 타겟

• name_images/userdata.dat: 에뮬레이터를 시작하는 이미지 파일과 스냅샷을 포함합니다.
• name_images/emulator-meta-data.pb: 에뮬레이터를 다시 시작하기 위해 에뮬레이터에 전달하는 데 필요한 직렬화된 정보를 포함합니다.

예

다음 예는 android_device 사용 방법을 보여줍니다. //java/android/helloandroid/BUILD에 다음을 포함

android_device(
    name = "nexus_s",
    cache = 32,
    default_properties = "nexus_s.properties",
    horizontal_resolution = 480,
    ram = 512,
    screen_density = 233,
    system_image = ":emulator_images_android_16_x86",
    vertical_resolution = 800,
    vm_heap = 32,
)

filegroup(
    name = "emulator_images_android_16_x86",
    srcs = glob(["androidsdk/system-images/android-16/**"]),
)

//java/android/helloandroid/nexus_s.properties에 다음 항목 포함:

ro.product.brand=google
ro.product.device=crespo
ro.product.manufacturer=samsung
ro.product.model=Nexus S
ro.product.name=soju

이 규칙은 이미지와 시작 스크립트를 생성합니다. bazel run :nexus_s -- --action=start를 실행하여 에뮬레이터를 로컬에서 시작할 수 있습니다. 이 스크립트는 다음과 같은 플래그를 노출합니다.

• --adb_port: adb를 노출할 포트입니다. adb 명령어를 에뮬레이터에 발급하려는 경우 adb 연결을 실행하는 포트입니다.
• --webmasters_port: 에뮬레이터의 텔넷 관리 콘솔을 노출할 포트입니다.
• --enable_display: true인 경우 에뮬레이터를 표시합니다 (기본값은 false).
• --action: 시작 또는 종료합니다.
• --apks_to_install: 에뮬레이터에 설치할 APK 목록입니다.

인수

android_ndk_repository

android_ndk_repository(name, api_level, path, repo_mapping)

네이티브 코드로 Android 타겟 빌드를 지원하도록 Android NDK를 사용하도록 Bazel을 구성합니다.

이 android_ndk_repository 구현은 Starlark의 구현으로 대체됩니다. 버전 25 이상을 포함한 NDK의 향후 버전에 관한 지원은 Starlark 버전 android_ndk_repository에서 구현됩니다. Starlark 버전은 rules_android_ndk를 참고하세요.

Android용으로 빌드하려면 WORKSPACE 파일에 android_sdk_repository 규칙도 필요합니다.

자세한 내용은 Bazel을 사용한 Android NDK 사용에 관한 전체 문서를 참고하세요.

예

android_ndk_repository(
    name = "androidndk",
)

위의 예에서는 $ANDROID_NDK_HOME에서 Android NDK를 찾아 지원하는 가장 높은 API 수준을 감지합니다.

android_ndk_repository(
    name = "androidndk",
    path = "./android-ndk-r20",
    api_level = 24,
)

위의 예에서는 ./android-ndk-r20의 작업공간 내에 있는 Android NDK를 사용합니다. JNI 코드를 컴파일할 때 API 수준 24 라이브러리를 사용합니다.

CPU 기능

Android NDK에는 런타임에 기기의 CPU를 감지하는 데 사용할 수 있는 cpufeatures 라이브러리가 포함되어 있습니다. 다음 예시에서는 Bazel과 함께 cpufeatures를 사용하는 방법을 보여줍니다.

# jni.cc
#include "ndk/sources/android/cpufeatures/cpu-features.h"
...

# BUILD
cc_library(
    name = "jni",
    srcs = ["jni.cc"],
    deps = ["@androidndk//:cpufeatures"],
)

인수

android_sdk_repository

android_sdk_repository(name, api_level, build_tools_version, path, repo_mapping)

로컬 Android SDK를 사용하여 Android 타겟 빌드를 지원하도록 Bazel을 구성합니다.

예

android_sdk_repository(
    name = "androidsdk",
)

재현 가능한 빌드를 보장하기 위해 path, api_level 및 build_tools_version 속성을 특정 값으로 설정할 수 있습니다. Android SDK에 지정된 API 수준이나 빌드 도구 버전이 설치되어 있지 않으면 빌드가 실패합니다.

android_sdk_repository(
    name = "androidsdk",
    path = "./sdk",
    api_level = 19,
    build_tools_version = "25.0.0",
)

위의 예는 Android SDK에 대한 작업공간 기준 경로를 사용하는 방법도 보여줍니다. 이는 Android SDK가 Bazel 작업공간의 일부인 경우에 유용합니다 (예: 버전 제어에 체크인된 경우).

지원 라이브러리

지원 라이브러리는 Android SDK Manager에서 'Android 지원 저장소'로 제공됩니다. 로컬 Maven 저장소로 패키징된 지원 및 AppCompat 라이브러리와 같이 버전이 지정된 일반 Android 라이브러리 집합입니다. android_sdk_repository는 android_binary 및 android_library 타겟의 종속 항목에 사용할 수 있는 이러한 각 라이브러리의 Bazel 타겟을 생성합니다.

생성된 타겟의 이름은 @androidsdk//${group}:${artifact}-${version} 형식의 Android 지원 저장소에 있는 라이브러리의 Maven 좌표에서 파생됩니다. 다음 예는 android_library가 v7 appcompat 라이브러리의 버전 25.0.0에 종속되는 방식을 보여줍니다.

android_library(
    name = "lib",
    srcs = glob(["*.java"]),
    manifest = "AndroidManifest.xml",
    resource_files = glob(["res/**"]),
    deps = ["@androidsdk//com.android.support:appcompat-v7-25.0.0"],
)

인수