Hãy tưởng tượng bạn cần chạy một công cụ trong quá trình xây dựng. Ví dụ: bạn có thể muốn tạo hoặc xử lý trước một tệp nguồn, hoặc nén một tệp nhị phân. Trong hướng dẫn này, bạn sẽ tạo một macro giúp đổi kích thước hình ảnh.
Macro phù hợp với các tác vụ đơn giản. Nếu bạn muốn thực hiện bất kỳ thao tác nào phức tạp hơn, chẳng hạn như thêm tính năng hỗ trợ cho một ngôn ngữ lập trình mới, hãy cân nhắc việc tạo một quy tắc. Quy tắc giúp bạn có thêm quyền kiểm soát và tính linh hoạt.
Cách dễ nhất để tạo một macro giúp đổi kích thước hình ảnh là sử dụng genrule:
genrule(
name = "logo_miniature",
srcs = ["logo.png"],
outs = ["small_logo.png"],
cmd = "convert $< -resize 100x100 $@",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
Nếu cần đổi kích thước nhiều hình ảnh, bạn có thể muốn sử dụng lại mã. Để làm như vậy,
hãy xác định một hàm trong một tệp .bzl riêng biệt và gọi tệp miniature.bzl:
def miniature(name, src, size="100x100", **kwargs):
"""Create a miniature of the src image.
The generated file is prefixed with 'small_'.
"""
native.genrule(
name = name,
srcs = [src],
outs = ["small_" + src],
cmd = "convert $< -resize " + size + " $@",
**kwargs
)
Một vài nhận xét:
Theo quy ước, macro có đối số
name, giống như quy tắc.Để ghi lại hành vi của một macro, hãy sử dụng chuỗi tài liệu như trong Python.
Để gọi
genrulehoặc bất kỳ quy tắc gốc nào khác, hãy sử dụngnative..Sử dụng
**kwargsđể chuyển tiếp các đối số bổ sung đếngenrulecơ bản (cách này hoạt động giống như trong Python). Điều này rất hữu ích để người dùng có thể sử dụng các thuộc tính chuẩn nhưvisibilityhoặctags.
Bây giờ, hãy sử dụng macro từ tệp BUILD:
load("//path/to:miniature.bzl", "miniature")
miniature(
name = "logo_miniature",
src = "image.png",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)