บทแนะนำ Bazel: กำหนดค่าเชนเครื่องมือ C++

รายงานปัญหา ดูแหล่งที่มา Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

บทแนะนำนี้ใช้สถานการณ์ตัวอย่างเพื่ออธิบายวิธีกำหนดค่าชุดเครื่องมือ C++ สำหรับโปรเจ็กต์ โดยอิงตามโปรเจ็กต์ C++ ตัวอย่าง ที่สร้างโดยใช้ clang โดยไม่มีข้อผิดพลาด

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีทำสิ่งต่อไปนี้

  • ตั้งค่าสภาพแวดล้อมของบิลด์
  • กำหนดค่าเครื่องมือ C++
  • สร้างกฎ Starlark ที่ให้การกำหนดค่าเพิ่มเติม สำหรับ cc_toolchain เพื่อให้ Bazel สามารถสร้างแอปพลิเคชัน ด้วย clang
  • ยืนยันผลลัพธ์ที่คาดไว้โดยเรียกใช้ bazel build --config=clang_config //main:hello-world ในเครื่อง Linux
  • สร้างแอปพลิเคชัน C++

ก่อนเริ่มต้น

ตั้งค่าสภาพแวดล้อมของบิลด์

บทแนะนำนี้ถือว่าคุณใช้ Linux และสร้างแอปพลิเคชัน C++ ได้สำเร็จ รวมถึงติดตั้งเครื่องมือและไลบรารีที่เหมาะสม บทแนะนำนี้ใช้ clang version 9.0.1 ซึ่งคุณติดตั้งในระบบได้

ตั้งค่าสภาพแวดล้อมการสร้างดังนี้

  1. หากยังไม่ได้ดำเนินการ ให้ดาวน์โหลดและติดตั้ง Bazel 0.23 ขึ้นไป

  2. ดาวน์โหลดโปรเจ็กต์ C++ ตัวอย่าง จาก GitHub แล้ววางไว้ในไดเรกทอรีว่างในเครื่องของคุณ

  3. เพิ่มเป้าหมาย cc_binary ต่อไปนี้ลงในไฟล์ main/BUILD

    cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

  4. สร้างไฟล์ .bazelrc ที่รูทของไดเรกทอรีพื้นที่ทำงานโดยมีเนื้อหาต่อไปนี้เพื่อเปิดใช้แฟล็ก --config

    # Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

สำหรับรายการ build:{config_name} --flag=value ระบบจะเชื่อมโยง Flag บรรทัดคำสั่ง --config={config_name} กับ Flag นั้น ดู เอกสารประกอบสำหรับค่าสถานะที่ใช้ crosstool_top cpu และ host_crosstool_top

เมื่อสร้างเป้าหมาย ด้วย bazel build --config=clang_config //main:hello-world Bazel จะใช้ ชุดเครื่องมือที่กำหนดเองจาก cc_toolchain_suite //toolchain:clang_suite ชุดเครื่องมืออาจแสดงเครื่องมือเชนที่แตกต่างกันสำหรับ CPU ที่แตกต่างกัน และนั่นคือเหตุผลที่แยกความแตกต่างด้วยแฟล็ก --cpu=k8

เนื่องจาก Bazel ใช้เครื่องมือภายในหลายอย่างที่เขียนด้วย C++ ในระหว่างการบิลด์ เช่น process-wrapper จึงมีการระบุ Toolchain C++ เริ่มต้นที่มีอยู่ก่อนแล้วสำหรับ แพลตฟอร์มโฮสต์ เพื่อให้เครื่องมือเหล่านี้สร้างขึ้นโดยใช้ Toolchain นั้นแทน Toolchain ที่สร้างขึ้นในบทแนะนำนี้

การกำหนดค่าเครื่องมือ C++

หากต้องการกำหนดค่า Toolchain ของ C++ ให้สร้างแอปพลิเคชันซ้ำๆ และกำจัด ข้อผิดพลาดแต่ละรายการทีละรายการตามที่อธิบายไว้ด้านล่าง

  1. เรียกใช้บิลด์ด้วยคำสั่งต่อไปนี้

    bazel build --config=clang_config //main:hello-world

    เนื่องจากคุณระบุ --crosstool_top=//toolchain:clang_suite ในไฟล์ .bazelrc Bazel จึงแสดงข้อผิดพลาดต่อไปนี้

    No such package `toolchain`: BUILD file not found on package path.

    ในไดเรกทอรีพื้นที่ทำงาน ให้สร้างไดเรกทอรี toolchain สำหรับแพ็กเกจ และไฟล์ BUILD ที่ว่างเปล่าภายในไดเรกทอรี toolchain

  2. เรียกใช้บิลด์อีกครั้ง เนื่องจากแพ็กเกจ toolchain ยังไม่ได้กำหนดเป้าหมาย clang_suite Bazel จึงแสดงข้อผิดพลาดต่อไปนี้

    No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD

    ในไฟล์ toolchain/BUILD ให้กำหนดกลุ่มไฟล์ว่างดังนี้

    package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")

  3. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

    '//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'

    Bazel พบว่าแฟล็ก --crosstool_top ชี้ไปยังกฎที่ไม่ได้ระบุผู้ให้บริการ ToolchainInfo ที่จำเป็น ดังนั้นคุณต้องชี้--crosstool_topไปที่กฎที่ให้ ToolchainInfo - นั่นคือกฎ cc_toolchain_suite ในไฟล์ toolchain/BUILD ให้แทนที่ filegroup ที่ว่างเปล่าด้วยข้อความต่อไปนี้

    cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)

    แอตทริบิวต์ toolchains จะแมปค่าของ --cpu (และ --compiler ด้วยเมื่อระบุ) กับ cc_toolchain โดยอัตโนมัติ คุณยังไม่ได้ กำหนดเป้าหมาย cc_toolchain และ Bazel จะแจ้งข้อผิดพลาดเกี่ยวกับเรื่องนี้ ในอีกไม่นาน

  4. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

    Rule '//toolchain:k8_toolchain' does not exist

    ตอนนี้คุณต้องกำหนดcc_toolchainเป้าหมายสำหรับทุกค่าในแอตทริบิวต์ cc_toolchain_suite.toolchains เพิ่มข้อมูลต่อไปนี้ลงในไฟล์ toolchain/BUILD

    filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

  5. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

    Rule '//toolchain:k8_toolchain_config' does not exist

    จากนั้นเพิ่มเป้าหมาย ":k8_toolchain_config" ลงในไฟล์ toolchain/BUILD ดังนี้

    filegroup(name = "k8_toolchain_config")

  6. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

    '//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'

    CcToolchainConfigInfo คือผู้ให้บริการที่คุณใช้เพื่อกำหนดค่า ชุดเครื่องมือ C++ หากต้องการแก้ไขข้อผิดพลาดนี้ ให้สร้างกฎ Starlark ที่ระบุ CcToolchainConfigInfo ให้กับ Bazel โดยสร้างไฟล์ toolchain/cc_toolchain_config.bzl ที่มีเนื้อหาต่อไปนี้

    def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

    cc_common.create_cc_toolchain_config_info() สร้างผู้ให้บริการที่จำเป็น CcToolchainConfigInfo หากต้องการใช้cc_toolchain_configกฎ ให้เพิ่มคำสั่ง load ไปยังtoolchain/BUILD ใต้คำสั่ง package โดยตรง

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")

    และแทนที่ filegroup "k8_toolchain_config" ด้วยการประกาศกฎ cc_toolchain_config

    cc_toolchain_config(name = "k8_toolchain_config")

  7. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

    ตอนนี้ Bazel มีข้อมูลเพียงพอที่จะพยายามสร้างโค้ด แต่ก็ยังไม่ทราบว่าจะใช้เครื่องมือใดเพื่อดำเนินการสร้างที่จำเป็นให้เสร็จสมบูรณ์ คุณจะแก้ไขการติดตั้งใช้งานกฎ Starlark เพื่อบอก Bazel ว่าจะใช้เครื่องมือใด คุณต้องใช้ตัวสร้าง tool_path() จาก @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl

    # toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

    ตรวจสอบว่า /usr/bin/clang และ /usr/bin/ld เป็นเส้นทางที่ถูกต้อง สำหรับระบบของคุณ

  8. เรียกใช้บิลด์อีกครั้ง Bazel จะแสดงข้อผิดพลาดต่อไปนี้

     ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....

    Bazel ต้องทราบตำแหน่งที่จะค้นหาส่วนหัวที่รวมไว้ ปัญหานี้แก้ไขได้หลายวิธี เช่น การใช้แอตทริบิวต์ includes ของ cc_binary แต่ในที่นี้จะแก้ไขที่ระดับเครื่องมือด้วยพารามิเตอร์ cxx_builtin_include_directories ของ cc_common.create_cc_toolchain_config_info โปรดทราบว่าหากคุณใช้ clang เวอร์ชันอื่น เส้นทางรวมจะแตกต่างกัน เส้นทางเหล่านี้อาจแตกต่างกันไปตามการจัดจำหน่ายด้วย

    แก้ไขค่าที่ส่งคืนใน toolchain/cc_toolchain_config.bzl ให้มีลักษณะดังนี้

     return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )

  9. เรียกใช้คำสั่งบิลด์อีกครั้ง คุณจะเห็นข้อผิดพลาดดังนี้

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

    สาเหตุคือ Linker ไม่มีไลบรารีมาตรฐาน C++ และไม่พบสัญลักษณ์ของไลบรารี คุณสามารถแก้ไขปัญหานี้ได้หลายวิธี เช่น การใช้แอตทริบิวต์ linkopts ของ cc_binary เราแก้ไขปัญหานี้โดย ตรวจสอบว่าเป้าหมายใดก็ตามที่ใช้ Toolchain ไม่จำเป็นต้องระบุ แฟล็กนี้

    คัดลอกโค้ดต่อไปนี้ไปยัง cc_toolchain_config.bzl

      # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

  10. หากคุณเรียกใช้ bazel build --config=clang_config //main:hello-world ควรจะสร้างได้ในที่สุด

ตรวจสอบงาน

ในบทแนะนำนี้ คุณได้เรียนรู้วิธีกำหนดค่า Toolchain C++ พื้นฐาน แต่ Toolchain มีประสิทธิภาพมากกว่าตัวอย่างง่ายๆ นี้

ประเด็นสำคัญมีดังนี้ - คุณต้องระบุแฟล็ก --crosstool_top ในบรรทัดคำสั่งซึ่งควร ชี้ไปยัง cc_toolchain_suite - คุณสร้างทางลัดสำหรับการกำหนดค่าที่เฉพาะเจาะจงได้โดยใช้ไฟล์ .bazelrc - cc_toolchain_suite อาจแสดง cc_toolchains สำหรับ CPU และ คอมไพเลอร์ต่างๆ คุณใช้ Flag บรรทัดคำสั่ง เช่น --cpu เพื่อแยกความแตกต่างได้ - คุณต้องแจ้งให้ Toolchain ทราบว่าเครื่องมืออยู่ที่ใด ในบทแนะนำนี้ มีเวอร์ชันที่ง่ายขึ้นซึ่งคุณจะเข้าถึงเครื่องมือจากระบบได้ หาก สนใจแนวทางที่ครอบคลุมมากขึ้น โปรดอ่านเกี่ยวกับพื้นที่ทำงานที่นี่ เครื่องมืออาจมาจากพื้นที่ทำงานอื่น และคุณจะต้องทำให้ไฟล์ของเครื่องมือพร้อมใช้งานสำหรับ cc_toolchain ที่มีทรัพยากร Dependency เป้าหมายในแอตทริบิวต์ เช่น compiler_files tool_paths ก็จะต้องมีการเปลี่ยนแปลงด้วยเช่นกัน - คุณสร้างฟีเจอร์เพื่อปรับแต่งว่าควรส่งแฟล็กใดไปยัง การดำเนินการต่างๆ ไม่ว่าจะเป็นการลิงก์หรือการดำเนินการประเภทอื่นๆ

อ่านเพิ่มเติม

ดูรายละเอียดเพิ่มเติมได้ที่ การกำหนดค่าชุดเครื่องมือ C++