Android 规则

规则

• android_binary
• aar_import
• android_library
• android_instrumentation_test
• android_local_test
• android_device
• android_ndk_repository
• android_sdk_repository

android_binary

android_binary(name, deps, srcs, assets, assets_dir, compatible_with, crunch_png, custom_package, debug_key, debug_signing_keys, debug_signing_lineage_file, densities, deprecation, dex_shards, dexopts, distribs, enable_data_binding, exec_compatible_with, exec_properties, features, incremental_dexing, instruments, javacopts, key_rotation_min_sdk, licenses, main_dex_list, main_dex_list_opts, main_dex_proguard_specs, manifest, manifest_values, multidex, nocompress_extensions, package_id, plugins, proguard_apply_dictionary, proguard_apply_mapping, proguard_generate_mapping, proguard_specs, resource_configuration_filters, resource_files, restricted_to, shrink_resources, tags, target_compatible_with, testonly, visibility)

生成 Android 应用软件包文件 (.apk)。

隐式输出目标

• name.apk：使用调试密钥和 zipaligned 签名的 Android 应用软件包文件，可用于开发和调试应用。 使用调试密钥签名时，您无法发布应用。
• name_unsigned.apk：上述文件的未签名版本，可在发布之前使用发布密钥签名。
• name_deploy.jar：包含此目标的传递闭包的 Java 归档。

  Deployment jar 包含将由类加载器从头到尾搜索此运行时类路径找到的所有类。

• name_proguard.jar：此 Java 归档包含对 name_deploy.jar 运行 ProGuard 的结果。 仅当指定了 proguard_specs 属性时，才会生成此输出。
• name_proguard.map：在 name_deploy.jar 上运行 ProGuard 的映射文件结果。仅在指定了 proguard_specs 属性且设置了 proguard_generate_mapping 或 shrink_resources 时，才会生成此输出。

示例

Android 规则示例可在 Bazel 源代码树的 examples/android 目录中找到。

参数

          android/support/multidex/MultiDex$V19.class
          android/support/multidex/MultiDex.class
          android/support/multidex/MultiDexApplication.class
          com/google/common/base/Objects.class
                    

aar_import

aar_import(name, deps, data, aar, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, exports, features, licenses, restricted_to, srcjar, tags, target_compatible_with, testonly, visibility)

此规则允许将 .aar 文件用作 android_library 和 android_binary 规则的库。

示例

    aar_import(
        name = "google-vr-sdk",
        aar = "gvr-android-sdk/libraries/sdk-common-1.10.0.aar",
    )

    android_binary(
        name = "app",
        manifest = "AndroidManifest.xml",
        srcs = glob(["**.java"]),
        deps = [":google-vr-sdk"],
    )

参数

android_library

android_library(name, deps, srcs, data, assets, assets_dir, compatible_with, custom_package, deprecation, distribs, enable_data_binding, exec_compatible_with, exec_properties, exported_plugins, exports, exports_manifest, features, idl_import_root, idl_parcelables, idl_preprocessed, idl_srcs, javacopts, licenses, manifest, neverlink, plugins, proguard_specs, resource_files, restricted_to, tags, target_compatible_with, testonly, visibility)

此规则会将其源代码编译并归档为 .jar 文件。Android 运行时库 android.jar 隐式放置在编译类路径上。

隐式输出目标

• libname.jar：一个 Java 归档。
• libname-src.jar：包含来源（“source jar”）的归档。
• name.aar：一个 Android“aar”软件包，其中包含此目标的 Java 归档和资源。它不包含传递的闭包。

示例

您可以在 Bazel 源代码树的 examples/android 目录中找到 Android 规则示例。

以下示例展示了如何设置 idl_import_root。让 //java/bazel/helloandroid/BUILD 包含：

android_library(
    name = "parcelable",
    srcs = ["MyParcelable.java"], # bazel.helloandroid.MyParcelable

    # MyParcelable.aidl will be used as import for other .aidl
    # files that depend on it, but will not be compiled.
    idl_parcelables = ["MyParcelable.aidl"] # bazel.helloandroid.MyParcelable

    # We don't need to specify idl_import_root since the aidl file
    # which declares bazel.helloandroid.MyParcelable
    # is present at java/bazel/helloandroid/MyParcelable.aidl
    # underneath a java root (java/).
)

android_library(
    name = "foreign_parcelable",
    srcs = ["src/android/helloandroid/OtherParcelable.java"], # android.helloandroid.OtherParcelable
    idl_parcelables = [
        "src/android/helloandroid/OtherParcelable.aidl" # android.helloandroid.OtherParcelable
    ],

    # We need to specify idl_import_root because the aidl file which
    # declares android.helloandroid.OtherParcelable is not positioned
    # at android/helloandroid/OtherParcelable.aidl under a normal java root.
    # Setting idl_import_root to "src" in //java/bazel/helloandroid
    # adds java/bazel/helloandroid/src to the list of roots
    # the aidl compiler will search for imported types.
    idl_import_root = "src",
)

# Here, OtherInterface.aidl has an "import android.helloandroid.CallbackInterface;" statement.
android_library(
    name = "foreign_interface",
    idl_srcs = [
        "src/android/helloandroid/OtherInterface.aidl" # android.helloandroid.OtherInterface
        "src/android/helloandroid/CallbackInterface.aidl" # android.helloandroid.CallbackInterface
    ],

    # As above, idl_srcs which are not correctly positioned under a java root
    # must have idl_import_root set. Otherwise, OtherInterface (or any other
    # interface in a library which depends on this one) will not be able
    # to find CallbackInterface when it is imported.
    idl_import_root = "src",
)

# MyParcelable.aidl is imported by MyInterface.aidl, so the generated
# MyInterface.java requires MyParcelable.class at compile time.
# Depending on :parcelable ensures that aidl compilation of MyInterface.aidl
# specifies the correct import roots and can access MyParcelable.aidl, and
# makes MyParcelable.class available to Java compilation of MyInterface.java
# as usual.
android_library(
    name = "idl",
    idl_srcs = ["MyInterface.aidl"],
    deps = [":parcelable"],
)

# Here, ServiceParcelable uses and thus depends on ParcelableService,
# when it's compiled, but ParcelableService also uses ServiceParcelable,
# which creates a circular dependency.
# As a result, these files must be compiled together, in the same android_library.
android_library(
    name = "circular_dependencies",
    srcs = ["ServiceParcelable.java"],
    idl_srcs = ["ParcelableService.aidl"],
    idl_parcelables = ["ServiceParcelable.aidl"],
)

参数

android_instrumentation_test

android_instrumentation_test(name, data, args, compatible_with, deprecation, distribs, env, env_inherit, exec_compatible_with, exec_properties, features, flaky, licenses, local, restricted_to, shard_count, size, support_apks, tags, target_compatible_with, target_device, test_app, testonly, timeout, toolchains, visibility)

android_instrumentation_test 规则用于运行 Android 插桩测试。它将启动模拟器，安装被测应用、测试应用以及任何其他所需的应用，然后运行测试软件包中定义的测试。

test_app 属性指定包含测试的 android_binary。而此 android_binary 则通过其 instruments 属性指定受测 android_binary 应用。

示例

# java/com/samples/hello_world/BUILD

android_library(
    name = "hello_world_lib",
    srcs = ["Lib.java"],
    manifest = "LibraryManifest.xml",
    resource_files = glob(["res/**"]),
)

# The app under test
android_binary(
    name = "hello_world_app",
    manifest = "AndroidManifest.xml",
    deps = [":hello_world_lib"],
)

# javatests/com/samples/hello_world/BUILD

android_library(
    name = "hello_world_test_lib",
    srcs = ["Tests.java"],
    deps = [
      "//java/com/samples/hello_world:hello_world_lib",
      ...  # test dependencies such as Espresso and Mockito
    ],
)

# The test app
android_binary(
    name = "hello_world_test_app",
    instruments = "//java/com/samples/hello_world:hello_world_app",
    manifest = "AndroidManifest.xml",
    deps = [":hello_world_test_lib"],
)

android_instrumentation_test(
    name = "hello_world_uiinstrumentation_tests",
    target_device = ":some_target_device",
    test_app = ":hello_world_test_app",
)

参数

android_local_test

android_local_test(name, deps, srcs, data, args, compatible_with, custom_package, densities, deprecation, enable_data_binding, env, env_inherit, exec_compatible_with, exec_properties, features, flaky, javacopts, jvm_flags, licenses, local, manifest, manifest_values, nocompress_extensions, plugins, resource_configuration_filters, resource_jars, resource_strip_prefix, restricted_to, runtime_deps, shard_count, size, stamp, tags, target_compatible_with, test_class, testonly, timeout, toolchains, use_launcher, visibility)

此规则适用于在本地（而不是在设备上）对 android_library 规则进行单元测试。它可与 Android Robolectric 测试框架搭配使用。 如需详细了解如何编写 Robolectric 测试，请访问 Android Robolectric 网站。

隐式输出目标

• name.jar：测试的 Java 归档。
• name-src.jar：包含来源（“source jar”）的归档。
• name_deploy.jar：适合部署的 Java 部署归档（只有在明确请求时才会构建）。

示例

如需将 Robolectric 与 android_local_test 搭配使用，请将 Robolectric 的代码库添加到 WORKSPACE 文件中：

http_archive(
    name = "robolectric",
    urls = ["https://github.com/robolectric/robolectric-bazel/archive/<COMMIT>.tar.gz"],
    strip_prefix = "robolectric-bazel-<COMMIT>",
    sha256 = "<HASH>",
)
load("@robolectric//bazel:robolectric.bzl", "robolectric_repositories")
robolectric_repositories()

android_local_test(
    name = "SampleTest",
    srcs = [
        "SampleTest.java",
    ],
    manifest = "LibManifest.xml",
    deps = [
        ":sample_test_lib",
        "@robolectric//bazel:android-all",
    ],
)

android_library(
    name = "sample_test_lib",
    srcs = [
         "Lib.java",
    ],
    resource_files = glob(["res/**"]),
    manifest = "AndroidManifest.xml",
)

参数

android_device

android_device(name, cache, compatible_with, default_properties, deprecation, distribs, exec_compatible_with, exec_properties, features, horizontal_resolution, licenses, platform_apks, ram, restricted_to, screen_density, system_image, tags, target_compatible_with, testonly, vertical_resolution, visibility, vm_heap)

此规则将创建一个使用指定规范配置的 Android 模拟器。此模拟器可以通过 bazel run 命令或直接执行生成的脚本启动。建议依靠现有的 android_device 规则，而不是自行定义规则。

此规则适合 --run_under 标志用于 bazel 测试和 blaze 运行的目标。它会启动模拟器，将要测试/运行的目标复制到模拟器，然后根据需要对其进行测试或运行。

如果底层 system_image 基于 X86 且针对最多 I686 CPU 架构进行了优化，则 android_device 支持创建 KVM 映像。如需使用 KVM，请将 tags = ['requires-kvm'] 添加到 android_device 规则中。

隐式输出目标

• name_images/userdata.dat：包含用于启动模拟器的映像和快照
• name_images/emulator-meta-data.pb：包含传递给模拟器重启模拟器所必需的序列化信息。

示例

以下示例展示了如何使用 android_device。 //java/android/helloandroid/BUILD包含

android_device(
    name = "nexus_s",
    cache = 32,
    default_properties = "nexus_s.properties",
    horizontal_resolution = 480,
    ram = 512,
    screen_density = 233,
    system_image = ":emulator_images_android_16_x86",
    vertical_resolution = 800,
    vm_heap = 32,
)

filegroup(
    name = "emulator_images_android_16_x86",
    srcs = glob(["androidsdk/system-images/android-16/**"]),
)

//java/android/helloandroid/nexus_s.properties 包含：

ro.product.brand=google
ro.product.device=crespo
ro.product.manufacturer=samsung
ro.product.model=Nexus S
ro.product.name=soju

此规则将生成图片和启动脚本。您可以通过执行 bazel run :nexus_s -- --action=start 在本地启动模拟器。该脚本会公开以下标志：

• --adb_port：要公开 adb 的端口。如果您想要向模拟器发出 adb 命令，则需要将这个端口发送到 adb 连接。
• --emulator_port：用于公开模拟器的 telnet 管理控制台的端口。
• --enable_display：如果模拟器为 true（默认为 false），则通过显示屏启动模拟器。
• --action：要么启动，要么终止。
• --apks_to_install：要在模拟器上安装的 APK 的列表。

参数

android_ndk_repository

android_ndk_repository(name, api_level, path, repo_mapping)

将 Bazel 配置为使用 Android NDK 来支持使用原生代码构建 Android 目标。

请注意，android_ndk_repository 的这个实现将替换为 Starlark 中的实现。对 NDK 未来版本（包括版本 25 及更高版本）的支持将在 Starlark 版本的 android_ndk_repository 中实现。如需了解 Starlark 版本，请参阅 rules_android_ndk。

请注意，为 Android 构建应用还需要在 WORKSPACE 文件中设置 android_sdk_repository 规则。

如需了解详情，请参阅有关将 Android NDK 与 Bazel 搭配使用的完整文档。

示例

android_ndk_repository(
    name = "androidndk",
)

上面的示例将从 $ANDROID_NDK_HOME 找到您的 Android NDK，并检测其支持的最高 API 级别。

android_ndk_repository(
    name = "androidndk",
    path = "./android-ndk-r20",
    api_level = 24,
)

上面的示例将使用位于 ./android-ndk-r20 中的工作区内的 Android NDK。它会在编译 JNI 代码时使用 API 级别 24 的库。

CPU 功能

Android NDK 包含 cpufeatures 库，该库可用于在运行时检测设备的 CPU。以下示例演示了如何将 cpufeatures 与 Bazel 搭配使用。

# jni.cc
#include "ndk/sources/android/cpufeatures/cpu-features.h"
...

# BUILD
cc_library(
    name = "jni",
    srcs = ["jni.cc"],
    deps = ["@androidndk//:cpufeatures"],
)

参数

android_sdk_repository

android_sdk_repository(name, api_level, build_tools_version, path, repo_mapping)

将 Bazel 配置为使用本地 Android SDK 来支持构建 Android 目标。

示例

android_sdk_repository(
    name = "androidsdk",
)

为了确保可重现的 build，您可以将 path、api_level 和 build_tools_version 属性设为特定值。如果 Android SDK 未安装指定的 API 级别或构建工具版本，构建将会失败。

android_sdk_repository(
    name = "androidsdk",
    path = "./sdk",
    api_level = 19,
    build_tools_version = "25.0.0",
)

上面的示例还演示了如何使用相对 Android SDK 的工作区路径。如果 Android SDK 是 Bazel 工作区的一部分（例如，如果签入到版本控制中），这会很有用。

支持库

支持库在 Android SDK 管理器中以“Android 支持代码库”的形式提供。这是一组通用化的 Android 库（例如 Support 和 AppCompat 库），打包为本地 Maven 代码库。android_sdk_repository 会为其中每个库生成可在 android_binary 和 android_library 目标的依赖项中使用的 Bazel 目标。

生成的目标的名称源自 Android 支持代码库中库的 Maven 坐标，格式为 @androidsdk//${group}:${artifact}-${version}。以下示例展示了 android_library 如何依赖于 v7 appcompat 库的 25.0.0 版本。

android_library(
    name = "lib",
    srcs = glob(["*.java"]),
    manifest = "AndroidManifest.xml",
    resource_files = glob(["res/**"]),
    deps = ["@androidsdk//com.android.support:appcompat-v7-25.0.0"],
)

参数