กลุ่มการดำเนินการ

กลุ่มการดำเนินการช่วยให้มีแพลตฟอร์มการดำเนินการหลายแพลตฟอร์มภายในเป้าหมายเดียวได้ กลุ่มการดำเนินการแต่ละกลุ่มมีการพึ่งพาToolchainของตัวเองและ ทำการแก้ปัญหาToolchainของตัวเอง

สถานะปัจจุบัน

คุณสามารถใช้กลุ่มการดำเนินการสำหรับการดำเนินการที่ประกาศไว้ในตัว เช่น CppLink ภายใน exec_properties เพื่อกำหนดข้อกำหนดการดำเนินการต่อการดำเนินการต่อเป้าหมาย ดูรายละเอียดเพิ่มเติมได้ที่ส่วน กลุ่มการดำเนินการเริ่มต้น

ฉากหลัง

กลุ่มการดำเนินการช่วยให้ผู้เขียนกฎกำหนดชุดการดำเนินการได้ โดยแต่ละชุดอาจมีแพลตฟอร์มการดำเนินการที่แตกต่างกัน แพลตฟอร์มการดำเนินการหลายแพลตฟอร์มช่วยให้การดำเนินการทำงานแตกต่างกันได้ เช่น การคอมไพล์แอป iOS ในผู้ปฏิบัติงานระยะไกล (Linux) แล้วลิงก์/ลงชื่อรหัสในผู้ปฏิบัติงาน Mac ในเครื่อง

ความสามารถในการกำหนดกลุ่มการดำเนินการยังช่วยลดการใช้ตัวช่วยจำการดำเนินการเพื่อเป็นตัวแทนในการระบุการดำเนินการได้ด้วย ตัวช่วยจำไม่รับประกันว่าจะไม่ซ้ำกันและอ้างอิงได้เพียงการดำเนินการเดียวเท่านั้น ซึ่งมีประโยชน์อย่างยิ่งในการจัดสรรทรัพยากรเพิ่มเติมให้กับการดำเนินการที่ใช้หน่วยความจำและการประมวลผลสูง เช่น การลิงก์ในการสร้าง C++ โดยไม่ต้องจัดสรรทรัพยากรมากเกินไปให้กับงานที่ใช้ทรัพยากรน้อยกว่า

การกำหนดกลุ่มการดำเนินการ

ในระหว่างการกำหนดกฎ ผู้เขียนกฎสามารถ ประกาศ ชุดกลุ่มการดำเนินการได้ ในกลุ่มการดำเนินการแต่ละกลุ่ม ผู้เขียนกฎสามารถระบุทุกสิ่งที่จำเป็นในการเลือกแพลตฟอร์มการดำเนินการสำหรับกลุ่มการดำเนินการนั้นๆ ได้แก่ ข้อจำกัดต่างๆ ผ่าน exec_compatible_with และประเภทเครื่องมือผ่าน toolchain

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        "link": exec_group(
            exec_compatible_with = ["@platforms//os:linux"],
            toolchains = ["//foo:toolchain_type"],
        ),
        "test": exec_group(
            toolchains = ["//foo_tools:toolchain_type"],
        ),
    },
    attrs = {
        "_compiler": attr.label(cfg = config.exec("link"))
    },
)

ในข้อมูลโค้ดด้านบน คุณจะเห็นว่าทรัพยากร Dependency ของเครื่องมือยังระบุ การเปลี่ยนกลุ่มการดำเนินการได้ด้วยโดยใช้ cfg พารามิเตอร์แอตทริบิวต์ และ config โมดูล โมดูลจะแสดงฟังก์ชัน exec ซึ่งใช้พารามิเตอร์สตริงเดียวที่เป็นชื่อของกลุ่มการดำเนินการที่ควรสร้างทรัพยากร Dependency

เช่นเดียวกับกฎดั้งเดิม กลุ่มการดำเนินการ test จะปรากฏในกฎการทดสอบ Starlark โดยค่าเริ่มต้น

การเข้าถึงกลุ่มการดำเนินการ

ในการใช้งานกฎ คุณสามารถประกาศให้การดำเนินการทำงานบนแพลตฟอร์มการดำเนินการของกลุ่มการดำเนินการได้ คุณทำได้โดยใช้ exec_group พารามิเตอร์ของเมธอดการสร้างการดำเนินการ ซึ่งได้แก่ ctx.actions.run และ ctx.actions.run_shell

# foo.bzl
def _impl(ctx):
  ctx.actions.run(
     inputs = [ctx.attr._some_tool, ctx.srcs[0]]
     exec_group = "compile",
     # ...
  )

ผู้เขียนกฎจะเข้าถึงเครื่องมือที่แก้ไขแล้ว ของกลุ่มการดำเนินการได้ด้วย เช่นเดียวกับวิธีที่คุณ เข้าถึงเครื่องมือที่แก้ไขแล้วของเป้าหมาย

# foo.bzl
def _impl(ctx):
  foo_info = ctx.exec_groups["link"].toolchains["//foo:toolchain_type"].fooinfo
  ctx.actions.run(
     inputs = [foo_info, ctx.srcs[0]]
     exec_group = "link",
     # ...
  )

กลุ่มการดำเนินการเริ่มต้น

กลุ่มการดำเนินการต่อไปนี้มีการกำหนดไว้ล่วงหน้า

• test: การดำเนินการโปรแกรมเรียกใช้การทดสอบ (ดูรายละเอียดเพิ่มเติมได้ที่ ส่วนแพลตฟอร์มการดำเนินการของสารานุกรมการทดสอบ)
• cpp_link: การดำเนินการลิงก์ C++

การใช้กลุ่มการดำเนินการเพื่อกำหนดพร็อพเพอร์ตี้การดำเนินการ

กลุ่มการดำเนินการผสานรวมกับ exec_properties แอตทริบิวต์ที่มีอยู่ในทุกกฎและช่วยให้ผู้เขียนเป้าหมายระบุ พจนานุกรมสตริงของพร็อพเพอร์ตี้ที่จะส่งไปยังกลไกการดำเนินการได้ ตัวอย่างเช่น หากต้องการกำหนดพร็อพเพอร์ตี้บางอย่าง เช่น หน่วยความจำ สำหรับเป้าหมายและจัดสรรหน่วยความจำที่สูงขึ้นให้กับการดำเนินการบางอย่าง คุณจะต้องเขียนรายการ exec_properties ด้วยคีย์ที่เพิ่มกลุ่มการดำเนินการ เช่น

# BUILD
my_rule(
    name = 'my_target',
    exec_properties = {
        'mem': '12g',
        'link.mem': '16g'
    }
    …
)

การดำเนินการทั้งหมดที่มี exec_group = "link" จะเห็นพจนานุกรมพร็อพเพอร์ตี้การดำเนินการ เป็น {"mem": "16g"} ดังที่คุณเห็นที่นี่ การตั้งค่าระดับกลุ่มการดำเนินการจะลบล้างการตั้งค่าระดับเป้าหมาย

การใช้กลุ่มการดำเนินการเพื่อกำหนดข้อจำกัดของแพลตฟอร์ม

กลุ่มการดำเนินการยังผสานรวมกับแอตทริบิวต์ exec_compatible_with และ exec_group_compatible_with ที่มีอยู่ในทุกกฎและช่วยให้ผู้เขียนเป้าหมายระบุ ข้อจำกัดเพิ่มเติมที่แพลตฟอร์มการดำเนินการที่เลือกสำหรับการดำเนินการของเป้าหมายต้องเป็นไปตาม

ตัวอย่างเช่น หากกฎ my_test กำหนดกลุ่มการดำเนินการ link นอกเหนือจากกลุ่มการดำเนินการเริ่มต้นและกลุ่มการดำเนินการ test การใช้แอตทริบิวต์เหล่านี้จะเรียกใช้การดำเนินการในกลุ่มการดำเนินการเริ่มต้นบนแพลตฟอร์มที่มี CPU จำนวนมาก การดำเนินการทดสอบบน Linux และการดำเนินการลิงก์บนแพลตฟอร์มการดำเนินการเริ่มต้น ดังนี้

# BUILD
constraint_setting(name = "cpu")
constraint_value(name = "high_cpu", constraint_setting = ":cpu")

platform(
  name = "high_cpu_platform",
  constraint_values = [":high_cpu"],
  exec_properties = {
    "cpu": "256",
  },
)

my_test(
  name = "my_test",
  exec_compatible_with = ["//constraints:high_cpu"],
  exec_group_compatible_with = {
    "test": ["@platforms//os:linux"],
  },
  ...
)

กลุ่มการดำเนินการสำหรับกฎดั้งเดิม

กลุ่มการดำเนินการต่อไปนี้พร้อมใช้งานสำหรับการดำเนินการที่กำหนดโดยกฎดั้งเดิม

• test: การดำเนินการโปรแกรมเรียกใช้การทดสอบ
• cpp_link: การดำเนินการลิงก์ C++

กลุ่มการดำเนินการและพร็อพเพอร์ตี้การดำเนินการของแพลตฟอร์ม

คุณสามารถกำหนด exec_properties สำหรับกลุ่มการดำเนินการที่กำหนดเองในเป้าหมายแพลตฟอร์มได้ (ซึ่งแตกต่างจาก exec_properties ที่กำหนดไว้ในเป้าหมายโดยตรง ซึ่งระบบจะปฏิเสธพร็อพเพอร์ตี้สำหรับกลุ่มการดำเนินการที่ไม่รู้จัก) จากนั้นเป้าหมายจะรับช่วงต่อ exec_properties ของแพลตฟอร์มการดำเนินการที่มีผลต่อกลุ่มการดำเนินการเริ่มต้นและกลุ่มการดำเนินการอื่นๆ ที่เกี่ยวข้อง

ตัวอย่างเช่น สมมติว่าการเรียกใช้การทดสอบในแพลตฟอร์มการดำเนินการต้องใช้ทรัพยากรบางอย่าง แต่ไม่จำเป็นสำหรับการคอมไพล์และการลิงก์ คุณสามารถจำลองสถานการณ์นี้ได้ดังนี้

constraint_setting(name = "resource")
constraint_value(name = "has_resource", constraint_setting = ":resource")

platform(
    name = "platform_with_resource",
    constraint_values = [":has_resource"],
    exec_properties = {
        "test.resource": "...",
    },
)

cc_test(
    name = "my_test",
    srcs = ["my_test.cc"],
    exec_compatible_with = [":has_resource"],
)

exec_properties ที่กำหนดไว้ในเป้าหมายโดยตรงจะมีลำดับความสำคัญสูงกว่าพร็อพเพอร์ตี้ที่รับช่วงต่อจากแพลตฟอร์มการดำเนินการ