Bazel チュートリアル: C++ ツールチェーンを構成する

Nightly · 9.0 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 7.7

このチュートリアルでは、プロジェクトの C++ ツールチェーンを構成する方法について、サンプルシナリオを使用して説明します。

学習内容

このチュートリアルでは、以下の方法について学習します。

ビルド環境を設定する
--toolchain_resolution_debug を使用してツールチェーンの解決をデバッグする
C++ ツールチェーンを構成する
cc_toolchain の追加構成を提供する Starlark ルールを作成して、Bazel が clang でアプリケーションをビルドできるようにする
Linux マシンでを実行して、の C++ バイナリをビルドするbazel build //main:hello-world
bazel build //main:hello-world --platforms=//:android_x86_64 を実行して、android 用のバイナリをクロスコンパイルする

始める前に

このチュートリアルでは、Linux を使用し、C++ アプリケーションを正常にビルドして、適切なツールとライブラリをインストールしていることを前提としています。このチュートリアルでは、 clang version 16 を使用します。これはシステムにインストールできます。

ビルド環境を設定する

ビルド環境を次のように設定します。

まだ行っていない場合は、Bazel 7.0.2 以降をダウンロードしてインストールします。
ルートフォルダに空の MODULE.bazel ファイルを追加します。
次の cc_binary ターゲットを main/BUILD ファイルに追加します。
```
cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)
```
Bazel は、ビルド中に C++ で記述された多くの内部ツールを使用するため、既存のデフォルトの C++ ツールチェーンがホストプラットフォームに指定されます。process-wrapperこれにより、これらの内部ツールは、このチュートリアルで作成したツールチェーンを使用してビルドできます。したがって、cc_binary ターゲットもデフォルトのツールチェーンでビルドされます。
次のコマンドでビルドを実行します。
```
bazel build //main:hello-world
```
MODULE.bazel にツールチェーンが登録されていなくても、ビルドは成功します。

内部の動作を確認するには、次を実行します。
```
bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type'

INFO: ToolchainResolution: Target platform @@platforms//host:host: Selected execution platform @@platforms//host:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8
```
--platforms を指定しない場合、Bazel は @platforms//host を使用して @bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8 のターゲットをビルドします。

C++ ツールチェーンを構成する

C++ ツールチェーンを構成するには、アプリケーションを繰り返しビルドし、次の説明に従って各エラーを 1 つずつ解消します。

また、clang version 9.0.1 を使用していることを前提としていますが、clang のバージョンが異なっても詳細が大きく変わることはありません。

次を追加します。toolchain/BUILD

filegroup(name = "empty")

cc_toolchain(
    name = "linux_x86_64_toolchain",
    toolchain_identifier = "linux_x86_64-toolchain",
    toolchain_config = ":linux_x86_64_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

toolchain(
    name = "cc_toolchain_for_linux_x86_64",
    toolchain = ":linux_x86_64_toolchain",
    toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
    exec_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
)

次に、適切な依存関係を追加し、 MODULE.bazel に次を使用してツールチェーンを登録します。

bazel_dep(name = "platforms", version = "0.0.10")
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64"
)

このステップでは、cc_toolchain を定義し、ホスト構成の toolchain ターゲットにバインドします。

もう一度ビルドを実行します。toolchain パッケージで linux_x86_64_toolchain_config ターゲットがまだ定義されていないため、Bazel は次のエラーをスローします。
```
ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.
```

toolchain/BUILD ファイルで、次のように空の filegroup を定義します。

package(default_visibility = ["//visibility:public"])

filegroup(name = "linux_x86_64_toolchain_config")

もう一度ビルドを実行します。Bazel は次のエラーをスローします。

'//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.

CcToolchainConfigInfo は、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容で toolchain/cc_toolchain_config.bzl ファイルを作成して、Bazel に CcToolchainConfigInfo を提供する Starlark ルールを作成します。

def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

cc_common.create_cc_toolchain_config_info() は、必要なプロバイダ CcToolchainConfigInfo を作成します。cc_toolchain_config ルールを使用するには、package ステートメントの直下の toolchain/BUILD に load ステートメントを追加します。

load(":cc_toolchain_config.bzl", "cc_toolchain_config")

また、「linux_x86_64_toolchain_config」filegroup を宣言の cc_toolchain_config ルールに置き換えます。

cc_toolchain_config(name = "linux_x86_64_toolchain_config")

もう一度ビルドを実行します。Bazel は次のエラーをスローします。

.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

この時点で、Bazel はコードのビルドを試行するのに十分な情報を取得していますが、必要なビルドアクションを完了するために使用するツールはまだわかりません。Starlark ルールの実装を変更して、使用するツールを Bazel に伝えます。そのためには、tool_path() コンストラクタが @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl から必要です。

# toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

/usr/bin/clang と /usr/bin/ld がシステムの正しいパスであることを確認します。

もう一度ビルドを実行します。Bazel は次のエラーをスローします。

ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world':
the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain):
  '/usr/include/c++/13/ctime'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h'
  ...

Bazel は、インクルードヘッダーを検索する場所を把握する必要があります。これを解決する方法はいくつかあります。たとえば、cc_binary の includes 属性を使用する方法がありますが、ここでは cc_common.create_cc_toolchain_config_info の cxx_builtin_include_directories パラメータを使用して、ツールチェーンレベルで解決します。clang のバージョンが異なる場合、インクルードパスは異なります。これらのパスは、ディストリビューションによって異なる場合もあります。

toolchain/cc_toolchain_config.bzl の戻り値を次のように変更します。

return cc_common.create_cc_toolchain_config_info(
    ctx = ctx,
    cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-16/lib/clang/16/include",
        "/usr/include",
    ],
    toolchain_identifier = "local",
    host_system_name = "local",
    target_system_name = "local",
    target_cpu = "k8",
    target_libc = "unknown",
    compiler = "clang",
    abi_version = "unknown",
    abi_libc_version = "unknown",
    tool_paths = tool_paths,
)

ビルドコマンドをもう一度実行すると、次のようなエラーが表示されます。

/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

これは、リンカーに C++ 標準ライブラリがなく、そのシンボルが見つからないためです。これを解決する方法はいくつかあります。たとえば、linkopts 属性を cc_binary 使用する方法があります。ここでは、ツールチェーンを使用するターゲットでこのフラグを指定する必要がないようにすることで解決します。

次のコードを toolchain/cc_toolchain_config.bzl にコピーします。

# NEW
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
# NEW
load(
    "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
    "feature",    # NEW
    "flag_group", # NEW
    "flag_set",   # NEW
    "tool_path",
)

all_link_actions = [ # NEW
    ACTION_NAMES.cpp_link_executable,
    ACTION_NAMES.cpp_link_dynamic_library,
    ACTION_NAMES.cpp_link_nodeps_dynamic_library,
]

def _impl(ctx):
    tool_paths = [
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/bin/false",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    features = [ # NEW
        feature(
            name = "default_linker_flags",
            enabled = True,
            flag_sets = [
                flag_set(
                    actions = all_link_actions,
                    flag_groups = ([
                        flag_group(
                            flags = [
                                "-lstdc++",
                            ],
                        ),
                    ]),
                ),
            ],
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        features = features, # NEW
        cxx_builtin_include_directories = [
            "/usr/lib/llvm-9/lib/clang/9.0.1/include",
            "/usr/include",
        ],
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths,
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

bazel build //main:hello-world を実行すると、最終的にホストのバイナリが正常にビルドされます。
toolchain/BUILD で、cc_toolchain_config、cc_toolchain、 toolchain ターゲットをコピーし、ターゲット名で linux_x86_64 を android_x86_64 に置き換えます。

MODULE.bazel で、android のツールチェーンを登録します。
```
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64",
    "//toolchain:cc_toolchain_for_android_x86_64"
)
```
bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64 を実行して、 Android 用のバイナリをビルドします。

実際には、Linux と Android で C++ ツールチェーンの構成が異なります。既存の cc_toolchain_config を変更して違いを反映させるか、プラットフォームごとに個別のルール（CcToolchainConfigInfo プロバイダ）を作成します。

実施したタスクを確認する

このチュートリアルでは、基本的な C++ ツールチェーンを構成する方法について説明しましたが、ツールチェーンはこれよりも強力です。

重要な学習ポイント:

Bazel がプラットフォームで同じ制約値のツールチェーンを解決するには、コマンドラインで一致する platforms フラグを指定する必要があります。言語固有の構成フラグについて詳しくは、ドキュメントをご覧ください。
ツールチェーンにツールの場所を知らせる必要があります。このチュートリアルでは、システムからツールにアクセスする簡略版を使用します。自己完結型の方法に関心がある場合は、外部依存関係をご覧ください。ツールは別のモジュールから取得できるため、 cc_toolchain などの属性のターゲット依存関係を使用して、 compiler_files でファイルを使用できるようにする必要があります。tool_paths も変更する必要があります。
機能を作成して、リンクやその他のタイプのアクションなど、さまざまなアクションに渡すフラグをカスタマイズできます。

Bazel チュートリアル: C++ ツールチェーンを構成する コレクションでコンテンツを整理 必要に応じて、コンテンツの保存と分類を行います。

学習内容

始める前に

ビルド環境を設定する

C++ ツールチェーンを構成する

実施したタスクを確認する

関連情報

Bazel チュートリアル: C++ ツールチェーンを構成する