กรณีการใช้งานทั่วไปของ C++ เกี่ยวกับการสร้าง

ในที่นี้คุณจะพบกับกรณีการใช้งานที่พบบ่อยที่สุดบางส่วนสำหรับการสร้างโปรเจ็กต์ C++ กับ Bazel เริ่มต้นสร้าง C++ หากยังไม่ได้ทำ ด้วย Bazel ด้วยการดูบทแนะนำจนจบ ข้อมูลเบื้องต้นเกี่ยวกับ Bazel: สร้างโครงการ C++

สำหรับข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs โปรดดู cc_library

การรวมหลายไฟล์ไว้ในเป้าหมาย

คุณสามารถรวมหลายไฟล์ไว้ในเป้าหมายเดียวได้ด้วย glob เช่น

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไฟล์ ไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ยกเว้น ไดเรกทอรีย่อย)

การใช้ทรานซิทีฟประกอบด้วย

หากไฟล์มีส่วนหัว กฎใดก็ตามที่มีไฟล์นั้นเป็นแหล่งที่มา (กล่าวคือ การมีไฟล์นั้นในแอตทริบิวต์ srcs, hdrs หรือ textual_hdrs) ควร ขึ้นอยู่กับกฎไลบรารีของส่วนหัวที่รวม ในทางกลับกัน การเข้าชมโดยตรงเท่านั้น ต้องระบุการอ้างอิงเป็นทรัพยากร Dependency ตัวอย่างเช่น สมมติว่า sandwich.h รวม bread.h และ bread.h รวม flour.h sandwich.h ไม่รวม flour.h (ใครอยากได้แป้งในแซนด์วิช) ดังนั้น BUILD ไฟล์จะมีลักษณะดังนี้

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ในส่วนนี้ ไลบรารี sandwich จะขึ้นอยู่กับไลบรารี bread ซึ่งอ้างอิง ในไลบรารี flour

การเพิ่มเส้นทางรวม

บางครั้งคุณไม่สามารถ (หรือไม่ต้องการ) การรูทเส้นทางที่รวมในพื้นที่ทำงาน ราก ไลบรารีที่มีอยู่อาจมีไดเรกทอรี "รวม" ที่ไม่มีอยู่แล้ว ตรงกับเส้นทางในพื้นที่ทำงาน ตัวอย่างเช่น สมมติว่าคุณมีข้อมูลต่อไปนี้ โครงสร้างไดเรกทอรี

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── MODULE.bazel

Bazel จะคาดหวังว่า some_lib.h จะรวมอยู่ใน legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc มี "some_lib.h" หากต้องการให้เส้นทางดังกล่าวถูกต้อง legacy/some_lib/BUILD จะต้องระบุว่า some_lib/include ไดเรกทอรีคือไดเรกทอรีรวม:

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ซึ่งมีประโยชน์อย่างยิ่งสำหรับทรัพยากร Dependency ภายนอก เช่น ไฟล์ส่วนหัว ต้องรวมกับคำนำหน้า /

รวมไลบรารีภายนอก

สมมติว่าคุณใช้ Google Test {: .external} คุณสามารถเพิ่มทรัพยากร Dependency ได้ในไฟล์ MODULE.bazel เพื่อ ดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บของคุณ:

bazel_dep(name = "googletest", version = "1.15.2")

การเขียนและทำการทดสอบ C++

ตัวอย่างเช่น คุณสร้างการทดสอบ ./test/hello-test.cc ได้ เช่น

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

จากนั้นสร้างไฟล์ ./test/BUILD ไฟล์สำหรับการทดสอบ

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    deps = [
        "@googletest//:main",
        "//main:hello-greet",
    ],
)

หากต้องการให้ hello-test เห็นhello-greet คุณต้องเพิ่ม "//test:__pkg__", ไปยังแอตทริบิวต์ visibility ใน ./main/BUILD

ตอนนี้คุณใช้ bazel test เพื่อทำการทดสอบได้แล้ว

bazel test test:hello-test

ซึ่งจะสร้างเอาต์พุตต่อไปนี้

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

การเพิ่มทรัพยากร Dependency ในไลบรารีที่คอมไพล์ไว้ล่วงหน้า

หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (สำหรับ ตัวอย่าง ส่วนหัวและไฟล์ .so) ให้รวมไว้ในกฎ cc_library ดังนี้

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

วิธีนี้จะทำให้เป้าหมาย C++ อื่นๆ ในพื้นที่ทำงานของคุณขึ้นอยู่กับกฎนี้