マクロの作成

ビルドの一環としてツールを実行する必要があるとします。たとえば、ソースファイルを生成または前処理したり、バイナリを圧縮したりできます。このチュートリアルでは、画像のサイズを変更するマクロを作成します。

マクロは単純なタスクに適しています。新しいプログラミング言語のサポートを追加するなど、より複雑な操作が必要な場合は、ルールの作成を検討してください。ルールを使用すると、管理性と柔軟性が向上します。

画像のサイズを変更するマクロを作成する最も簡単な方法は、genrule を使用することです。

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

より多くの画像のサイズを変更する必要がある場合は、コードを再利用することをおすすめします。これを行うには、別の .bzl ファイルで関数を定義し、ファイル miniature.bzl を呼び出します。

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

備考:

• マクロには通常、ルールと同様に name 引数があります。

• マクロの動作をドキュメント化するには、Python と同様に docstring を使用します。

• genrule またはその他のネイティブ ルールを呼び出すには、native. を使用します。

• **kwargs を使用して、追加の引数を基になる genrule に転送します（Python と同様に機能します）。これは、ユーザーが visibility や tags などの標準属性を使用できるようにするのに便利です。

次に、BUILD ファイルのマクロを使用します。

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)