BazelCon 2024 등록이 시작되었습니다

이 페이지는 Cloud Translation API를 통해 번역되었습니다.

Bazel 튜토리얼: 자바 프로젝트 빌드

7.3 · 7.2 · 7.1 · 7.0 · 6.5

이 튜토리얼에서는 Bazel을 사용하여 Java 애플리케이션을 빌드하는 기본사항을 다룹니다. 작업공간을 설정하고 대상 및 BUILD 파일과 같은 주요 Bazel 개념을 보여주는 간단한 Java 프로젝트를 빌드합니다.

예상 완료 시간: 30분

학습할 내용

이 튜토리얼에서는 다음을 수행하는 방법을 알아봅니다.

타겟 빌드
프로젝트의 종속 항목 시각화
프로젝트를 여러 대상과 패키지로 분할
패키지 전반에서 타겟 공개 상태 제어
라벨을 통해 타겟 참조
대상 배포

시작하기 전에

Bazel 설치

튜토리얼을 준비하려면 먼저 Bazel을 설치합니다(아직 설치하지 않은 경우).

JDK 설치

Java JDK를 설치합니다 (권장 버전은 11이지만 8~15 버전이 지원됨).
JAVA_HOME 환경 변수를 JDK를 가리키도록 설정합니다.
- Linux/macOS:
```
export JAVA_HOME="$(dirname $(dirname $(realpath $(which javac))))"
```
- Windows:
  1. 제어판을 엽니다.
  2. '시스템 및 보안' > '시스템' > '고급 시스템 설정' > '고급' 탭 > '환경 변수...'로 이동합니다. .
  3. '사용자 변수' 목록(상단에 있는 목록)에서 '새로 만들기'를 클릭합니다.
  4. '변수 이름' 필드에 JAVA_HOME을 입력합니다.
  5. '디렉터리 탐색...'을 클릭합니다.
  6. JDK 디렉터리(예: C:\Program Files\Java\jdk1.8.0_152)로 이동합니다.
  7. 모든 대화상자 창에서 '확인'을 클릭합니다.

샘플 프로젝트 가져오기

Bazel의 GitHub 저장소에서 샘플 프로젝트를 가져옵니다.

git clone https://github.com/bazelbuild/examples

이 튜토리얼의 샘플 프로젝트는 examples/java-tutorial 디렉터리에 있으며 다음과 같이 구성됩니다.

java-tutorial
├── BUILD
├── src
│   └── main
│       └── java
│           └── com
│               └── example
│                   ├── cmdline
│                   │   ├── BUILD
│                   │   └── Runner.java
│                   ├── Greeting.java
│                   └── ProjectRunner.java
└── MODULE.bazel

Bazel을 사용하여 빌드

작업공간 설정

프로젝트를 빌드하려면 먼저 작업공간을 설정해야 합니다. 워크스페이스는 프로젝트의 소스 파일과 Bazel의 빌드 출력을 보관하는 디렉터리입니다. Bazel이 특수로 인식하는 파일도 포함되어 있습니다.

MODULE.bazel 파일: 디렉터리와 디렉터리의 콘텐츠를 Bazel 작업공간으로 식별하고 프로젝트 디렉터리 구조의 루트에 있습니다.
하나 이상의 BUILD 파일: Bazel에 프로젝트의 여러 부분을 빌드하는 방법을 알려줍니다. BUILD 파일이 포함된 작업공간 내 디렉터리는 패키지입니다. 패키지에 대해서는 이 튜토리얼의 뒷부분에서 알아봅니다.)

디렉터리를 Bazel 워크스페이스로 지정하려면 해당 디렉터리에 MODULE.bazel라는 빈 파일을 만듭니다.

Bazel이 프로젝트를 빌드할 때 모든 입력과 종속 항목이 동일한 워크스페이스에 있어야 합니다. 서로 다른 워크스페이스에 있는 파일은 연결되지 않는 한 서로 독립적입니다. 연결은 이 튜토리얼의 범위를 벗어납니다.

BUILD 파일 이해하기

BUILD 파일에는 Bazel에 관한 여러 유형의 안내가 포함되어 있습니다. 가장 중요한 유형은 빌드 규칙으로, 실행 파일 바이너리 또는 라이브러리와 같은 원하는 출력을 빌드하는 방법을 Bazel에 알려줍니다. BUILD 파일의 빌드 규칙의 각 인스턴스는 타겟이라고 하며 특정 소스 파일 및 종속 항목 집합을 가리킵니다. 타겟은 다른 타겟을 가리킬 수도 있습니다.

java-tutorial/BUILD 파일을 살펴봅니다.

java_binary(
    name = "ProjectRunner",
    srcs = glob(["src/main/java/com/example/*.java"]),
)

이 예에서 ProjectRunner 타겟은 Bazel의 내장 java_binary 규칙을 인스턴스화합니다. 이 규칙은 Bazel에 .jar 파일과 래퍼 셸 스크립트(둘 다 타겟의 이름을 따름)를 빌드하도록 지시합니다.

타겟의 속성은 종속 항목과 옵션을 명시적으로 명시합니다. name 속성은 필수이지만 많은 속성은 선택사항입니다. 예를 들어 ProjectRunner 규칙 대상에서 name은 대상 이름이고 srcs는 Bazel이 대상을 빌드하는 데 사용하는 소스 파일을 지정하며 main_class은 기본 메서드가 포함된 클래스를 지정합니다. 이 예에서는 glob을 사용하여 소스 파일 세트를 하나씩 나열하는 대신 Bazel에 전달합니다.

프로젝트 빌드

샘플 프로젝트를 빌드하려면 java-tutorial 디렉터리로 이동하여 다음을 실행합니다.

bazel build //:ProjectRunner

타겟 라벨에서 // 부분은 작업공간의 루트(이 경우에는 루트 자체)를 기준으로 한 BUILD 파일의 위치이고 ProjectRunner는 BUILD 파일의 타겟 이름입니다. 타겟 라벨에 관한 자세한 내용은 이 튜토리얼의 끝부분에서 알아봅니다.

Bazel은 다음과 비슷한 출력을 생성합니다.

   INFO: Found 1 target...
   Target //:ProjectRunner up-to-date:
      bazel-bin/ProjectRunner.jar
      bazel-bin/ProjectRunner
   INFO: Elapsed time: 1.021s, Critical Path: 0.83s

축하합니다. 첫 번째 Bazel 대상을 빌드했습니다. Bazel은 빌드 출력을 작업공간 루트의 bazel-bin 디렉터리에 배치합니다. 콘텐츠를 둘러보고 Bazel의 출력 구조에 관해 알아보세요.

이제 새로 빌드된 바이너리를 테스트합니다.

bazel-bin/ProjectRunner

종속 항목 그래프 검토

Bazel에서는 빌드 종속 항목을 BUILD 파일에 명시적으로 선언해야 합니다. Bazel은 이러한 문을 사용하여 프로젝트의 종속 항목 그래프를 만들고 이를 통해 정확한 증분 빌드를 지원합니다.

샘플 프로젝트의 종속 항목을 시각화하려면 작업공간 루트에서 다음 명령어를 실행하여 종속 항목 그래프의 텍스트 표현을 생성하면 됩니다.

bazel query  --notool_deps --noimplicit_deps "deps(//:ProjectRunner)" --output graph

위 명령어는 Bazel에 호스트 및 암시적 종속 항목을 제외한 타겟 //:ProjectRunner의 모든 종속 항목을 찾고 출력을 그래프로 형식 지정하라고 지시합니다.

그런 다음 텍스트를 GraphViz에 붙여넣습니다.

보시다시피 프로젝트에는 추가 종속 항목 없이 두 개의 소스 파일을 빌드하는 단일 타겟이 있습니다.

타겟 'ProjectRunner'의 종속 항목 그래프

워크스페이스를 설정하고 프로젝트를 빌드하고 종속 항목을 검사한 후 약간의 복잡성을 추가할 수 있습니다.

Bazel 빌드 미세 조정

소규모 프로젝트에는 단일 타겟으로 충분하지만, 대규모 프로젝트는 빠른 증분 빌드 (즉, 변경된 부분만 다시 빌드)를 사용하고 프로젝트의 여러 부분을 한 번에 빌드하여 빌드 속도를 높이기 위해 여러 타겟과 패키지로 분할하는 것이 좋습니다.

여러 빌드 대상 지정

샘플 프로젝트 빌드를 두 개의 대상으로 분할할 수 있습니다. java-tutorial/BUILD 파일의 콘텐츠를 다음으로 바꿉니다.

java_binary(
    name = "ProjectRunner",
    srcs = ["src/main/java/com/example/ProjectRunner.java"],
    main_class = "com.example.ProjectRunner",
    deps = [":greeter"],
)

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
)

이 구성을 사용하면 Bazel은 먼저 greeter 라이브러리를 빌드한 다음 ProjectRunner 바이너리를 빌드합니다. java_binary의 deps 속성은 ProjectRunner 바이너리를 빌드하는 데 greeter 라이브러리가 필요하다고 Bazel에 알립니다.

이 새 버전의 프로젝트를 빌드하려면 다음 명령어를 실행합니다.

bazel build //:ProjectRunner

Bazel은 다음과 유사한 출력을 생성합니다.

INFO: Found 1 target...
Target //:ProjectRunner up-to-date:
  bazel-bin/ProjectRunner.jar
  bazel-bin/ProjectRunner
INFO: Elapsed time: 2.454s, Critical Path: 1.58s

이제 새로 빌드된 바이너리를 테스트합니다.

bazel-bin/ProjectRunner

이제 ProjectRunner.java를 수정하고 프로젝트를 다시 빌드하면 Bazel은 해당 파일만 다시 컴파일합니다.

종속 항목 그래프를 보면 ProjectRunner가 이전과 동일한 입력에 종속되지만 빌드의 구조는 다릅니다.

종속 항목을 추가한 후 타겟 'ProjectRunner'의 종속 항목 그래프

이제 두 개의 타겟으로 프로젝트를 빌드했습니다. ProjectRunner 타겟은 소스 파일 하나를 빌드하고 소스 파일 하나를 추가로 빌드하는 다른 타겟 (:greeter) 하나에 종속됩니다.

여러 패키지 사용

이제 프로젝트를 여러 패키지로 분할해 보겠습니다. src/main/java/com/example/cmdline 디렉터리를 살펴보면 BUILD 파일과 일부 소스 파일도 포함되어 있습니다. 따라서 Bazel에게 작업공간에 이제 //src/main/java/com/example/cmdline와 //라는 두 개의 패키지가 포함됩니다 (작업공간의 루트에 BUILD 파일이 있기 때문).

src/main/java/com/example/cmdline/BUILD 파일을 살펴보세요.

java_binary(
    name = "runner",
    srcs = ["Runner.java"],
    main_class = "com.example.cmdline.Runner",
    deps = ["//:greeter"],
)

runner 타겟은 // 패키지의 greeter 타겟에 종속되므로 타겟 라벨은 //:greeter입니다. Bazel은 deps 속성을 통해 이를 인식합니다. 종속 항목 그래프를 살펴보세요.

타겟 'runner'의 종속 항목 그래프

그러나 빌드가 성공하려면 visibility 속성을 사용하여 //src/main/java/com/example/cmdline/BUILD의 runner 타겟에 //BUILD의 타겟에 대한 공개 상태를 명시적으로 부여해야 합니다. 기본적으로 타겟은 동일한 BUILD 파일의 다른 타겟에만 표시되기 때문입니다. Bazel은 타겟 공개 상태를 사용하여 구현 세부정보가 포함된 라이브러리가 공개 API로 유출되는 등의 문제를 방지합니다.

이렇게 하려면 아래와 같이 visibility 속성을 java-tutorial/BUILD의 greeter 타겟에 추가합니다.

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
    visibility = ["//src/main/java/com/example/cmdline:__pkg__"],
)

이제 작업공간의 루트에서 다음 명령어를 실행하여 새 패키지를 빌드할 수 있습니다.

bazel build //src/main/java/com/example/cmdline:runner

Bazel은 다음과 유사한 출력을 생성합니다.

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner.jar
  bazel-bin/src/main/java/com/example/cmdline/runner
  INFO: Elapsed time: 1.576s, Critical Path: 0.81s

이제 새로 빌드된 바이너리를 테스트합니다.

./bazel-bin/src/main/java/com/example/cmdline/runner

이제 프로젝트를 수정하여 각각 하나의 타겟을 포함하는 두 개의 패키지로 빌드하고 두 패키지 간의 종속 항목을 이해했습니다.

라벨을 사용하여 타겟 참조

BUILD 파일과 명령줄에서 Bazel은 대상 라벨을 사용하여 대상을 참조합니다(예: //:ProjectRunner 또는 //src/main/java/com/example/cmdline:runner). 구문은 다음과 같습니다.

//path/to/package:target-name

타겟이 규칙 타겟인 경우 path/to/package는 BUILD 파일이 포함된 디렉터리의 경로이고 target-name는 BUILD 파일에서 타겟의 이름(name 속성)입니다. 타겟이 파일 타겟인 경우 path/to/package는 패키지의 루트 경로이고 target-name은 전체 경로를 포함한 타겟 파일의 이름입니다.

저장소 루트에서 타겟을 참조할 때는 패키지 경로가 비어 있으므로 //:target-name만 사용하면 됩니다. 동일한 BUILD 파일 내에서 타겟을 참조할 때는 // 작업공간 루트 식별자를 건너뛰고 :target-name만 사용할 수도 있습니다.

예를 들어 java-tutorial/BUILD 파일의 타겟의 경우 패키지 경로를 지정할 필요가 없습니다. 워크스페이스 루트 자체가 패키지 (//)이고 두 타겟 라벨이 단순히 //:ProjectRunner 및 //:greeter이기 때문입니다.

그러나 //src/main/java/com/example/cmdline/BUILD 파일의 타겟의 경우 //src/main/java/com/example/cmdline의 전체 패키지 경로를 지정해야 했고 타겟 라벨은 //src/main/java/com/example/cmdline:runner였습니다.

배포할 Java 타겟 패키징

이제 모든 런타임 종속 항목이 있는 바이너리를 빌드하여 배포할 자바 타겟을 패키징해 보겠습니다. 이렇게 하면 개발 환경 외부에서 바이너리를 실행할 수 있습니다.

java_binary 빌드 규칙은 .jar 및 래퍼 셸 스크립트를 생성합니다. 다음 명령어를 사용하여 runner.jar의 콘텐츠를 살펴봅니다.

jar tf bazel-bin/src/main/java/com/example/cmdline/runner.jar

콘텐츠는 다음과 같습니다.

META-INF/
META-INF/MANIFEST.MF
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class

보시다시피 runner.jar에는 Runner.class가 포함되어 있지만 종속 항목인 Greeting.class는 포함되어 있지 않습니다. Bazel이 생성하는 runner 스크립트는 클래스 경로에 greeter.jar를 추가하므로 이 스크립트를 그대로 두면 로컬에서 실행되지만 다른 머신에서 독립형으로 실행되지는 않습니다. 다행히 java_binary 규칙을 사용하면 배포 가능한 독립형 바이너리를 빌드할 수 있습니다. 빌드하려면 대상 이름에 _deploy.jar를 추가합니다.

bazel build //src/main/java/com/example/cmdline:runner_deploy.jar

Bazel은 다음과 유사한 출력을 생성합니다.

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner_deploy.jar up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar
INFO: Elapsed time: 1.700s, Critical Path: 0.23s

필요한 런타임 종속 항목이 포함되어 있으므로 개발 환경 외부에서 독립형으로 실행할 수 있는 runner_deploy.jar를 빌드했습니다. 이전과 동일한 명령어를 사용하여 이 독립형 JAR의 콘텐츠를 살펴봅니다.

jar tf bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar

콘텐츠에는 실행하는 데 필요한 모든 클래스가 포함됩니다.

META-INF/
META-INF/MANIFEST.MF
build-data.properties
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class
com/example/Greeting.class

추가 자료

자세한 내용은 다음을 참고하세요.

rules_jvm_external에서 전이 Maven 종속 항목을 관리하는 규칙을 확인할 수 있습니다.
외부 종속 항목: 로컬 저장소 및 원격 저장소로 작업하는 방법을 자세히 알아봅니다.
Bazel에 대해 자세히 알아볼 수 있는 기타 규칙
Bazel을 사용하여 C++ 프로젝트 빌드를 시작하는 방법을 알아보는 C++ 빌드 튜토리얼
Bazel로 Android 및 iOS용 모바일 애플리케이션 빌드를 시작하려면 Android 애플리케이션 튜토리얼 및 iOS 애플리케이션 튜토리얼을 참고하세요.

즐겁게 빌드하세요!