このチュートリアルでは、サンプル シナリオを使用して、プロジェクトの C++ ツールチェーンを構成する方法について説明します。これは、clang を使用してエラーのないビルドを行うC++ サンプル プロジェクトに基づいています。
学習内容
このチュートリアルでは、次の方法について学習します。
- ビルド環境を設定する
- C++ ツールチェーンを構成する
- Bazel が
clangを使用してアプリケーションをビルドできるように、cc_toolchainの追加構成を指定する Starlark ルールを作成します。 - Linux マシンで
bazel build --config=clang_config //main:hello-worldを実行して、想定される結果を確認する - C++ アプリケーションをビルドする
始める前に
ビルド環境を設定する
このチュートリアルでは、Linux で C++ アプリケーションを正常にビルドし、適切なツールとライブラリをインストールしていることを前提としています。このチュートリアルでは、システムにインストールできる clang version 9.0.1 を使用します。
ビルド環境を次のように設定します。
まだ行っていない場合は、Bazel 0.23 以降をダウンロードしてインストールします。
GitHub からC++ サンプル プロジェクトをダウンロードし、ローカルマシンの空のディレクトリに配置します。
次の
cc_binaryターゲットをmain/BUILDファイルに追加します。cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )--configフラグの使用を有効にするには、ワークスペース ディレクトリのルートに次の内容の.bazelrcファイルを作成します。# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
エントリ build:{config_name} --flag=value の場合、コマンドライン フラグ --config={config_name} がその特定のフラグに関連付けられます。使用されるフラグ（crosstool_top、cpu、host_crosstool_top）については、ドキュメントをご覧ください。
bazel build --config=clang_config //main:hello-world を使用してターゲットをビルドすると、Bazel は cc_toolchain_suite
//toolchain:clang_suite のカスタム ツールチェーンを使用します。スイートには、CPU ごとに異なるツールチェーンが一覧表示される場合があります。そのため、--cpu=k8 フラグで区別されます。
Bazel はビルド中に process-wrapper など、C++ で記述された多くの内部ツールを使用するため、ホスト プラットフォームに既存のデフォルトの C++ ツールチェーンが指定されます。これにより、これらのツールは、このチュートリアルで作成したツールチェーンではなく、そのツールチェーンを使用してビルドされます。
C++ ツールチェーンの構成
C++ ツールチェーンを構成するには、以下の手順に沿ってアプリケーションを繰り返しビルドし、エラーを 1 つずつ排除します。
次のコマンドでビルドを実行します。
bazel build --config=clang_config //main:hello-world.bazelrcファイルで--crosstool_top=//toolchain:clang_suiteを指定しているため、Bazel は次のエラーをスローします。No such package `toolchain`: BUILD file not found on package path.ワークスペース ディレクトリに、パッケージの
toolchainディレクトリと、toolchainディレクトリ内に空のBUILDファイルを作成します。ビルドをもう一度実行します。
toolchainパッケージにclang_suiteターゲットがまだ定義されていないため、Bazel は次のエラーをスローします。No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILDファイルで、空のファイルグループを次のように定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")ビルドをもう一度実行します。Bazel は次のエラーをスローします。
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel は、
--crosstool_topフラグが、必要なToolchainInfoプロバイダを提供しないルールを参照していることを検出しました。そのため、--crosstool_topをToolchainInfoを提供するルール（cc_toolchain_suiteルール）に指すようにする必要があります。toolchain/BUILDファイルで、空のファイルグループを次のように置き換えます。cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性は、--cpu値（指定されている場合は--compiler値も）をcc_toolchainに自動的にマッピングします。まだcc_toolchainターゲットを定義していないため、まもなく Bazel からエラーが報告されます。ビルドをもう一度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain' does not exist次に、
cc_toolchain_suite.toolchains属性のすべての値にcc_toolchainターゲットを定義する必要があります。toolchain/BUILDファイルに以下を追加します。filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )ビルドをもう一度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain_config' does not exist次に、
toolchain/BUILDファイルに「:k8_toolchain_config」ターゲットを追加します。filegroup(name = "k8_toolchain_config")ビルドをもう一度実行します。Bazel は次のエラーをスローします。
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfoは、C++ ツールチェーンを構成するために使用するプロバイダです。このエラーを修正するには、次の内容のtoolchain/cc_toolchain_config.bzlファイルを作成して、Bazel にCcToolchainConfigInfoを提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()は、必要なプロバイダCcToolchainConfigInfoを作成します。cc_toolchain_configルールを使用するには、toolchains/BUILDに読み込みステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")「k8_toolchain_config」ファイルグループを
cc_toolchain_configルールの宣言に置き換えます。cc_toolchain_config(name = "k8_toolchain_config")ビルドをもう一度実行します。Bazel は次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`この時点で、Bazel にはコードのビルドを試みるのに十分な情報がありますが、必要なビルド アクションを完了するために使用するツールはまだわかりません。Starlark ルールの実装を変更して、使用するツールを Bazel に指示します。これには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzlの tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clangと/usr/bin/ldがシステムの正しいパスであることを確認します。ビルドをもう一度実行します。Bazel は次のエラーをスローします。
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel は、含まれるヘッダーを検索する場所を把握する必要があります。これを解決する方法はいくつかあります（
cc_binaryのincludes属性を使用するなど）。ここでは、cc_common.create_cc_toolchain_config_infoのcxx_builtin_include_directoriesパラメータを使用して、ツールチェーン レベルで解決します。別のバージョンのclangを使用している場合、インクルードパスは異なります。これらのパスはディストリビューションによって異なる場合があります。toolchain/cc_toolchain_config.bzlの戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'これは、リンカーに C++ 標準ライブラリがないため、シンボルが見つからないためです。この問題を解決するには、
cc_binaryのlinkopts属性を使用するなど、さまざまな方法があります。ここでは、ツールチェーンを使用するターゲットでこのフラグを指定する必要がないようにすることで、この問題を解決しています。次のコードを
cc_toolchain_config.bzlにコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-worldを実行すると、最終的にビルドされます。
課題を確認する
このチュートリアルでは、基本的な C++ ツールチェーンを構成する方法について説明しましたが、ツールチェーンは、この単純な例よりも強力です。
主なポイントは次のとおりです。
- コマンドラインで --crosstool_top フラグを指定する必要があります。これは cc_toolchain_suite を参照する必要があります。
- .bazelrc ファイルを使用して、特定の構成のショートカットを作成できます。
- cc_toolchain_suite には、さまざまな CPU とコンパイラ用の cc_toolchains が一覧表示される場合があります。--cpu などのコマンドライン フラグを使用して区別できます。- ツールが存在する場所を toolchain に知らせる必要があります。このチュートリアルでは、システムからツールにアクセスする簡素化されたバージョンを使用します。より自己完結型のアプローチにご関心をお持ちの場合は、ワークスペースについての記事をご覧ください。ツールは別のワークスペースから取得できます。その場合は、compiler_files などの属性にターゲット依存関係を指定して、そのファイルを cc_toolchain で使用できるようにする必要があります。tool_paths も変更する必要があります。- リンクやその他のタイプのアクションなど、さまざまなアクションに渡すフラグをカスタマイズする特徴を作成できます。
関連情報
詳細については、C++ ツールチェーンの構成をご覧ください。