Bazel を初めて使用する場合は、Bazel で Android をビルドする チュートリアルから始めてください。
概要
Bazel は、Android Native Development Kit（NDK）ツールチェーンを使用する構成など、さまざまなビルド構成で実行できます。つまり、通常の
cc_library と cc_binary ルールを
Bazel 内で直接 Android 用にコンパイルできます。Bazel は、android_ndk_repository リポジトリ
ルールとそれに関連する bzlmod 拡張機能を使用してこれを実現します。
一般的な Android
コンパイルには、rules_androidを使用します。
このチュートリアルでは、C++ ライブラリの依存関係を
Android アプリに統合する方法について説明し、NDK
ツールチェーンの検出と登録に
rules_android_ndkを使用します。
前提条件
Android SDK と NDK がインストールされていることを確認してください。
NDK と SDK の設定
外部リポジトリの設定は、WORKSPACE または bzlmod（MODULE.bazel）を使用しているかによって異なります。bzlmod は Bazel 7 以降で推奨されるソリューションです。 MODULE.bazel と WORKSPACE のセットアップ スタンザは 互いに独立していることに注意してください。 MODULE.bazel と WORKSPACE の設定スタンザは互いに独立しています。1 つの依存関係管理ソリューションを使用している場合は、もう一方のボイラープレートを追加する 必要はありません。
Bzlmod MODULE.bazel の設定
MODULE.bazel に次のスニペットを追加します。
# NDK
bazel_dep(name = "rules_android_ndk", version = "0.1.3")
android_ndk_repository_extension = use_extension("@rules_android_ndk//:extension.bzl", "android_ndk_repository_extension")
use_repo(android_ndk_repository_extension, "androidndk")
register_toolchains("@androidndk//:all")
# SDK
bazel_dep(name = "rules_android", version = "0.6.6")
register_toolchains(
"@rules_android//toolchains/android:android_default_toolchain",
"@rules_android//toolchains/android_sdk:android_sdk_tools",
)
android_sdk_repository_extension = use_extension("@rules_android//rules/android_sdk_repository:rule.bzl", "android_sdk_repository_extension")
use_repo(android_sdk_repository_extension, "androidsdk")
register_toolchains("@androidsdk//:sdk-toolchain", "@androidsdk//:all")
以前の WORKSPACE の設定
WORKSPACE に次のスニペットを追加します。
load("@rules_android//rules:rules.bzl", "android_sdk_repository")
android_sdk_repository(
name = "androidsdk", # Required. Name *must* be "androidsdk".
path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)
load("@rules_android_ndk//:rules.bzl", "android_ndk_repository")
android_ndk_repository(
name = "androidndk", # Required. Name *must* be "androidndk".
path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)
WORKSPACE の互換性に関する注意事項:
rules_androidルールとrules_android_ndkルールの両方で、上記の WORKSPACE スニペットに示されていない追加の ボイラープレートが必要です。最新の 完全なインスタンス化スタンザについては、WORKSPACE ファイルをご覧ください。rules_android_ndk
android_ndk_repository ルールの詳細については、その
ドキュメント文字列をご覧ください。
クイック スタート
Android 用に C++ をビルドするには、cc_library の依存関係を
android_binary ルールまたは android_library ルールに追加します。
たとえば、Android アプリの次の BUILD ファイルがあるとします。
# In <project>/app/src/main/BUILD.bazel
load("@rules_cc//cc:cc_library.bzl", "cc_library")
load("@rules_android//rules:rules.bzl", "android_binary", "android_library")
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
)
android_library(
name = "lib",
srcs = ["java/com/example/android/bazel/MainActivity.java"],
resource_files = glob(["res/**/*"]),
custom_package = "com.example.android.bazel",
manifest = "LibraryManifest.xml",
deps = [":jni_lib"],
)
android_binary(
name = "app",
deps = [":lib"],
manifest = "AndroidManifest.xml",
)
この BUILD ファイルにより、次のターゲット グラフが生成されます。
図 1.cc_library の依存関係を持つ Android プロジェクトのビルドグラフ。
アプリをビルドするには、次のコマンドを実行します。
bazel build //app/src/main:app --android_platforms=<your platform>--android_platforms を指定しない場合、
JNI ヘッダーがないというエラーでビルドが失敗します。
bazel build コマンドは、Java ファイル、Android リソース ファイル、
cc_library ルールをコンパイルし、すべてを APK にパッケージ化します。
$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MFBazel は、--android_platforms で指定されたアーキテクチャを対象として、すべての cc_libraries を単一の共有オブジェクト（.so）ファイルにコンパイルします。詳細については、ターゲット ABI の構成に関する
詳細をご覧ください。
設定例
この例は、Bazel のサンプル リポジトリで入手できます。
BUILD.bazel ファイルでは、android_binary、
android_library、cc_library の各ルールを使用して 3 つのターゲットが定義されています。
android_binary の最上位ターゲットは APK をビルドします。
cc_library ターゲットには、JNI 関数
実装を含む単一の C++ ソースファイルが含まれています。
#include <jni.h>
#include <string>
extern "C"
JNIEXPORT jstring
JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
JNIEnv *env,
jobject /* this */) {
std::string hello = "Hello from C++";
return env->NewStringUTF(hello.c_str());
}
android_library ターゲットは、Java ソース、リソース ファイル、
cc_library ターゲットへの依存関係を指定します。この例では、MainActivity.java は共有オブジェクト ファイル libapp.so を読み込み、JNI 関数のメソッド シグネチャを定義します。
public class MainActivity extends AppCompatActivity {
static {
System.loadLibrary("app");
}
@Override
protected void onCreate(Bundle savedInstanceState) {
// ...
}
public native String stringFromJNI();
}
ターゲット ABI を構成する
ターゲット ABI を構成するには、--android_platforms フラグを次のように使用します。
bazel build //:app --android_platforms=comma-separated list of platforms--platforms フラグと同様に、--android_platforms に渡される値は
platform
ターゲットのラベルであり、標準の制約値を使用してデバイスを記述します。
たとえば、64 ビット ARM プロセッサを搭載した Android デバイスの場合、プラットフォームは次のように定義します。
platform(
name = "android_arm64",
constraint_values = [
"@platforms//os:android",
"@platforms//cpu:arm64",
],
)
すべての Android platform で、@platforms//os:android
OS 制約を使用する必要があります。CPU 制約を移行するには、次の表を確認してください。
| CPU 値 | プラットフォーム |
|---|---|
armeabi-v7a |
@platforms//cpu:armv7 |
arm64-v8a |
@platforms//cpu:arm64 |
x86 |
@platforms//cpu:x86_32 |
x86_64 |
@platforms//cpu:x86_64 |
もちろん、マルチアーキテクチャ APK の場合は、複数のラベルを渡します。たとえば、--android_platforms=//:arm64,//:x86_64（最上位のBUILD.bazel ファイルで定義されている場合）などです。
Bazel はデフォルトの Android プラットフォームを選択できないため、定義して
--android_platforms で指定する必要があります。
NDK リビジョンと Android API レベルに応じて、次の ABI を 使用できます。
| NDK リビジョン | ABI |
|---|---|
| 16 以下 | armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64 |
| 17 以上 | armeabi-v7a、arm64-v8a、x86、x86_64 |
これらの ABI の詳細については、NDK ドキュメント をご覧ください。
マルチ ABI Fat APK は APK のサイズが大きくなるため、リリースビルドにはおすすめしませんが、開発ビルドや QA ビルドには役立ちます。
C++ 標準を選択する
C++ 標準に従ってビルドするには、次のフラグを使用します。
| C++ 標準 | フラグ |
|---|---|
| C++98 | デフォルト。フラグは不要 |
| C++11 | --cxxopt=-std=c++11 |
| C++14 | --cxxopt=-std=c++14 |
| C++17 | --cxxopt=-std=c++17 |
次に例を示します。
bazel build //:app --cxxopt=-std=c++11--cxxopt、--copt、
--linkopt を使用してコンパイラ フラグとリンカー フラグを渡す方法については、ユーザー マニュアルをご覧ください。
コンパイラ フラグとリンカー フラグは、cc_library
を使用して copts と linkopts の属性として指定することもできます。次に例を示します。
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
copts = ["-std=c++11"],
linkopts = ["-ldl"], # link against libdl
)
Android 用の cc_library を android_binary を使用せずにビルドする
Android 用のスタンドアロン cc_binary または cc_library を
android_binary を使用せずにビルドするには、--platforms フラグを使用します。
たとえば、Android プラットフォームを
my/platforms/BUILDで定義したとします。
bazel build //my/cc/jni:target \
--platforms=//my/platforms:x86_64この方法では、ビルドツリー全体が影響を受けます。
これらのフラグは、bazelrc 構成（ABI ごとに 1 つ）に配置できます。
project/.bazelrc に配置します。
common:android_x86 --platforms=//my/platforms:x86
common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a
# In general
common:android_<abi> --platforms=//my/platforms:<abi>
次に、cc_library 用の x86 をビルドするには、次のコマンドを実行します。
bazel build //my/cc/jni:target --config=android_x86一般に、この方法は低レベルのターゲット（cc_library など）の場合や、
ビルドするものがわかっている場合に使用します。制御できない多くのターゲットをビルドすることが想定される高レベルのターゲットの場合は、android_binary からの自動構成
遷移に依存します。