Cómo crear una macro

Informa un problema Ver código fuente

Imagina que necesitas ejecutar una herramienta como parte de la compilación. Por ejemplo, es posible que quieras generar o preprocesar un archivo de origen, o comprimir un objeto binario. En este instructivo, crearás una macro que cambia el tamaño de una imagen.

Las macros son adecuadas para tareas simples. Si deseas realizar una tarea más complicada, por ejemplo, agregar compatibilidad con un nuevo lenguaje de programación, considera crear una regla. Las reglas le brindan más control y flexibilidad.

La manera más fácil de crear una macro que cambie el tamaño de una imagen es usar un genrule:

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

Si necesitas cambiar el tamaño de más imágenes, vuelve a usar el código. Para ello, define una función en un archivo .bzl separado y llama al archivo miniature.bzl:

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

Algunos comentarios:

  • Por convención, las macros tienen un argumento name, al igual que las reglas.

  • Para documentar el comportamiento de una macro, usa docstring como en Python.

  • Para llamar a un genrule o cualquier otra regla nativa, usa native..

  • Usa **kwargs para reenviar los argumentos adicionales al genrule subyacente (funciona igual que en Python). Esto es útil para que un usuario pueda usar atributos estándar como visibility o tags.

Ahora, usa la macro del archivo BUILD:

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)