構成可能なビルド属性

コレクションでコンテンツを整理 必要に応じて、コンテンツの保存と分類を行います。
問題を報告する ソースを表示

構成可能な属性(一般に select())は、コマンドラインでビルドルールの属性の値を切り替えることができる Bazel の機能です。

たとえば、アーキテクチャに適した実装を自動的に選択するマルチプラットフォーム ライブラリや、ビルド時にカスタマイズ可能な機能構成可能なバイナリに使用できます。

# myapp/BUILD

cc_binary(
    name = "mybinary",
    srcs = ["main.cc"],
    deps = select({
        ":arm_build": [":arm_lib"],
        ":x86_debug_build": [":x86_dev_lib"],
        "//conditions:default": [":generic_lib"],
    }),
)

config_setting(
    name = "arm_build",
    values = {"cpu": "arm"},
)

config_setting(
    name = "x86_debug_build",
    values = {
        "cpu": "x86",
        "compilation_mode": "dbg",
    },
)

コマンドラインのフラグに基づいて依存関係を「選択」する cc_binary を宣言します。具体的には、deps は次のようになります。

コマンド の依存関係 =
bazel build //myapp:mybinary --cpu=arm [":arm_lib"]
bazel build //myapp:mybinary -c dbg --cpu=x86 [":x86_dev_lib"]
bazel build //myapp:mybinary --cpu=ppc [":generic_lib"]
bazel build //myapp:mybinary -c dbg --cpu=ppc [":generic_lib"]

select() は、構成条件に基づいて選択される値のプレースホルダとして機能します。構成条件は、config_setting ターゲットを参照するラベルです。構成可能な属性で select() を使用すると、さまざまな条件が満たされたときに、属性に異なる値を効果的に採用できます。

一致は明確である必要があります。1 つの条件に完全に一致する必要があります。また、複数の条件が一致する場合は、1 つの values が他のすべてのものと厳密なスーパーセットである必要があります。たとえば、values = {"cpu": "x86", "compilation_mode": "dbg"}values = {"cpu": "x86"} のスペシャライゼーションです。他に条件がない場合、組み込み条件 //conditions:default は自動的に一致します。

この例では deps を使用していますが、select() は、srcsresourcescmd などのほとんどの属性で同様に機能します。構成不可の少数の属性のみで、アノテーションが明確になっている。たとえば、config_settingvalues 属性は構成できません。

select() と依存関係

一部の属性は、ターゲットの下にあるすべての推移的依存関係のビルド パラメータを変更します。たとえば、genruletools は、--cpu を Bazel を実行しているマシンの CPU に変更します(クロスコンパイルにより、ターゲットが構築される CPU とは異なる場合があります)。これは構成の遷移と呼ばれます。

指定

#myapp/BUILD

config_setting(
    name = "arm_cpu",
    values = {"cpu": "arm"},
)

config_setting(
    name = "x86_cpu",
    values = {"cpu": "x86"},
)

genrule(
    name = "my_genrule",
    srcs = select({
        ":arm_cpu": ["g_arm.src"],
        ":x86_cpu": ["g_x86.src"],
    }),
    tools = select({
        ":arm_cpu": [":tool1"],
        ":x86_cpu": [":tool2"],
    }),
)

cc_binary(
    name = "tool1",
    srcs = select({
        ":arm_cpu": ["armtool.cc"],
        ":x86_cpu": ["x86tool.cc"],
    }),
)

実行中

$ bazel build //myapp:my_genrule --cpu=arm

x86 デベロッパー マシン上で、ビルドを g_arm.srctool1x86tool.cc にバインドします。my_genrule にアタッチされた両方の select が、my_genrule のビルド パラメータを使用します。これには --cpu=arm が含まれます。tools 属性により、tool1 とその推移的な依存関係の --cpux86 に変更されます。tool1select は、tool1 のビルド パラメータを使用します。これには --cpu=x86 が含まれます。

構成条件

構成可能な属性の各キーは、config_setting または constraint_value へのラベル参照です。

config_setting は、想定されるコマンドライン フラグ設定のコレクションにすぎません。これらをターゲットにカプセル化することで、ユーザーが複数の場所から参照できる「標準的な」条件を維持することが容易になります。

constraint_value は、マルチプラットフォームの動作をサポートしています。

組み込みフラグ

Bazel には --cpu などのフラグが組み込まれています。ビルドツールは、すべてのプロジェクトのすべてのビルドでネイティブに認識します。これらは config_settingvalues 属性で指定されます。

config_setting(
    name = "meaningful_condition_name",
    values = {
        "flag1": "value1",
        "flag2": "value2",
        ...
    },
)

flagN はフラグ名です(-- はないため、"--cpu" ではなく "cpu")。valueN は、このフラグの期待値です。:meaningful_condition_nameすべてのエントリに一致する場合に、:meaningful_condition_name が一致します。順序は関係ありません。

valueN は、コマンドラインで設定した場合と同様に解析されます。これは次のことを意味します。

  • bazel build -c opt に一致する values = { "compilation_mode": "opt" }
  • bazel build --force_pic=1 に一致する values = { "force_pic": "true" }
  • bazel build --noforce_pic に一致する values = { "force_pic": "0" }

config_setting は、ターゲットの動作に影響するフラグのみをサポートします。たとえば、--show_progress は、Bazel がユーザーに進行状況を報告する方法にのみ影響するため、許可されません。ターゲットは、そのフラグを使用して結果を構築できません。サポートされているフラグの正確なセットについては、文書化されていません。実際には、意味のあるフラグのほとんどが機能します。

カスタムフラグ

Starlark のビルド設定を使用して、独自のプロジェクト固有のフラグをモデル化できます。組み込みフラグとは異なり、これらはビルド ターゲットとして定義されるため、Bazel はターゲット ラベルを使用してフラグを参照します。

これらは config_settingflag_values 属性でトリガーされます。

config_setting(
    name = "meaningful_condition_name",
    flag_values = {
        "//myflags:flag1": "value1",
        "//myflags:flag2": "value2",
        ...
    },
)

動作は組み込みフラグと同じです。実際の例については、こちらをご覧ください。

--define は、カスタムフラグの代替の以前の構文(--define foo=bar など)です。これは、values 属性(values = {"define": "foo=bar"})または define_values 属性(define_values = {"foo": "bar"})で表すことができます。--define は下位互換性のためにのみサポートされます。可能な限り Starlark のビルド設定を優先します。

valuesflag_valuesdefine_values はそれぞれ独立して評価されます。config_setting はすべての値と一致する場合に一致します。

デフォルトの条件

組み込み条件 //conditions:default は、他の条件が一致しない場合に一致します。

「完全一致」ルールにより、一致とデフォルト条件のない構成可能な属性は "no matching conditions" エラーを出力します。これにより、予期しない設定によるサイレント エラーから保護できます。

# myapp/BUILD

config_setting(
    name = "x86_cpu",
    values = {"cpu": "x86"},
)

cc_library(
    name = "x86_only_lib",
    srcs = select({
        ":x86_cpu": ["lib.cc"],
    }),
)
$ bazel build //myapp:x86_only_lib --cpu=arm
ERROR: Configurable attribute "srcs" doesn't match this configuration (would
a default condition help?).
Conditions checked:
  //myapp:x86_cpu

より明確なエラーについては、select()no_match_error 属性を使用してカスタム メッセージを設定できます。

プラットフォーム

コマンドラインで複数のフラグを指定する機能は柔軟性がありますが、ターゲットをビルドするたびに個別にフラグを設定するのは、負担になる場合があります。プラットフォームを使用すると、これらをシンプルなバンドルにまとめることができます。

# myapp/BUILD

sh_binary(
    name = "my_rocks",
    srcs = select({
        ":basalt": ["pyroxene.sh"],
        ":marble": ["calcite.sh"],
        "//conditions:default": ["feldspar.sh"],
    }),
)

config_setting(
    name = "basalt",
    constraint_values = [
        ":black",
        ":igneous",
    ],
)

config_setting(
    name = "marble",
    constraint_values = [
        ":white",
        ":metamorphic",
    ],
)

# constraint_setting acts as an enum type, and constraint_value as an enum value.
constraint_setting(name = "color")
constraint_value(name = "black", constraint_setting = "color")
constraint_value(name = "white", constraint_setting = "color")
constraint_setting(name = "texture")
constraint_value(name = "smooth", constraint_setting = "texture")
constraint_setting(name = "type")
constraint_value(name = "igneous", constraint_setting = "type")
constraint_value(name = "metamorphic", constraint_setting = "type")

platform(
    name = "basalt_platform",
    constraint_values = [
        ":black",
        ":igneous",
    ],
)

platform(
    name = "marble_platform",
    constraint_values = [
        ":white",
        ":smooth",
        ":metamorphic",
    ],
)

プラットフォームはコマンドラインで指定できます。これにより、プラットフォームの constraint_values のサブセットを含む config_setting が有効になり、それらの config_settingselect() 式で照合できるようになります。

たとえば、my_rockssrcs 属性を calcite.sh に設定するには、次のコマンドを実行します。

bazel build //my_app:my_rocks --platforms=//myapp:marble_platform

プラットフォームを使用しないと、次のようになります。

bazel build //my_app:my_rocks --define color=white --define texture=smooth --define type=metamorphic

select()constraint_value を直接読み取ることもできます。

constraint_setting(name = "type")
constraint_value(name = "igneous", constraint_setting = "type")
constraint_value(name = "metamorphic", constraint_setting = "type")
sh_binary(
    name = "my_rocks",
    srcs = select({
        ":igneous": ["igneous.sh"],
        ":metamorphic" ["metamorphic.sh"],
    }),
)

これにより、単一の値のみをチェックする必要がある場合に、ボイラープレート config_setting が不要になります。

プラットフォームは現在開発中です。詳しくは、ドキュメントをご覧ください。

select() の組み合わせ

同じ属性に select が複数回表示されることもあります。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"] +
           select({
               ":armeabi_mode": ["armeabi_src.sh"],
               ":x86_mode": ["x86_src.sh"],
           }) +
           select({
               ":opt_mode": ["opt_extras.sh"],
               ":dbg_mode": ["dbg_extras.sh"],
           }),
)

select を別の select 内に表示することはできません。selects をネストする必要があり、属性が他のターゲットを値として受け取る場合は、中間ターゲットを使用します。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":armeabi_mode": [":armeabi_lib"],
        ...
    }),
)

sh_library(
    name = "armeabi_lib",
    srcs = select({
        ":opt_mode": ["armeabi_with_opt.sh"],
        ...
    }),
)

複数の条件が一致した場合に select を一致させる必要がある場合は、AND チェーンを検討してください。

または連結

以下の点を考慮してください。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1": [":standard_lib"],
        ":config2": [":standard_lib"],
        ":config3": [":standard_lib"],
        ":config4": [":special_lib"],
    }),
)

ほとんどの条件は同じ依存関係に評価されます。ただし、この構文は読みやすく、維持も困難です。[":standard_lib"] を何度も繰り返す必要がないようにすると便利です。

1 つの方法は、値を BUILD 変数として事前定義することです。

STANDARD_DEP = [":standard_lib"]

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1": STANDARD_DEP,
        ":config2": STANDARD_DEP,
        ":config3": STANDARD_DEP,
        ":config4": [":special_lib"],
    }),
)

これにより、依存関係の管理が容易になります。ただし、それでも不要な重複が発生します。

より直接サポートが必要な場合は、次のいずれかを使用してください。

selects.with_or

Skylibselects モジュールの with_or マクロは、select 内で直接 OR 条件をサポートします。

load("@bazel_skylib//lib:selects.bzl", "selects")
sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = selects.with_or({
        (":config1", ":config2", ":config3"): [":standard_lib"],
        ":config4": [":special_lib"],
    }),
)

selects.config_setting_group

Skylibselects モジュールの config_setting_group マクロは、複数の config_settingOR をサポートします。

load("@bazel_skylib//lib:selects.bzl", "selects")
config_setting(
    name = "config1",
    values = {"cpu": "arm"},
)
config_setting(
    name = "config2",
    values = {"compilation_mode": "dbg"},
)
selects.config_setting_group(
    name = "config1_or_2",
    match_any = [":config1", ":config2"],
)
sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1_or_2": [":standard_lib"],
        "//conditions:default": [":other_lib"],
    }),
)

selects.with_or とは異なり、異なるターゲットは異なる属性間で :config1_or_2 を共有できます。

一方が他方の明確な「専門性」でない限り、複数の条件が一致してもエラーが発生します。詳しくはこちらをご覧ください。

AND チェーン

複数の条件が一致するときに select 分岐を一致させる必要がある場合は、Skylib マクロ config_setting_group を使用します。

config_setting(
    name = "config1",
    values = {"cpu": "arm"},
)
config_setting(
    name = "config2",
    values = {"compilation_mode": "dbg"},
)
selects.config_setting_group(
    name = "config1_and_2",
    match_all = [":config1", ":config2"],
)
sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1_and_2": [":standard_lib"],
        "//conditions:default": [":other_lib"],
    }),
)

OR チェーンとは異なり、既存の config_settingselect 内で直接 AND することはできません。明示的に config_setting_group でラップする必要があります。

カスタム エラー メッセージ

デフォルトでは、条件が一致しない場合、select() が接続されているターゲットは失敗し、次のエラーが返されます。

ERROR: Configurable attribute "deps" doesn't match this configuration (would
a default condition help?).
Conditions checked:
  //tools/cc_target_os:darwin
  //tools/cc_target_os:android

これは no_match_error 属性でカスタマイズできます。

cc_library(
    name = "my_lib",
    deps = select(
        {
            "//tools/cc_target_os:android": [":android_deps"],
            "//tools/cc_target_os:windows": [":windows_deps"],
        },
        no_match_error = "Please build with an Android or Windows toolchain",
    ),
)
$ bazel build //myapp:my_lib
ERROR: Configurable attribute "deps" doesn't match this configuration: Please
build with an Android or Windows toolchain

ルールの互換性

ルールの実装では、設定可能な属性の解決値を受け取ります。たとえば、次のような場合です。

# myapp/BUILD

some_rule(
    name = "my_target",
    some_attr = select({
        ":foo_mode": [":foo"],
        ":bar_mode": [":bar"],
    }),
)
$ bazel build //myapp/my_target --define mode=foo

ルールの実装コードでは、ctx.attr.some_attr[":foo"] とみなされます。

マクロは select() 句を受け入れ、ネイティブ ルールに渡すことができます。直接操作することはできません。たとえば、マクロが

select({"foo": "val"}, ...)

To

select({"foo": "val_with_suffix"}, ...)

これには 2 つの理由があります。

まず、マクロは Bazel の読み込みフェーズで評価されるため、select がどのパスを選択するかについて選択する必要があるマクロは機能しません。フラグの値は、その前にフラグの値が確認される前に行われます。これは Bazel の設計上の主な制限で、すぐに変わることはほとんどありません。

第 2 に、マクロはすべてselect パスの反復処理を行うだけで済みますが、技術的には可能ですが、一貫性のある UI がありません。これを変更するにはさらに設計が必要です。

Bazel クエリと cquery

Bazel query は、Bazel の読み込みフェーズで動作します。つまり、ターゲットがどのコマンドライン フラグを使用するかは、ビルドの後半(分析フェーズ)まで評価されないため、認識されません。そのため、どの select() 分岐が選択されたのかを特定できません。

Bazel cquery は Bazel の分析フェーズの後に動作するため、これらすべての情報が含まれ、select() を正確に解決できます。

次の点を検討します。

load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
# myapp/BUILD

string_flag(
    name = "dog_type",
    build_setting_default = "cat"
)

cc_library(
    name = "my_lib",
    deps = select({
        ":long": [":foo_dep"],
        ":short": [":bar_dep"],
    }),
)

config_setting(
    name = "long",
    flag_values = {":dog_type": "dachshund"},
)

config_setting(
    name = "short",
    flag_values = {":dog_type": "pug"},
)

query:my_lib の依存関係を過大評価します。

$ bazel query 'deps(//myapp:my_lib)'
//myapp:my_lib
//myapp:foo_dep
//myapp:bar_dep

cquery にはその正確な依存関係が表示されます。

$ bazel cquery 'deps(//myapp:my_lib)' --//myapp:dog_type=pug
//myapp:my_lib
//myapp:bar_dep

よくある質問

マクロで select() が機能しないのはなぜですか?

select() はルール内で動作します。詳細については、ルールの互換性をご覧ください。

この質問の主要な問題は、通常、select() がマクロで機能しないということです。これらはルールとは異なります。違いについては、ルールマクロのドキュメントをご覧ください。エンドツーエンドの例を以下に示します。

ルールとマクロを定義します。

# myapp/defs.bzl

# Rule implementation: when an attribute is read, all select()s have already
# been resolved. So it looks like a plain old attribute just like any other.
def _impl(ctx):
    name = ctx.attr.name
    allcaps = ctx.attr.my_config_string.upper()  # This works fine on all values.
    print("My name is " + name + " with custom message: " + allcaps)

# Rule declaration:
my_custom_bazel_rule = rule(
    implementation = _impl,
    attrs = {"my_config_string": attr.string()},
)

# Macro declaration:
def my_custom_bazel_macro(name, my_config_string):
    allcaps = my_config_string.upper()  # This line won't work with select(s).
    print("My name is " + name + " with custom message: " + allcaps)

ルールとマクロをインスタンス化します。

# myapp/BUILD

load("//myapp:defs.bzl", "my_custom_bazel_rule")
load("//myapp:defs.bzl", "my_custom_bazel_macro")

my_custom_bazel_rule(
    name = "happy_rule",
    my_config_string = select({
        "//tools/target_cpu:x86": "first string",
        "//tools/target_cpu:ppc": "second string",
    }),
)

my_custom_bazel_macro(
    name = "happy_macro",
    my_config_string = "fixed string",
)

my_custom_bazel_macro(
    name = "sad_macro",
    my_config_string = select({
        "//tools/target_cpu:x86": "first string",
        "//tools/target_cpu:ppc": "other string",
    }),
)

sad_macroselect() を処理できないため、ビルドが失敗します。

$ bazel build //myapp:all
ERROR: /myworkspace/myapp/BUILD:17:1: Traceback
  (most recent call last):
File "/myworkspace/myapp/BUILD", line 17
my_custom_bazel_macro(name = "sad_macro", my_config_stri..."}))
File "/myworkspace/myapp/defs.bzl", line 4, in
  my_custom_bazel_macro
my_config_string.upper()
type 'select' has no method upper().
ERROR: error loading package 'myapp': Package 'myapp' contains errors.

sad_macro をコメントアウトすると、ビルドが成功します。

# Comment out sad_macro so it doesn't mess up the build.
$ bazel build //myapp:all
DEBUG: /myworkspace/myapp/defs.bzl:5:3: My name is happy_macro with custom message: FIXED STRING.
DEBUG: /myworkspace/myapp/hi.bzl:15:3: My name is happy_rule with custom message: FIRST STRING.

定義上のマクロは、Bazel がビルドのコマンドライン フラグを読み取る前に評価されるため、これは変更できません。これは、select() を評価するのに十分な情報がないことを意味します。

ただし、マクロは不透明な blob として select() をルールに渡すことができます。

# myapp/defs.bzl

def my_custom_bazel_macro(name, my_config_string):
    print("Invoking macro " + name)
    my_custom_bazel_rule(
        name = name + "_as_target",
        my_config_string = my_config_string,
    )
$ bazel build //myapp:sad_macro_less_sad
DEBUG: /myworkspace/myapp/defs.bzl:23:3: Invoking macro sad_macro_less_sad.
DEBUG: /myworkspace/myapp/defs.bzl:15:3: My name is sad_macro_less_sad with custom message: FIRST STRING.

select() が常に true を返すのはなぜですか?

定義によるマクロ(ルールではない)では、select() を評価できません。そのため、通常、このような操作を行うとエラーになります。

ERROR: /myworkspace/myapp/BUILD:17:1: Traceback
  (most recent call last):
File "/myworkspace/myapp/BUILD", line 17
my_custom_bazel_macro(name = "sad_macro", my_config_stri..."}))
File "/myworkspace/myapp/defs.bzl", line 4, in
  my_custom_bazel_macro
my_config_string.upper()
type 'select' has no method upper().

ブール値は、通知なく失敗する特殊なケースです。そのため、慎重に注意する必要があります。

$ cat myapp/defs.bzl
def my_boolean_macro(boolval):
  print("TRUE" if boolval else "FALSE")

$ cat myapp/BUILD
load("//myapp:defs.bzl", "my_boolean_macro")
my_boolean_macro(
    boolval = select({
        "//tools/target_cpu:x86": True,
        "//tools/target_cpu:ppc": False,
    }),
)

$ bazel build //myapp:all --cpu=x86
DEBUG: /myworkspace/myapp/defs.bzl:4:3: TRUE.
$ bazel build //mypro:all --cpu=ppc
DEBUG: /myworkspace/myapp/defs.bzl:4:3: TRUE.

これは、マクロが select() のコンテンツを認識しないためです。そのため、ユーザーが評価しているのは select() オブジェクト自体です。Pythonic 設計標準に従って、ごく少数の例外を除いて、すべてのオブジェクトは自動的に true を返します。

select() を辞書のように読み取ることはできますか?

Bazel がビルドのコマンドライン パラメータを認識する前にマクロが評価されるため、マクロは選択値を評価できません。たとえば、少なくとも select() の辞書を読み取り、各値に接尾辞を追加できますか。

概念的には可能ですが、まだ Bazel の機能としては使用できません。今すぐできることとしては、直線的な辞書を作成して、それを select() にフィードします。

$ cat myapp/defs.bzl
def selecty_genrule(name, select_cmd):
  for key in select_cmd.keys():
    select_cmd[key] += " WITH SUFFIX"
  native.genrule(
      name = name,
      outs = [name + ".out"],
      srcs = [],
      cmd = "echo " + select(select_cmd + {"//conditions:default": "default"})
        + " > $@"
  )

$ cat myapp/BUILD
selecty_genrule(
    name = "selecty",
    select_cmd = {
        "//tools/target_cpu:x86": "x86 mode",
    },
)

$ bazel build //testapp:selecty --cpu=x86 && cat bazel-genfiles/testapp/selecty.out
x86 mode WITH SUFFIX

select() とネイティブの両方のタイプをサポートする場合は、以下のようにします。

$ cat myapp/defs.bzl
def selecty_genrule(name, select_cmd):
    cmd_suffix = ""
    if type(select_cmd) == "string":
        cmd_suffix = select_cmd + " WITH SUFFIX"
    elif type(select_cmd) == "dict":
        for key in select_cmd.keys():
            select_cmd[key] += " WITH SUFFIX"
        cmd_suffix = select(select_cmd + {"//conditions:default": "default"})

    native.genrule(
        name = name,
        outs = [name + ".out"],
        srcs = [],
        cmd = "echo " + cmd_suffix + "> $@",
    )

select() が bind() と連携しないのはなぜですか?

bind() は WORKSPACE ルールであり、BUILD ルールではありません。

ワークスペース ルールに特定の構成はなく、BUILD ルールと同じ方法で評価されません。したがって、bind() 内の select() を実際に特定のブランチに評価することはできません。

代わりに、alias()actual 属性の select() を使用して、この種のランタイム決定を行う必要があります。alias() は BUILD ルールであり、特定の構成で評価されるため、これは正しく機能します。

必要に応じて、bind() ターゲット ポイントを alias() に指定することもできます。

$ cat WORKSPACE
workspace(name = "myapp")
bind(name = "openssl", actual = "//:ssl")
http_archive(name = "alternative", ...)
http_archive(name = "boringssl", ...)

$ cat BUILD
config_setting(
    name = "alt_ssl",
    define_values = {
        "ssl_library": "alternative",
    },
)

alias(
    name = "ssl",
    actual = select({
        "//:alt_ssl": "@alternative//:ssl",
        "//conditions:default": "@boringssl//:ssl",
    }),
)

この設定では、--define ssl_library=alternative を渡すと、//:ssl または //external:ssl に依存するターゲットに @alternative//:ssl にある代替手段が表示されます。

select() が期待する値を選択しないのはなぜですか?

//myapp:foo に、期待する条件を選択しない select() がある場合は、cquerybazel config を使用してデバッグします。

//myapp:foo がビルドする最上位のターゲットの場合は、次のコマンドを実行します。

$ bazel cquery //myapp:foo <desired build flags>
//myapp:foo (12e23b9a2b534a)

サブグラフ内のどこか //myapp:foo に依存する他のターゲット //bar をビルドする場合は、次のコマンドを実行します。

$ bazel cquery 'somepath(//bar, //myapp:foo)' <desired build flags>
//bar:bar   (3ag3193fee94a2)
//bar:intermediate_dep (12e23b9a2b534a)
//myapp:foo (12e23b9a2b534a)

//myapp:foo の横にある (12e23b9a2b534a) は、//myapp:fooselect() を解決する構成のハッシュです。その値は bazel config で調べることができます。

$ bazel config 12e23b9a2b534a
BuildConfigurationValue 12e23b9a2b534a
Fragment com.google.devtools.build.lib.analysis.config.CoreOptions {
  cpu: darwin
  compilation_mode: fastbuild
  ...
}
Fragment com.google.devtools.build.lib.rules.cpp.CppOptions {
  linkopt: [-Dfoo=bar]
  ...
}
...

次に、この出力を各 config_setting で想定される設定と比較します。

//myapp:foo は、同じビルド内の異なる構成に存在する場合があります。somepath を使用して適切なクエリを取得する方法については、cquery のドキュメントをご覧ください。

select() がプラットフォームに対応していないのはなぜですか?

Bazel は、セマンティクスが不明確なため、指定されたプラットフォームがターゲット プラットフォームであるかどうかを確認する構成可能な属性をサポートしていません。

例:

platform(
    name = "x86_linux_platform",
    constraint_values = [
        "@platforms//cpu:x86",
        "@platforms//os:linux",
    ],
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":x86_linux_platform": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

この BUILD ファイルで、ターゲット プラットフォームに @platforms//cpu:x86@platforms//os:linux の両方の制約があり、:x86_linux_platform がここで定義されていない場合は、どの select() を使用する必要がありますか。BUILD ファイルの作成者と別のプラットフォームを定義したユーザーは、考え方が異なる可能性があります。

別の方法があれば教えてください。

代わりに、次の制約がある任意のプラットフォームに一致する config_setting を定義します。

config_setting(
    name = "is_x86_linux",
    constraint_values = [
        "@platforms//cpu:x86",
        "@platforms//os:linux",
    ],
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":is_x86_linux": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

このプロセスは特定のセマンティクスを定義して、どのプラットフォームが目的の条件を満たしているかをユーザーに明確に示します。

プラットフォームで本当に select を行いたい場合は、

ビルド要件でプラットフォームの確認が特に必要な場合は、config_setting--platforms フラグの値を反転できます。

config_setting(
    name = "is_specific_x86_linux_platform",
    values = {
        "platforms": ["//package:x86_linux_platform"],
    },
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":is_specific_x86_linux_platform": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

Bazel チームは、これを承認することはありません。想定された条件が一致しない場合、ビルドを過度に制約し、ユーザーを混乱させます。