このチュートリアルでは、サンプル シナリオを使用して、プロジェクトの C++ ツールチェーンを構成する方法について説明します。これは、clang を使用してエラーなしでビルドされるサンプル C++ プロジェクトに基づいています。
学習内容
このチュートリアルでは、次の方法を学習します。
- ビルド環境を設定する
- C++ ツールチェーンを構成する
- Bazel が
clangでアプリをビルドできるように、cc_toolchainの追加構成を提供する Starlark ルールを作成します。 - Linux マシンで
bazel build --config=clang_config //main:hello-worldを実行して、想定される結果を確認します - C++ アプリケーションをビルドする
始める前に
ビルド環境を設定する
このチュートリアルでは、Linux を使用し、C++ アプリケーションを正常にビルドし、適切なツールとライブラリがインストールされていることを前提としています。このチュートリアルでは clang version 9.0.1 を使用します。これをシステムにインストールできます。
ビルド環境を次のように設定します。
まだ行っていない場合は、Bazel 0.23 をダウンロードしてインストールします。
GitHub からサンプル C++ プロジェクトをダウンロードし、ローカルマシンの空のディレクトリに配置します。
次の
cc_binaryターゲットをmain/BUILDファイルに追加します。cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )ワークスペース ディレクトリのルートに
.bazelrcファイルを作成し、以下の内容を指定して--configフラグを使用できるようにします。# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
build:{config_name} --flag=value というエントリの場合、コマンドライン フラグ --config={config_name} はそのフラグに関連付けられています。使用するフラグについては、crosstool_top、cpu、host_crosstool_top のドキュメントをご覧ください。
bazel build --config=clang_config //main:hello-world を使用してターゲットをビルドすると、Bazel は cc_toolchain_suite //toolchain:clang_suite のカスタム ツールチェーンを使用します。スイートでは、CPU ごとに異なるツールチェーンが表示されることがあります。そのため、--cpu=k8 フラグで区別します。
Bazel は、ビルド時に C++ で記述された多くの内部ツール（process-wrapper など）を使用するため、既存のデフォルトの C++ ツールチェーンはホスト プラットフォームに対して指定されているため、これらのツールチェーンは、このチュートリアルで作成したものではなく、そのツールチェーンを使用してビルドされます。
C++ ツールチェーンの構成
C++ ツールチェーンを構成するには、以下に示すとおり、アプリケーションを繰り返しビルドして、各エラーを 1 つずつ排除します。
次のコマンドを使用してビルドを実行します。
bazel build --config=clang_config //main:hello-world.bazelrcファイルで--crosstool_top=//toolchain:clang_suiteを指定したため、Bazel から次のエラーがスローされます。No such package `toolchain`: BUILD file not found on package path.ワークスペース ディレクトリで、パッケージ用の
toolchainディレクトリと、toolchainディレクトリ内に空のBUILDファイルを作成します。ビルドを再度実行します。
toolchainパッケージではclang_suiteターゲットがまだ定義されていないため、Bazel が次のエラーをスローします。No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILDファイルで、次のように空のファイルグループを定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")ビルドを再度実行します。Bazel が次のエラーをスローします。
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel が、必要な
ToolchainInfoプロバイダを提供していないルールを--crosstool_topフラグが参照していることを検出した。そのため、ToolchainInfoを提供するルール、つまりcc_toolchain_suiteルールを--crosstool_topに設定する必要があります。toolchain/BUILDファイルで、空のファイルグループを次のように置き換えます。cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性は、--cpu（および指定された場合は--compiler）の値を自動的にcc_toolchainにマッピングします。cc_toolchainターゲットがまだ定義されておらず、Bazel がそのことをすぐにエラーにします。ビルドを再度実行します。Bazel が次のエラーをスローします。
Rule '//toolchain:k8_toolchain' does not exist次に、
cc_toolchain_suite.toolchains属性のすべての値にcc_toolchainターゲットを定義する必要があります。toolchain/BUILDファイルに以下を追加します。filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )ビルドを再度実行します。Bazel が次のエラーをスローします。
Rule '//toolchain:k8_toolchain_config' does not exist次に、
toolchain/BUILDファイルに「:k8_toolchain_config」ターゲットを追加します。filegroup(name = "k8_toolchain_config")ビルドを再度実行します。Bazel が次のエラーをスローします。
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfoは、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容のtoolchain/cc_toolchain_config.bzlファイルを作成して、Bazel にCcToolchainConfigInfoを提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()は、必要なプロバイダCcToolchainConfigInfoを作成します。cc_toolchain_configルールを使用するには、パッケージ ステートメントのすぐ下にあるtoolchain/BUILDに読み込みステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")そのため、「k8_toolchain_config」ファイル グループを
cc_toolchain_configルールの宣言に置き換えます。cc_toolchain_config(name = "k8_toolchain_config")ビルドを再度実行します。Bazel が次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`この時点で、Bazel はコードのビルドを試みるのに十分な情報を持っていますが、必要なビルド アクションを完了するためのツールがまだわかりません。使用するツールを Bazel に指示するように、Starlark ルールの実装を変更します。そのためには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzlの tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clangと/usr/bin/ldがシステムの正しいパスであることを確認します。ビルドを再度実行します。Bazel が次のエラーをスローします。
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel は、含まれるヘッダーの検索場所を認識している必要があります。これを解決するには、
cc_binaryのincludes属性を使用するなど、複数の方法がありますが、ここではツールチェーン レベルでcc_common.create_cc_toolchain_config_infoのcxx_builtin_include_directoriesパラメータを使用して解決します。別のバージョンのclangを使用している場合は、インクルード パスが異なることに注意してください。これらのパスは、配布に応じて異なる場合があります。toolchain/cc_toolchain_config.bzlの戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'これは、リンカーに C++ 標準ライブラリがなく、そのシンボルが見つからないためです。これを解決するには、
cc_binaryのlinkopts属性を使用するなど、さまざまな方法があります。この問題は、ツールチェーンを使用するターゲットでこのフラグを指定する必要がないことで解決できます。次のコードを
cc_toolchain_config.bzlにコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-worldを実行すると、最終的にビルドされます。
提出物を確認
このチュートリアルでは、基本的な C++ ツールチェーンの構成方法を学習しましたが、ツールチェーンは、このシンプルな例よりも強力です。
重要なポイントは次のとおりです。
- cc_toolchain_suite を指すように、コマンドラインで --crosstool_top フラグを指定する必要があります。
- .bazelrc ファイルを使用して、特定の構成のショートカットを作成できます。
- cc_toolchain_suite では、さまざまな CPU やコンパイラの cc_toolchains を指定できます。--cpu などのコマンドライン フラグを使用して区別できます。- ツールがどこにあるかをツールチェーンに認識させる必要があります。このチュートリアルには、システムからツールにアクセスする簡略版が用意されています。自己完結型のアプローチにご興味がある場合は、こちらのワークスペースをご覧ください。ツールは別のワークスペースから取得できるため、compiler_files などの属性の依存関係を持つ cc_toolchain でそのファイルを使用できるようにする必要があります。tool_paths も変更する必要があります。- リンクを作成して他のアクションを実行するかどうかを示すフラグを作成して、どのアクションに渡す必要があるかをカスタマイズする機能を作成できます。
参考資料
詳細については、C++ ツールチェーンの構成をご覧ください。