安定版リリースのドキュメントについては、[バージョニングされたドキュメント] プルダウンを使用してください。デフォルトのビューには HEAD の最新バージョンが表示されます。

このページは Cloud Translation API によって翻訳されました。

一般的な C++ ビルドのユースケース

ここでは、Bazel を使用した C++ プロジェクトをビルドする際の一般的なユースケースをいくつか紹介します。Bazel を使用した C++ プロジェクトのビルドをまだ行っていない場合は、まず、Bazel の概要: C++ プロジェクトのビルドのチュートリアルに沿って操作してください。

cc_library と hdrs ヘッダーファイルの詳細については、cc_library をご覧ください。

ターゲットに複数のファイルを含める

glob を使用すると、1 つのターゲットに複数のファイルを含めることができます。例:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

このターゲットを使用すると、Bazel は、このターゲットを含む BUILD ファイルと同じディレクトリ（サブディレクトリを除く）で検出した .cc ファイルと .h ファイルをすべてビルドします。

推移的インクルードを使用する

ファイルにヘッダーが含まれている場合、そのファイルをソースとするルール（つまり、そのファイルを srcs、hdrs、または textual_hdrs 属性に含める）は、含まれるヘッダーのライブラリルールに依存する必要があります。逆に、依存関係として指定する必要があるのは直接的な依存関係のみです。たとえば、sandwich.h に bread.h が含まれ、bread.h に flour.h が含まれているとします。sandwich.h に flour.h（サンドイッチに小麦粉を入れたい人は？）が含まれていないため、BUILD ファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここで、sandwich ライブラリは、flour ライブラリに依存する bread ライブラリに依存します。

インクルードパスの追加

ワークスペースのルートでルートインクルードパスを作成できない（またはしたくない）場合があります。既存のライブラリには、ワークスペース内のパスと一致しないインクルードディレクトリがすでに存在している可能性があります。たとえば、次のディレクトリ構造があるとします。

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel は some_lib.h が legacy/some_lib/include/some_lib.h として含まれることを想定しますが、some_lib.cc に "some_lib.h" が含まれているとします。このインクルードパスを有効にするには、legacy/some_lib/BUILD で some_lib/include ディレクトリがインクルードディレクトリであることを指定する必要があります。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

外部依存関係の場合は、ヘッダーファイルを / 接頭辞で含める必要があるため、特に便利です。

外部ライブラリを追加する

Google Test {: .external} を使用しているとします。WORKSPACE ファイルのリポジトリ関数のいずれかを使用して Google テストをダウンロードし、リポジトリで使用できるようにします。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

次に、gtest.BUILD（Google Test のコンパイルに使用する BUILD ファイル）を作成します。Google Test にはいくつかの「特別な」要件があるため、cc_library ルールがより複雑になります。

googletest-release-1.10.0/googletest/src/gtest-all.cc: googletest-release-1.10.0/googletest/src/ 内にある他のすべてのファイルを #include します。重複するシンボルのリンクエラーを防ぐため、コンパイルから除外します。
googletest-release-1.10.0/googletest/include/ ディレクトリ（"gtest/gtest.h"）からの相対パスであるヘッダーファイルを使用するため、そのディレクトリをインクルードパスに追加する必要があります。
pthread でリンクする必要があるため、これを linkopt として追加します。

最終的なルールは次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/googletest/src/*.cc"],
        exclude = ["googletest-release-1.10.0/googletest/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/googletest/include/**/*.h",
        "googletest-release-1.10.0/googletest/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/googletest/include",
        "-Iexternal/gtest/googletest-release-1.10.0/googletest"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

この方法はやや乱雑です。アーカイブの構造に起因する副産物として、すべての先頭に googletest-release-1.10.0 が付加されます。strip_prefix 属性を追加すると、http_archive でこの接頭辞が削除されます。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

この場合、gtest.BUILD は次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest/src/*.cc"],
        exclude = ["googletest/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest/include/**/*.h",
        "googletest/src/*.h"
    ]),
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

cc_ ルールが @gtest//:main に依存できるようになりました。

C++ テストの作成と実行

たとえば、次のようなテスト用の ./test/hello-test.cc を作成します。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

次に、テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test から参照できるようにするには、"//test:__pkg__", を ./main/BUILD の visibility 属性に追加する必要があります。

これで、bazel test を使用してテストを実行できるようになりました。

bazel test test:hello-test

これにより、次の出力が生成されます。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

プリコンパイルされたライブラリへの依存関係を追加する

コンパイル済みバージョンのみがあるライブラリ（ヘッダーや .so ファイルなど）を使用する場合は、cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

こうすることで、ワークスペース内の他の C++ ターゲットがこのルールに依存できるようになります。