टेस्ट करना

समस्या की शिकायत करेंopen_in_new सोर्स देखेंopen_in_new ठीक

बेज़ल में स्टारलार्क कोड को टेस्ट करने के कई अलग-अलग तरीके हैं. इस पेज पर, इस्तेमाल के उदाहरण के हिसाब से मौजूदा सबसे सही तरीकों और फ़्रेमवर्क के बारे में जानकारी दी गई है.

जांच के नियम

Skylib में unittest.bzl नाम का एक टेस्ट फ़्रेमवर्क है. यह नियमों के विश्लेषण के समय के व्यवहार की जांच करता है, जैसे कि उनकी कार्रवाइयां और सेवा देने वाली कंपनियां. इस तरह के टेस्ट को "विश्लेषण की जांच" कहा जाता है. फ़िलहाल, ये नियमों के अंदरूनी काम की जांच करने का सबसे अच्छा विकल्प है.

कुछ सावधानियां:

• टेस्ट दावे बिल्ड में होते हैं, न कि एक अलग टेस्ट रनर प्रोसेस. टेस्ट के लिए बनाए गए टारगेट के नाम इस तरह रखने चाहिए कि वे दूसरे टेस्ट के टारगेट या बिल्ड से न टकराएं. टेस्ट के दौरान होने वाली एक गड़बड़ी को बेज़ल, जांच में गड़बड़ी के बजाय एक बिल्ड ब्रेक के तौर पर देखता है.

• इसलिए, टेस्ट किए जा रहे नियमों और दावों वाले नियमों को सेट अप करने के लिए, काफ़ी मात्रा में बॉयलरप्लेट की ज़रूरत होती है. पहली बार में यह बॉयलरप्लेट मुश्किल लग सकता है. इससे यह ध्यान रखने में मदद मिलती है कि लोड होने के दौरान मैक्रो का आकलन किया जाता है और टारगेट जनरेट किए जाते हैं. वहीं, नियम लागू करने के फ़ंक्शन, विश्लेषण के दौरान बाद तक नहीं चलते.

• विश्लेषण की जांच का मकसद है कि यह काफ़ी छोटा और हल्का हो. विश्लेषण टेस्टिंग फ़्रेमवर्क की कुछ सुविधाएं, ज़्यादा से ज़्यादा ट्रांज़िटिव डिपेंडेंसी (फ़िलहाल 500) वाले टारगेट की पुष्टि करने तक सीमित हैं. ऐसा, बड़ी जांचों के साथ इन सुविधाओं का इस्तेमाल करने पर, परफ़ॉर्मेंस पर पड़ने वाले असर की वजह से होता है.

बुनियादी सिद्धांत है जांच के लिए एक नियम तय करना, जो टेस्ट के नियम से तय होता है. इससे, टेस्ट के नियम के तहत, टेस्ट के नियम बनाने वालों को ऐक्सेस मिल जाता है.

जांच के नियम को लागू करने का फ़ंक्शन, दावों को पूरा करता है. अगर कोई गड़बड़ी होती है, तो उसे fail() को कॉल करके तुरंत लागू नहीं किया जाता. इससे, विश्लेषण के समय बिल्ड में गड़बड़ी होगी. इसके बजाय, गड़बड़ियों को जनरेट की गई ऐसी स्क्रिप्ट में सेव किया जाता है जो टेस्ट पूरा नहीं होता.

नीचे खिलौने का एक छोटा सा उदाहरण देखें और उसके बाद कार्रवाइयों की जांच करने का एक उदाहरण देखें.

कम से कम उदाहरण

//mypkg/myrules.bzl:

MyInfo = provider(fields = {
    "val": "string value",
    "out": "output File",
})

def _myrule_impl(ctx):
    """Rule that just generates a file and returns a provider."""
    out = ctx.actions.declare_file(ctx.label.name + ".out")
    ctx.actions.write(out, "abc")
    return [MyInfo(val="some value", out=out)]

myrule = rule(
    implementation = _myrule_impl,
)

//mypkg/myrules_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "analysistest")
load(":myrules.bzl", "myrule", "MyInfo")

# ==== Check the provider contents ====

def _provider_contents_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    # If preferred, could pass these values as "expected" and "actual" keyword
    # arguments.
    asserts.equals(env, "some value", target_under_test[MyInfo].val)

    # If you forget to return end(), you will get an error about an analysis
    # test needing to return an instance of AnalysisTestResultInfo.
    return analysistest.end(env)

# Create the testing rule to wrap the test logic. This must be bound to a global
# variable, not called in a macro's body, since macros get evaluated at loading
# time but the rule gets evaluated later, at analysis time. Since this is a test
# rule, its name must end with "_test".
provider_contents_test = analysistest.make(_provider_contents_test_impl)

# Macro to setup the test.
def _test_provider_contents():
    # Rule under test. Be sure to tag 'manual', as this target should not be
    # built using `:all` except as a dependency of the test.
    myrule(name = "provider_contents_subject", tags = ["manual"])
    # Testing rule.
    provider_contents_test(name = "provider_contents_test",
                           target_under_test = ":provider_contents_subject")
    # Note the target_under_test attribute is how the test rule depends on
    # the real rule target.

# Entry point from the BUILD file; macro for running each test case's macro and
# declaring a test suite that wraps them together.
def myrules_test_suite(name):
    # Call all test functions and wrap their targets in a suite.
    _test_provider_contents()
    # ...

    native.test_suite(
        name = name,
        tests = [
            ":provider_contents_test",
            # ...
        ],
    )

//mypkg/BUILD:

load(":myrules.bzl", "myrule")
load(":myrules_test.bzl", "myrules_test_suite")

# Production use of the rule.
myrule(
    name = "mytarget",
)

# Call a macro that defines targets that perform the tests at analysis time,
# and that can be executed with "bazel test" to return the result.
myrules_test_suite(name = "myrules_test")

यह टेस्ट, bazel test //mypkg:myrules_test की मदद से किया जा सकता है.

शुरुआती load() स्टेटमेंट के अलावा, फ़ाइल के दो मुख्य हिस्से होते हैं:

• खुद को टेस्ट करता है. हर टेस्ट में 1) टेस्टिंग नियम के लिए विश्लेषण-समय लागू करने वाला फ़ंक्शन, 2) analysistest.make() के ज़रिए जांच के नियम की घोषणा, और 3) टेस्ट के तहत नियम (और उसकी डिपेंडेंसी) और जांच के नियम की घोषणा करने के लिए लोडिंग-टाइम फ़ंक्शन (मैक्रो) शामिल है. अगर टेस्ट केस के बीच, दावों में कोई बदलाव नहीं होता, तो 1) और 2) को एक से ज़्यादा टेस्ट केस शेयर कर सकते हैं.

• टेस्ट सुइट फ़ंक्शन, हर जांच के लिए लोड होने में लगने वाले समय के फ़ंक्शन को कॉल करता है. साथ ही, सभी टेस्ट को एक साथ बंडल करने वाले test_suite टारगेट का एलान करता है.

एक जैसा नाम रखने के लिए, सुझाए गए नाम रखने के तरीके का पालन करें: foo को जांच के नाम का वह हिस्सा दिखाएं जिससे पता चलता है कि टेस्ट किस चीज़ की जांच कर रहा है (ऊपर दिए गए उदाहरण में provider_contents). उदाहरण के लिए, JUnit टेस्ट के तरीके का नाम testFoo होगा.

इसके बाद:

• टेस्ट में टेस्ट और टारगेट को जनरेट करने वाले मैक्रो का नाम _test_foo (_test_provider_contents) होना चाहिए

• इसके टेस्ट के नियम का नाम foo_test (provider_contents_test) होना चाहिए

• इस नियम टाइप के टारगेट का लेबल foo_test (provider_contents_test) होना चाहिए

• टेस्टिंग के नियम को लागू करने के फ़ंक्शन का नाम _foo_test_impl (_provider_contents_test_impl) होना चाहिए

• जांच में शामिल नियमों के टारगेट के लेबल और उनकी डिपेंडेंसी के पहले foo_ (provider_contents_) होना चाहिए

ध्यान दें कि सभी टारगेट के लेबल और उसी बिल्ड पैकेज के दूसरे लेबल में अंतर हो सकता है. इसलिए, जांच के लिए यूनीक नाम का इस्तेमाल करना मददगार होता है.

जांच नहीं की जा सकी

इस बात की पुष्टि करना मददगार हो सकता है कि कोई नियम कुछ इनपुट या किसी खास स्थिति में फ़ेल हो जाता है. इसके लिए, विश्लेषण टेस्ट फ़्रेमवर्क का इस्तेमाल करें:

analysistest.make की मदद से बनाए गए जांच के नियम में expect_failure की जानकारी होनी चाहिए:

failure_testing_test = analysistest.make(
    _failure_testing_test_impl,
    expect_failure = True,
)

जांच के नियम को लागू करने के दौरान, इस बात का दावा किया जाना चाहिए कि किस तरह की गड़बड़ी हुई है (खास तौर पर, गड़बड़ी का मैसेज):

def _failure_testing_test_impl(ctx):
    env = analysistest.begin(ctx)
    asserts.expect_failure(env, "This rule should never work")
    return analysistest.end(env)

यह भी पक्का करें कि टेस्ट में आपका टारगेट, खास तौर पर 'मैन्युअल' के तौर पर टैग किया गया हो. ऐसा न करने पर, :all का इस्तेमाल करके अपने पैकेज में सभी टारगेट बनाने से, जान-बूझकर काम न करने वाला टारगेट बिल्ड होगा. साथ ही, बिल्ड फ़ेल हो जाएगा. 'मैन्युअल' की मदद से, टेस्ट में शामिल आपका टारगेट सिर्फ़ तब तैयार होगा, जब साफ़ तौर पर इसके बारे में बताया गया हो या यह मैन्युअल तौर पर नहीं किए गए टारगेट (जैसे कि टेस्ट के नियम) की डिपेंडेंसी के तौर पर हो:

def _test_failure():
    myrule(name = "this_should_fail", tags = ["manual"])

    failure_testing_test(name = "failure_testing_test",
                         target_under_test = ":this_should_fail")

# Then call _test_failure() in the macro which generates the test suite and add
# ":failure_testing_test" to the suite's test targets.

रजिस्टर की गई कार्रवाइयों की पुष्टि की जा रही है

हो सकता है कि आप ऐसे टेस्ट लिखना चाहें जो आपके नियम के मुताबिक रजिस्टर की गई कार्रवाइयों के बारे में दावे करें. उदाहरण के लिए, ctx.actions.run() का इस्तेमाल करके. यह काम विश्लेषण की जांच करने के नियम को लागू करने वाले फ़ंक्शन में किया जा सकता है. एक उदाहरण:

def _inspect_actions_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    actions = analysistest.target_actions(env)
    asserts.equals(env, 1, len(actions))
    action_output = actions[0].outputs.to_list()[0]
    asserts.equals(
        env, target_under_test.label.name + ".out", action_output.basename)
    return analysistest.end(env)

ध्यान दें कि analysistest.target_actions(env), Action ऑब्जेक्ट की सूची दिखाता है. ये ऑब्जेक्ट, टेस्ट के तहत टारगेट से रजिस्टर की गई कार्रवाइयों को दिखाते हैं.

अलग-अलग फ़्लैग के तहत नियम के व्यवहार की पुष्टि करना

शायद आप इस बात की पुष्टि करना चाहें कि आपका असली नियम, कुछ बिल्ड फ़्लैग के आधार पर तय तरीके से काम करता है. उदाहरण के लिए, अगर कोई उपयोगकर्ता यह तय करता है, तो आपका नियम अलग तरह से काम कर सकता है:

bazel build //mypkg:real_target -c opt

बनाम

bazel build //mypkg:real_target -c dbg

पहली नज़र में, अपने हिसाब से बनाए गए बिल्ड फ़्लैग का इस्तेमाल करके, टेस्ट में टारगेट की जांच की जा सकती है.

bazel test //mypkg:myrules_test -c opt

हालांकि, इसके बाद आपके टेस्ट सुइट के लिए एक साथ एक टेस्ट शामिल करना नामुमकिन हो जाता है. यह टेस्ट, -c opt में नियम के व्यवहार की पुष्टि करता है. दूसरा टेस्ट, जो -c dbg के तहत नियम के व्यवहार की पुष्टि करता है. दोनों टेस्ट एक ही बिल्ड में नहीं हो सकते!

टेस्ट रूल तय करते समय, अपनी पसंद के बिल्ड फ़्लैग बताकर इस समस्या को हल किया जा सकता है:

myrule_c_opt_test = analysistest.make(
    _myrule_c_opt_test_impl,
    config_settings = {
        "//command_line_option:compilation_mode": "opt",
    },
)

आम तौर पर, टेस्ट किए जा रहे टारगेट का विश्लेषण, मौजूदा बिल्ड फ़्लैग के आधार पर किया जाता है. config_settings को तय करने से, दिए गए कमांड लाइन विकल्पों की वैल्यू बदल जाती हैं. (ऐसा कोई भी विकल्प जिसकी जानकारी नहीं है, वह असल कमांड लाइन से अपनी वैल्यू बनाए रखेगा).

बताए गए config_settings डिक्शनरी में, कमांड लाइन फ़्लैग के आगे एक खास प्लेसहोल्डर वैल्यू //command_line_option: होनी चाहिए, जैसा कि ऊपर दिखाया गया है.

आर्टफ़ैक्ट की पुष्टि करना

जनरेट की गई फ़ाइलें सही हैं या नहीं, यह पता करने के कुछ मुख्य तरीके यहां दिए गए हैं:

• आपके पास शेल, Python या किसी दूसरी भाषा में टेस्ट स्क्रिप्ट लिखने और *_test नियम के सही टाइप को टारगेट करने का विकल्प होता है.

• आपको जिस तरह की जांच करनी है उसके लिए खास नियम का इस्तेमाल किया जा सकता है.

टेस्ट टारगेट का इस्तेमाल करना

आर्टफ़ैक्ट की पुष्टि करने का सबसे आसान तरीका यह है कि आप स्क्रिप्ट लिखें और अपनी BUILD फ़ाइल में *_test टारगेट जोड़ें. आपको जिन आर्टफ़ैक्ट की जांच करनी है वे इस टारगेट के डेटा पर निर्भर होने चाहिए. अगर एक से ज़्यादा टेस्ट के लिए, पुष्टि करने वाला लॉजिक फिर से इस्तेमाल किया जा सकता है, तो यह एक ऐसी स्क्रिप्ट होनी चाहिए जो कमांड लाइन वाले तर्क लेते हों और जिन्हें टेस्ट टारगेट के args एट्रिब्यूट से कंट्रोल किया जाता हो. यहां एक उदाहरण दिया गया है, जो पुष्टि करता है कि ऊपर बताए गए myrule का आउटपुट "abc" है.

//mypkg/myrule_validator.sh:

if [ "$(cat $1)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed for each target whose artifacts are to be checked.
sh_test(
    name = "validate_mytarget",
    srcs = [":myrule_validator.sh"],
    args = ["$(location :mytarget.out)"],
    data = [":mytarget.out"],
)

कस्टम नियम का इस्तेमाल करना

एक ज़्यादा जटिल विकल्प शेल स्क्रिप्ट को एक ऐसे टेंप्लेट के रूप में लिखना है जो नए नियम से इंस्टैंशिएट हो जाता है. इसमें ज़्यादा इन्डायरेक्ट और Starlark लॉजिक शामिल है. हालांकि, इससे BUILD फ़ाइलें ज़्यादा साफ़ हो जाती हैं. इसका एक साइड फ़ायदा यह भी है कि किसी भी तरह के आर्ग्युमेंट की प्री-प्रोसेसिंग, स्क्रिप्ट के बजाय Starlark में की जा सकती है. स्क्रिप्ट खुद ही दस्तावेज़ों की तरह ज़्यादा होती है. इसकी वजह यह है कि इसमें वैल्यू वाले प्लेसहोल्डर (तर्क के लिए) के बजाय, सिंबल वाले प्लेसहोल्डर (विकल्पों के लिए) का इस्तेमाल किया जाता है.

//mypkg/myrule_validator.sh.template:

if [ "$(cat %TARGET%)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/myrule_validation.bzl:

def _myrule_validation_test_impl(ctx):
  """Rule for instantiating myrule_validator.sh.template for a given target."""
  exe = ctx.outputs.executable
  target = ctx.file.target
  ctx.actions.expand_template(output = exe,
                              template = ctx.file._script,
                              is_executable = True,
                              substitutions = {
                                "%TARGET%": target.short_path,
                              })
  # This is needed to make sure the output file of myrule is visible to the
  # resulting instantiated script.
  return [DefaultInfo(runfiles=ctx.runfiles(files=[target]))]

myrule_validation_test = rule(
    implementation = _myrule_validation_test_impl,
    attrs = {"target": attr.label(allow_single_file=True),
             # You need an implicit dependency in order to access the template.
             # A target could potentially override this attribute to modify
             # the test logic.
             "_script": attr.label(allow_single_file=True,
                                   default=Label("//mypkg:myrule_validator"))},
    test = True,
)

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed just once, to expose the template. Could have also used export_files(),
# and made the _script attribute set allow_files=True.
filegroup(
    name = "myrule_validator",
    srcs = [":myrule_validator.sh.template"],
)

# Needed for each target whose artifacts are to be checked. Notice that you no
# longer have to specify the output file name in a data attribute, or its
# $(location) expansion in an args attribute, or the label for the script
# (unless you want to override it).
myrule_validation_test(
    name = "validate_mytarget",
    target = ":mytarget",
)

इसके अलावा, टेंप्लेट एक्सपैंशन ऐक्शन का इस्तेमाल करने के बजाय, टेंप्लेट को स्ट्रिंग के तौर पर .bzl फ़ाइल में इनलाइन किया जा सकता था. साथ ही, विश्लेषण के दौरान str.format तरीके या % फ़ॉर्मैट का इस्तेमाल करके उसे बड़ा किया जा सकता था.

Starlark की सुविधाओं की जांच की जा रही है

Skylib के unittest.bzl फ़्रेमवर्क का इस्तेमाल यूटिलिटी फ़ंक्शन (इसका मतलब है कि ऐसे फ़ंक्शन जो न तो मैक्रो हैं और न ही नियम लागू करना है) की जांच करने के लिए इस्तेमाल किया जा सकता है. unittest.bzl की analysistest लाइब्रेरी के बजाय, unittest का इस्तेमाल किया जा सकता है. ऐसे टेस्ट सुइट के लिए, सुविधा फ़ंक्शन unittest.suite() का इस्तेमाल बॉयलरप्लेट को कम करने के लिए किया जा सकता है.

//mypkg/myhelpers.bzl:

def myhelper():
    return "abc"

//mypkg/myhelpers_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "unittest")
load(":myhelpers.bzl", "myhelper")

def _myhelper_test_impl(ctx):
  env = unittest.begin(ctx)
  asserts.equals(env, "abc", myhelper())
  return unittest.end(env)

myhelper_test = unittest.make(_myhelper_test_impl)

# No need for a test_myhelper() setup function.

def myhelpers_test_suite(name):
  # unittest.suite() takes care of instantiating the testing rules and creating
  # a test_suite.
  unittest.suite(
    name,
    myhelper_test,
    # ...
  )

//mypkg/BUILD:

load(":myhelpers_test.bzl", "myhelpers_test_suite")

myhelpers_test_suite(name = "myhelpers_tests")

ज़्यादा उदाहरणों के लिए, Skylib के टेस्ट देखें.