パフォーマンスの最適化

問題を報告 ソースを表示

ルールを作成する際に最もよくあるパフォーマンスの問題は、依存関係から蓄積されたデータを走査またはコピーすることです。ビルド全体で集計すると、これらのオペレーションは O(N^2) 時間またはスペースを要する可能性があります。これを回避するには、依存関係を効果的に使用する方法を理解することが重要です。

これを正しく行うことは難しいため、Bazel には、間違いを犯した可能性のある場所を見つけるために役立つメモリ プロファイラも用意されています。注意: 非効率的なルールを作成するコストは、それが広く使用されるまで明らかではありません。

依存関係を使用する

ルールの依存関係から情報をロールアップする場合は、必ず depsets を使用してください。現在のルールにローカルで情報を公開する場合は、プレーンなリストまたは辞書のみを使用してください。

depset は、共有を可能にするネストされたグラフとして情報を表します。

次のグラフについて考えてみましょう。

C -> B -> A
D ---^

各ノードは単一の文字列を公開します。depset を使用した場合、データは次のようになります。

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

各項目は 1 回だけ言及されることに注意してください。リストの場合は次のようになります。

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

この場合、'a' は 4 回言及されています。グラフが大きいほど この問題はますます悪化します

依存関係を正しく使用して推移的情報をパブリッシュするルール実装の例を次に示します。なお、これは O(N^2) ではないため、必要に応じてリストを使用してルールローカル情報を公開しても問題ありません。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

詳細については、依存関係の概要ページをご覧ください。

depset.to_list() の呼び出しを避ける

to_list() を使用して依存関係をフラットリストに強制変換することもできますが、通常は O(N^2) コストが発生します。デバッグ目的以外では、デプセットのフラット化は可能な限り避けてください。

よくある誤解は、<xx>_binary ルールなどの最上位のターゲットでのみ依存関係をフラット化すると、ビルドグラフの各レベルで費用が累積されない、というものです。ただし、依存関係が重複するターゲット セットをビルドしても、これは依然として O(N^2) です。これは、テスト //foo/tests/... をビルドするとき、または IDE プロジェクトをインポートするときに行われます。

depset への通話回数を減らす

ループ内で depset を呼び出すのは誤りです。ネストが深すぎると デプセットが発生し パフォーマンスが低下します次に例を示します。

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

このコードは簡単に置き換えることができます。まず、推移的依存関係を収集して一度にすべてマージします。

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

これは、リストの理解を使用して短縮できる場合があります。

x = depset(transitive = [i.deps for i in inputs])

コマンドラインに resourcemanager.actions.args() を使用する

コマンドラインを作成するときは、ctx.actions.args() を使用してください。これにより、依存関係の展開を実行フェーズで延期できます。

これにより、厳密に高速化されるだけでなく、ルールのメモリ消費量が削減され、場合によっては 90% 以上削減されます。

以下にコツを紹介します。

  • 依存関係とリストは、自分でフラット化するのではなく、引数として直接渡します。これらは ctx.actions.args() 拡張されます。 depset の内容の変換が必要な場合は、ctx.actions.args#add を見て、要件に合致するものがあるかどうかを確認してください。

  • File#path を引数として渡していますか?その必要はありません。File は自動的にそのパスに変換され、展開まで延期されます。

  • 文字列を連結して作成しないようにします。最適な文字列引数は定数です。この引数のメモリは、ルールのすべてのインスタンス間で共有されます。

  • コマンドラインの引数が長すぎる場合は、ctx.actions.args#use_param_file を使用して、ctx.actions.args() オブジェクトを条件付きまたは無条件でパラメータ ファイルに書き込めます。この処理は、アクションの実行時にバックグラウンドで行われます。パラメータ ファイルを明示的に制御する必要がある場合は、ctx.actions.write を使用して手動で記述できます。

例:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

推移的アクションの入力は依存関係である必要がある

ctx.actions.run を使用してアクションを作成する場合は、inputs フィールドが依存関係を受け入れることを忘れないでください。依存関係から入力が推移的に収集される場合は常に、これを使用します。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

吊り下げ

Bazel がハングしているように見える場合は、Ctrl-\ を押すか、Bazel に SIGQUIT シグナル(kill -3 $(bazel info server_pid))を送信して、$(bazel info output_base)/server/jvm.out ファイル内のスレッドダンプを取得できます。

bazel がハングすると bazel info を実行できない可能性があるため、通常は output_base ディレクトリがワークスペース ディレクトリの bazel-<workspace> シンボリック リンクの親になります。

パフォーマンス プロファイリング

JSON トレース プロファイルは、Bazel が呼び出し中に何にかかった時間をすばやく把握するのに便利です。

--experimental_command_profile フラグを使用すると、さまざまな種類の Java フライト レコーダー プロファイル(CPU 時間、経過時間、メモリ割り当て、ロック競合)をキャプチャできます。

--starlark_cpu_profile フラグを使用すると、すべての Starlark スレッドによる CPU 使用率の pprof プロファイルを書き込むことができます。

メモリのプロファイリング

Bazel には、ルールのメモリ使用量の確認に役立つメモリ プロファイラが組み込まれています。問題が発生した場合は、ヒープをダンプして、問題の原因となっているコード行を特定できます。

メモリ トラッキングを有効にする

次の 2 つの起動フラグをすべての Bazel 呼び出しに渡す必要があります。

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

これらのコマンドにより、サーバーがメモリ トラッキング モードで起動します。これらを忘れた Bazel 呼び出しを 1 回でも行うと、サーバーが再起動するため、最初からやり直す必要があります。

Memory Tracker の使用

例として、ターゲット foo を見て、その機能を確認します。分析のみを実行し、ビルド実行フェーズは実行しない場合は、--nobuild フラグを追加します。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

次に、Bazel インスタンス全体が消費するメモリ量を確認します。

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules を使用してルールクラス別に分類します。

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory を使用して pprof ファイルを生成して、メモリの場所を確認します。

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

pprof ツールを使用してヒープを調査します。まず、pprof -flame $HOME/prof.gz を使用してフレームグラフを取得することをおすすめします。

https://github.com/google/pprof から pprof を取得します。

行を含む、最もホットなコールサイトのテキストダンプを取得します。

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)