กรณีการใช้งานทั่วไปของ C++ เกี่ยวกับการสร้าง

ในส่วนนี้ คุณจะได้พบกับกรณีการใช้งานที่พบบ่อยที่สุดสำหรับการสร้างโปรเจ็กต์ C++ ด้วย Bazel หากยังไม่ได้ทำ ให้เริ่มต้นใช้งานการสร้างโปรเจ็กต์ C++ ด้วย Bazel โดยทำตามบทแนะนำเบื้องต้นเกี่ยวกับ Bazel สร้างโปรเจ็กต์ C++

ดูข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs ได้ที่ cc_library

การรวมไฟล์หลายไฟล์ไว้ในเป้าหมายเดียว

คุณสามารถรวมไฟล์หลายไฟล์ไว้ในเป้าหมายเดียวได้ด้วย glob เช่น

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ไม่รวมไดเรกทอรีย่อย)

การใช้การรวมแบบทรานซิทีฟ

หากไฟล์มีการรวมส่วนหัว กฎใดก็ตามที่มีไฟล์นั้นเป็นแหล่งที่มา (นั่นคือ มีไฟล์นั้นอยู่ในแอตทริบิวต์ srcs, hdrs, หรือ textual_hdrs) ควร ขึ้นอยู่กับกฎไลบรารีของส่วนหัวที่รวม ในทางกลับกัน คุณต้องระบุเฉพาะการขึ้นต่อกันโดยตรงเป็นการขึ้นต่อกัน ตัวอย่างเช่น สมมติว่า sandwich.h มีการรวม bread.h และ bread.h มีการรวม flour.h sandwich.h ไม่มีการรวม flour.h (ใครอยากกินแซนวิชที่มีแป้ง) ดังนั้นไฟล์ BUILD จะมีลักษณะดังนี้

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ในที่นี้ ไลบรารี sandwich ขึ้นอยู่กับไลบรารี bread ซึ่งขึ้นอยู่กับไลบรารี flour

การเพิ่มเส้นทางรวม

บางครั้งคุณไม่สามารถ (หรือไม่อยาก) กำหนดเส้นทางรวมที่รูทของพื้นที่ทำงาน ไลบรารีที่มีอยู่อาจมีไดเรกทอรีรวมที่ไม่ตรงกับเส้นทางในพื้นที่ทำงาน ตัวอย่างเช่น สมมติว่าคุณมีโครงสร้างไดเรกทอรีต่อไปนี้

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel จะคาดหวังให้มีการรวม some_lib.h เป็น legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc มีการรวม "some_lib.h" legacy/some_lib/BUILD จะต้องระบุว่าไดเรกทอรี some_lib/include เป็นไดเรกทอรีรวมเพื่อให้เส้นทางรวมนั้นถูกต้อง

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ซึ่งจะเป็นประโยชน์อย่างยิ่งสำหรับการขึ้นต่อกันภายนอก เนื่องจากไฟล์ส่วนหัวของการขึ้นต่อกันภายนอกต้องมีการรวมด้วยคำนำหน้า /

การรวมไลบรารีภายนอก

สมมติว่าคุณใช้ Google Test คุณสามารถใช้ฟังก์ชันที่เก็บอย่างใดอย่างหนึ่งในไฟล์ WORKSPACE เพื่อดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บ

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

จากนั้นสร้าง gtest.BUILD ซึ่งเป็นไฟล์ BUILD ที่ใช้คอมไพล์ Google Test Google Test มีข้อกำหนด "พิเศษ" หลายอย่างที่ทำให้กฎ cc_library ซับซ้อนมากขึ้น ดังนี้

• googletest-release-1.10.0/src/gtest-all.cc #include ไฟล์อื่นๆ ทั้งหมดใน googletest-release-1.10.0/src/ ให้ยกเว้นไฟล์นี้จากการคอมไพล์เพื่อป้องกันข้อผิดพลาดในการลิงก์สำหรับสัญลักษณ์ที่ซ้ำกัน

• ใช้ไฟล์ส่วนหัวที่สัมพันธ์กับไดเรกทอรี googletest-release-1.10.0/include/ ("gtest/gtest.h") ดังนั้นคุณต้อง เพิ่มไดเรกทอรีนั้นลงในเส้นทางรวม

• ต้องลิงก์ใน pthread ดังนั้นให้เพิ่ม pthread เป็น linkopt

ดังนั้นกฎสุดท้ายจึงมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ซึ่งค่อนข้างซับซ้อน เนื่องจากทุกอย่างมีคำนำหน้าเป็น googletest-release-1.10.0 ซึ่งเป็นผลพลอยได้จากโครงสร้างของไฟล์เก็บถาวร คุณสามารถทำให้ http_archive นำคำนำหน้านี้ออกได้โดยการเพิ่มแอตทริบิวต์ strip_prefix

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

จากนั้น gtest.BUILD จะมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ตอนนี้กฎ cc_ สามารถขึ้นอยู่กับ @gtest//:main ได้แล้ว

การเขียนและการเรียกใช้การทดสอบ C++

ตัวอย่างเช่น คุณสามารถสร้างการทดสอบ ./test/hello-test.cc เช่น

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

จากนั้นสร้างไฟล์ ./test/BUILD สำหรับการทดสอบ

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

หากต้องการให้ hello-greet แสดงใน hello-test คุณต้องเพิ่ม "//test:__pkg__", ลงในแอตทริบิวต์ visibility ใน ./main/BUILD

ตอนนี้คุณใช้ bazel test เพื่อเรียกใช้การทดสอบได้แล้ว

bazel test test:hello-test

ซึ่งจะสร้างเอาต์พุตต่อไปนี้

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

การเพิ่มการขึ้นต่อกันในไลบรารีที่คอมไพล์ไว้ล่วงหน้า

หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (เช่น ส่วนหัวและไฟล์ .so) ให้รวมไลบรารีนั้นไว้ในกฎ cc_library

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

วิธีนี้จะทำให้เป้าหมาย C++ อื่นๆ ในพื้นที่ทำงานขึ้นอยู่กับกฎนี้ได้