ルール

ルールは、Bazel が入力に対して実行して一連の出力を生成する一連のアクションを定義します。これらの出力は、ルールの実装関数から返されるプロバイダで参照されます。たとえば、C++ バイナリルールは次のようになります。

1. .cpp ソースファイル（入力）のセットを取得します。
2. ソースファイル（アクション）で g++ を実行します。
3. 実行可能出力と他のファイルを含めて DefaultInfo プロバイダを返して、ランタイムで使用できるようにします。
4. ターゲットとその依存関係から収集された C++ 固有の情報を含む CcInfo プロバイダを返します。

Bazel の観点では、g++ と標準 C++ ライブラリもこのルールの入力です。ルール作成者は、ルールへのユーザー提供入力だけでなく、アクションの実行に必要なすべてのツールとライブラリも考慮する必要があります。

ルールを作成または変更する前に、Bazel のビルドフェーズをよく理解してください。ビルドの 3 つのフェーズ（読み込み、分析、実行）を理解することが重要です。ルールとマクロの違いを理解するには、マクロについても学習することをおすすめします。始める前に、ルール チュートリアルをご覧ください。このページを参照用として使用します。

Bazel 自体には、いくつかのルールが組み込まれています。genrule や filegroup などのこれらのネイティブ ルールは、コア サポートを提供します。独自のルールを定義することで、Bazel がネイティブにサポートしていない言語とツールのサポートを追加できます。

Bazel には、Starlark 言語を使用してルールを作成するための拡張モデルが用意されています。これらのルールは .bzl ファイルで記述され、BUILD ファイルから直接読み込むことができます。

独自のルールを定義する場合は、サポートする属性と出力の生成方法を決定できます。

ルールの implementation 関数は、分析フェーズでの正確な動作を定義します。この関数は外部コマンドを実行しません。代わりに、後で実行フェーズでルールの出力を構築するために使用されるアクションを登録します（必要に応じて）。

ルールの作成

.bzl ファイルで rule 関数を使用して新しいルールを定義し、結果をグローバル変数に保存します。rule の呼び出しでは、属性と実装関数を指定します。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "deps": attr.label_list(),
        ...
    },
)

これにより、example_library という名前のルールの種類が定義されます。

また、rule の呼び出しでは、ルールが実行ファイル（executable = True を使用）またはテスト実行可能ファイル（test = True を使用）を作成するかどうかも指定する必要があります。後者の場合、ルールはテストルールであり、ルールの名前の末尾は _test にする必要があります。

ターゲットのインスタンス化

ルールは BUILD ファイルで読み込みして呼び出すことができます。

load('//some/pkg:rules.bzl', 'example_library')

example_library(
    name = "example_target",
    deps = [":another_target"],
    ...
)

ビルドルールの各呼び出しは値を返しませんが、ターゲットを定義するという副作用があります。これはルールのインスタンス化と呼ばれます。これにより、新しいターゲットの名前と、ターゲットの属性の値を指定します。

ルールは、Starlark 関数から呼び出し、.bzl ファイルに読み込むこともできます。ルールを呼び出す Starlark 関数は、Starlark マクロと呼ばれます。Starlark マクロは最終的には BUILD ファイルから呼び出す必要があります。また、BUILD ファイルが評価されてターゲットがインスタンス化される読み込みフェーズでのみ呼び出すことができます。

属性

属性はルールの引数です。属性は、ターゲットの実装に特定の値を提供できます。また、他のターゲットを参照して、依存関係のグラフを作成することもできます。

srcs や deps などのルール固有の属性は、属性名からスキーマ（attr モジュールを使用して作成）へのマップを rule の attrs パラメータに渡すことで定義します。name や visibility などの共通の属性は、すべてのルールに暗黙的に追加されます。追加属性は、特に実行可能ルールとテストルールに暗黙的に追加されます。ルールに暗黙的に追加される属性は、attrs に渡される辞書に含めることはできません。

依存関係属性

ソースコードを処理するルールでは、通常、さまざまな依存関係のタイプを処理するために次の属性を定義します。

• srcs は、ターゲットのアクションによって処理されるソースファイルを指定します。多くの場合、属性スキーマには、ルールが処理するソースファイルの種類に想定されるファイル拡張子が指定されています。ヘッダー ファイルを使用する言語のルールでは、通常、ターゲットとそのコンシューマによって処理されるヘッダーに個別の hdrs 属性を指定します。
• deps は、ターゲットのコード依存関係を指定します。属性スキーマでは、これらの依存関係を提供するプロバイダを指定する必要があります。（たとえば、cc_library は CcInfo を提供します）。
• data は、ターゲットに依存する実行可能ファイルに対して実行時に利用可能にするファイルを指定します。これにより、任意のファイルを指定できるようになります。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = [".example"]),
        "hdrs": attr.label_list(allow_files = [".header"]),
        "deps": attr.label_list(providers = [ExampleInfo]),
        "data": attr.label_list(allow_files = True),
        ...
    },
)

以下は、依存関係属性の例です。入力ラベルを指定する属性（attr.label_list、attr.label、attr.label_keyed_string_dict で定義された属性）は、ターゲットが定義されたときに、その属性にラベル（または対応する Label オブジェクト）がリストされているターゲットとターゲットの間に特定のタイプの依存関係を指定します。これらのラベルのリポジトリとパスは、定義されたターゲットに対して相対的に解決されます。

example_library(
    name = "my_target",
    deps = [":other_target"],
)

example_library(
    name = "other_target",
    ...
)

この例では、other_target は my_target の依存関係であるため、other_target が最初に分析されます。ターゲットの依存関係グラフに循環がある場合はエラーです。

非公開属性と暗黙的な依存関係

デフォルト値を持つ依存関係属性は、暗黙的な依存関係を作成します。ユーザーが BUILD ファイルで指定しないターゲット グラフの一部であるため、暗黙的です。暗黙的な依存関係は、ルールとツール（コンパイラなどのビルド時依存関係）の関係をハードコードする場合に便利です。ほとんどの場合、ユーザーはルールで使用するツールを指定することに関心がありません。ルールの実装関数内では、これは他の依存関係と同様に扱われます。

ユーザーにその値をオーバーライドすることを許可しないで暗黙的な依存関係を提供する場合は、アンダースコア（_）で始まる名前を指定して属性を非公開にできます。非公開属性にはデフォルト値が必要です。通常、プライベート属性は暗黙的な依存関係にのみ使用します。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        ...
        "_compiler": attr.label(
            default = Label("//tools:example_compiler"),
            allow_single_file = True,
            executable = True,
            cfg = "exec",
        ),
    },
)

この例では、example_library タイプのすべてのターゲットにコンパイラ //tools:example_compiler に対する暗黙的な依存関係があります。これにより、ユーザーがラベルを入力として渡さなくても、example_library の実装関数はコンパイラを呼び出すアクションを生成できます。_compiler は非公開属性であるため、ctx.attr._compiler は常にこのルールタイプのすべてのターゲットで //tools:example_compiler を参照します。または、アンダースコアなしで属性に compiler という名前を付け、デフォルト値をそのままにすることもできます。これにより、必要に応じて別のコンパイラを代用できますが、コンパイラのラベルを意識する必要はありません。

暗黙的な依存関係は通常、ルールの実装と同じリポジトリにあるツールに使用されます。ツールが実行プラットフォームまたは別のリポジトリから取得された場合は、ルールでそのツールをツールチェーンから取得する必要があります。

出力属性

出力属性（attr.output や attr.output_list など）は、ターゲットが生成する出力ファイルを宣言します。これらは、次の 2 つの点で依存関係属性と異なります。

• 他の場所で定義されたターゲットを参照するのではなく、出力ファイル ターゲットを定義します。
• 出力ファイル ターゲットは、インスタンス化されたルール ターゲットに依存します。

通常、出力属性は、ルールでターゲット名に基づかないユーザー定義名の出力を作成する必要がある場合にのみ使用されます。ルールに出力属性が 1 つある場合、通常の名前は out または outs です。

出力属性は、事前宣言された出力を作成する際に推奨される方法です。この出力は、特定の依存関係として使用したり、コマンドラインからリクエストしたりできます。

実装関数

すべてのルールには implementation 関数が必要です。これらの関数は分析フェーズで厳密に実行され、読み込みフェーズで生成されたターゲットのグラフを、実行フェーズで実行されるアクションのグラフに変換します。そのため、実装関数は実際にファイルを読み書きできません。

ルールの実装関数は通常、非公開です（名前の先頭にアンダースコアを付けます）。通常は、ルールと同じ名前が付けられますが、末尾に _impl が付きます。

実装関数は 1 つのパラメータを受け取ります。ルール コンテキスト（通常は ctx という名前）です。プロバイダのリストが返されます。

ターゲット

依存関係は、分析時に Target オブジェクトとして表されます。これらのオブジェクトには、ターゲットの実装関数が実行されたときに生成されたプロバイダが含まれています。

ctx.attr には、各依存関係属性の名前に対応するフィールドがあり、その属性を使用する各直接依存関係を表す Target オブジェクトが含まれています。label_list 属性の場合、これは Targets のリストです。label 属性の場合、これは単一の Target または None です。

プロバイダ オブジェクトのリストは、ターゲットの実装関数によって返されます。

return [ExampleInfo(headers = depset(...))]

これらには、インデックス表記（[]）を使用してアクセスできます。プロバイダのタイプをキーとして使用します。これらは、Starlark で定義されたカスタム プロバイダ、または Starlark グローバル変数として使用可能なネイティブ ルールのプロバイダです。

たとえば、ルールが hdrs 属性を使用してヘッダー ファイルを取得し、ターゲットとそのコンシューマのコンパイル アクションに提供する場合、次のように収集できます。

def _example_library_impl(ctx):
    ...
    transitive_headers = [hdr[ExampleInfo].headers for hdr in ctx.attr.hdrs]

以前の構造体スタイルがありますが、使用は強くおすすめしません。ルールは移行する必要があります。

ファイル

ファイルは File オブジェクトで表されます。Bazel は分析フェーズ中にファイル I/O を実行しないため、これらのオブジェクトを使用してファイルの内容を直接読み書きすることはできません。代わりに、アクションを出力する関数（ctx.actions を参照）に渡され、アクション グラフを構成します。

File は、ソースファイルまたは生成ファイルのいずれかです。生成される各ファイルは、1 つのアクションの出力である必要があります。ソースファイルは、どのアクションの出力にもできません。

依存関係属性ごとに、ctx.files の対応するフィールドには、その属性を使用するすべての依存関係のデフォルト出力のリストが含まれます。

def _example_library_impl(ctx):
    ...
    headers = depset(ctx.files.hdrs, transitive = transitive_headers)
    srcs = ctx.files.srcs
    ...

ctx.file には、仕様が allow_single_file = True に設定された依存関係属性の File または None が 1 つ含まれます。ctx.executable は ctx.file と同じように動作しますが、仕様で executable = True が設定されている依存関係属性のフィールドのみが含まれます。

出力の宣言

分析フェーズでは、ルールの実装関数によって出力が作成される場合があります。すべてのラベルは読み込みフェーズ中に把握されている必要があるため、これらの追加出力にはラベルがありません。出力の File オブジェクトは、ctx.actions.declare_file と ctx.actions.declare_directory を使用して作成できます。多くの場合、出力の名前はターゲットの名前 ctx.label.name に基づいています。

def _example_library_impl(ctx):
  ...
  output_file = ctx.actions.declare_file(ctx.label.name + ".output")
  ...

出力属性用に作成されたものなど、事前宣言された出力の場合、代わりに ctx.outputs の対応するフィールドから File オブジェクトを取得できます。

操作

アクションは、一連の入力から一連の出力を生成する方法を表します（「hello.c で gcc を実行して hello.o を取得する」など）。アクションが作成されても、Bazel はコマンドをすぐに実行しません。アクションは別のアクションの出力に依存する可能性があるため、依存関係のグラフに登録されます。たとえば、C では、リンカーはコンパイラ後に呼び出す必要があります。

アクションを作成する汎用関数は ctx.actions で定義されています。

• ctx.actions.run: 実行可能ファイルを実行します。
• ctx.actions.run_shell: シェルコマンドを実行します。
• ctx.actions.write: 文字列をファイルに書き込みます。
• ctx.actions.expand_template: テンプレートからファイルを生成します。

ctx.actions.args を使用すると、アクションの引数を効率的に蓄積できます。実行時まで depset をフラット化する必要がなくなります。

def _example_library_impl(ctx):
    ...

    transitive_headers = [dep[ExampleInfo].headers for dep in ctx.attr.deps]
    headers = depset(ctx.files.hdrs, transitive = transitive_headers)
    srcs = ctx.files.srcs
    inputs = depset(srcs, transitive = [headers])
    output_file = ctx.actions.declare_file(ctx.label.name + ".output")

    args = ctx.actions.args()
    args.add_joined("-h", headers, join_with = ",")
    args.add_joined("-s", srcs, join_with = ",")
    args.add("-o", output_file)

    ctx.actions.run(
        mnemonic = "ExampleCompile",
        executable = ctx.executable._compiler,
        arguments = [args],
        inputs = inputs,
        outputs = [output_file],
    )
    ...

アクションは、入力ファイルのリストまたは depset を受け取り、出力ファイルの（空ではない）リストを生成します。入力ファイルと出力ファイルのセットは、分析フェーズで把握する必要があります。依存関係のプロバイダなど、属性の値に依存する場合もありますが、実行の結果には依存しません。たとえば、アクションで unzip コマンドを実行する場合、インフレートするファイルを（unzip を実行する前に）指定する必要があります。内部で可変数のファイルを作成するアクションは、それらを単一のファイル（zip、tar、その他のアーカイブ形式など）にラップできます。

アクションには、すべての入力をリストする必要があります。使用されていない入力の一覧表示は許可されますが、効率的ではありません。

アクションの出力はすべて作成する必要があります。他のファイルも書き込むことができますが、出力に含まれていないものはコンシューマが使用できません。宣言された出力はすべて、なんらかのアクションによって書き込まれる必要があります。

アクションは純粋関数に似ています。提供された入力にのみ依存し、コンピュータ情報、ユーザー名、時計、ネットワーク、I/O デバイスにアクセスしないでください（入力の読み取りと出力の書き込みを除く）。これは、出力がキャッシュに保存されて再利用されるため重要です。

依存関係は Bazel によって解決され、Bazel は実行するアクションを決定します。依存関係グラフに循環がある場合はエラーです。アクションを作成しても、そのアクションが必ず実行されるとは限りません。これは、そのアクションの出力がビルドに必要かどうかによって異なります。

プロバイダ

プロバイダは、ルールが依存する他のルールに公開する情報の一部です。このデータには、出力ファイル、ライブラリ、ツールのコマンドラインに渡すパラメータなど、ターゲットのコンシューマが認識すべきあらゆるデータを含めることができます。

ルールの実装関数は、インスタンス化されたターゲットの直接依存関係からプロバイダのみを読み取ることができるため、ルールは、ターゲットのコンシューマが認識する必要があるターゲットの依存関係から情報を転送する必要があります。通常は、その情報を depset に蓄積します。

ターゲットのプロバイダは、実装関数によって返されるプロバイダ オブジェクトのリストで指定します。

古い実装関数は、実装関数がプロバイダ オブジェクトのリストではなく struct を返すレガシー スタイルで記述することもできます。このスタイルは使用しないことを強くおすすめします。ルールは移行しないようにしてください。

デフォルトの出力

ターゲットのデフォルト出力は、コマンドラインからターゲットのビルドがリクエストされたときにデフォルトでリクエストされる出力です。たとえば、java_library ターゲット //pkg:foo のデフォルト出力は foo.jar であるため、bazel build //pkg:foo コマンドでビルドされます。

デフォルトの出力は、DefaultInfo の files パラメータで指定します。

def _example_library_impl(ctx):
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        ...
    ]

ルールの実装で DefaultInfo が返されない場合、または files パラメータが指定されていない場合、DefaultInfo.files はデフォルトで事前に宣言されたすべての出力（通常は出力属性によって作成された出力）になります。

アクションを実行するルールでは、出力が直接使用されないことが想定されていても、デフォルトの出力を指定する必要があります。リクエストされた出力のグラフにないアクションはプルーニングされます。出力がターゲットのコンシューマによってのみ使用される場合、ターゲットが単独で構築されている場合、これらのアクションは実行されません。失敗したターゲットのみを再ビルドしても失敗が再現されないため、デバッグが難しくなります。

Runfiles

Runfile は、（ビルド時ではなく）実行時にターゲットによって使用される一連のファイルです。実行フェーズで、Bazel は runfiles を指すシンボリック リンクを含むディレクトリ ツリーを作成します。これにより、バイナリの環境がステージングされ、実行時にランファイルにアクセスできるようになります。

ランファイルは、ルールの作成時に手動で追加できます。runfiles オブジェクトは、ルール コンテキスト ctx.runfiles の runfiles メソッドで作成し、DefaultInfo の runfiles パラメータに渡すことができます。実行可能ルールの実行可能出力は、暗黙的に実行ファイルに追加されます。

一部のルールでは、通常は data という名前の属性を指定します。この属性の出力は、ターゲットのランファイルに追加されます。Runfile は、data からだけでなく、最終的な実行用のコードを提供する可能性のある属性（通常は srcs（data に関連付けられた filegroup ターゲットが含まれている場合があります）と deps）からも統合する必要があります。

def _example_library_impl(ctx):
    ...
    runfiles = ctx.runfiles(files = ctx.files.data)
    transitive_runfiles = []
    for runfiles_attr in (
        ctx.attr.srcs,
        ctx.attr.hdrs,
        ctx.attr.deps,
        ctx.attr.data,
    ):
        for target in runfiles_attr:
            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
    runfiles = runfiles.merge_all(transitive_runfiles)
    return [
        DefaultInfo(..., runfiles = runfiles),
        ...
    ]

カスタム プロバイダ

プロバイダは provider 関数を使用して定義し、ルール固有の情報を伝達できます。

ExampleInfo = provider(
    "Info needed to compile/link Example code.",
    fields = {
        "headers": "depset of header Files from transitive dependencies.",
        "files_to_link": "depset of Files from compilation.",
    },
)

ルール実装関数は、プロバイダ インスタンスを作成して返すことができます。

def _example_library_impl(ctx):
  ...
  return [
      ...
      ExampleInfo(
          headers = headers,
          files_to_link = depset(
              [output_file],
              transitive = [
                  dep[ExampleInfo].files_to_link for dep in ctx.attr.deps
              ],
          ),
      )
  ]

プロバイダのカスタム初期化

カスタムの前処理と検証ロジックを使用して、プロバイダのインスタンス化を保護できます。これにより、すべてのプロバイダ インスタンスが特定の不変条件を満たすようにしたり、インスタンスを取得するためのすっきりした API をユーザーに提供したりできます。

これを行うには、init コールバックを provider 関数に渡します。このコールバックが指定されている場合、provider() の戻り型は、2 つの値のタプル（init が使用されていない場合の通常の戻り値であるプロバイダ シンボルと「未加工のコンストラクタ」）に変更されます。

この場合、プロバイダ シンボルが呼び出されると、新しいインスタンスを直接返すのではなく、引数を init コールバックに転送します。コールバックの戻り値は、フィールド名（文字列）を値にマッピングする辞書である必要があります。これは、新しいインスタンスのフィールドを初期化するために使用されます。コールバックには任意の署名が付けられる場合があります。引数が署名と一致しない場合、コールバックが直接呼び出されたようにエラーが報告されます。

一方、未加工のコンストラクタは init コールバックをバイパスします。

次の例では、init を使用して引数を前処理して検証します。

# //pkg:exampleinfo.bzl

_core_headers = [...]  # private constant representing standard library files

# Keyword-only arguments are preferred.
def _exampleinfo_init(*, files_to_link, headers = None, allow_empty_files_to_link = False):
    if not files_to_link and not allow_empty_files_to_link:
        fail("files_to_link may not be empty")
    all_headers = depset(_core_headers, transitive = headers)
    return {"files_to_link": files_to_link, "headers": all_headers}

ExampleInfo, _new_exampleinfo = provider(
    fields = ["files_to_link", "headers"],
    init = _exampleinfo_init,
)

ルールの実装では、次のようにプロバイダをインスタンス化できます。

ExampleInfo(
    files_to_link = my_files_to_link,  # may not be empty
    headers = my_headers,  # will automatically include the core headers
)

未加工のコンストラクタを使用すると、init ロジックを経由しない代替の公開ファクトリ関数を定義できます。たとえば、exampleinfo.bzl で次のように定義できます。

def make_barebones_exampleinfo(headers):
    """Returns an ExampleInfo with no files_to_link and only the specified headers."""
    return _new_exampleinfo(files_to_link = depset(), headers = all_headers)

通常、未加工のコンストラクタは、名前がアンダースコア（上記の _new_exampleinfo）で始まる変数にバインドされるため、ユーザーコードがそれを読み込んで任意のプロバイダ インスタンスを生成することはできません。

init のもう 1 つの用途は、ユーザーがプロバイダ シンボルを呼び出すのを完全に防ぎ、代わりにファクトリ関数を使用するように強制することです。

def _exampleinfo_init_banned(*args, **kwargs):
    fail("Do not call ExampleInfo(). Use make_exampleinfo() instead.")

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init_banned)

def make_exampleinfo(...):
    ...
    return _new_exampleinfo(...)

実行可能ルールとテストルール

実行可能ルールは、bazel run コマンドで呼び出せるターゲットを定義します。テストルールは、bazel test コマンドで呼び出せるターゲットを持つ特別な種類の実行可能ルールです。実行可能ルールとテストルールは、rule の呼び出しでそれぞれの executable または test 引数を True に設定することで作成されます。

example_binary = rule(
   implementation = _example_binary_impl,
   executable = True,
   ...
)

example_test = rule(
   implementation = _example_binary_impl,
   test = True,
   ...
)

テストルールの名前は _test で終わる必要があります。（テストのターゲット名も、慣例として _test で終わることがよくありますが、これは必須ではありません）。テスト以外のルールでは、この接尾辞を付けないでください。

どちらの種類のルールでも、run または test コマンドで呼び出される実行可能出力ファイル（事前宣言されている場合も、されていない場合もあります）を生成する必要があります。この実行可能ファイルとして使用するルールの出力を Bazel に伝えるには、返された DefaultInfo プロバイダの executable 引数として渡します。この executable は、ルールのデフォルト出力に追加されます（そのため、executable と files の両方に渡す必要はありません）。また、runfiles にも暗黙的に追加されます。

def _example_binary_impl(ctx):
    executable = ctx.actions.declare_file(ctx.label.name)
    ...
    return [
        DefaultInfo(executable = executable, ...),
        ...
    ]

このファイルを生成するアクションは、ファイルに実行可能ビットを設定する必要があります。ctx.actions.run アクションまたは ctx.actions.run_shell アクションの場合、アクションによって呼び出される基になるツールによって行う必要があります。ctx.actions.write アクションの場合は is_executable = True を渡します。

従来の動作として、実行可能ルールには特別な ctx.outputs.executable の事前宣言出力があります。DefaultInfo で指定しない場合、このファイルはデフォルトの実行可能ファイルとして機能します。それ以外の場合は使用しないでください。この出力メカニズムは、分析時の実行可能ファイル名のカスタマイズをサポートしていないため、非推奨となっています。

実行可能ルールとテストルールの例をご覧ください。

実行可能ルールとテストルールには、すべてのルールに追加される属性に加えて、暗黙的に定義された追加の属性があります。暗黙的に追加された属性のデフォルトは変更できませんが、デフォルトを変更する Starlark マクロで非公開ルールをラップすることで回避できます。

def example_test(size = "small", **kwargs):
  _example_test(size = size, **kwargs)

_example_test = rule(
 ...
)

Runfile の場所

実行可能ターゲットが bazel run（または test）で実行されると、runfiles ディレクトリのルートが実行可能ファイルの隣に配置されます。パスは次のように関連しています。

# Given launcher_path and runfile_file:
runfiles_root = launcher_path.path + ".runfiles"
workspace_name = ctx.workspace_name
runfile_path = runfile_file.short_path
execution_root_relative_path = "%s/%s/%s" % (
    runfiles_root, workspace_name, runfile_path)

runfiles ディレクトリの下にある File へのパスは、File.short_path に対応します。

bazel によって直接実行されるバイナリは、runfiles ディレクトリのルートに隣接しています。ただし、実行ファイルから呼び出されるバイナリでは、同じ仮定はできません。これを軽減するために、各バイナリは、環境またはコマンドライン引数またはフラグを使用して、ランファイルのルートをパラメータとして受け取る方法を提供する必要があります。これにより、バイナリは呼び出すバイナリに、正規の正規ランファイル ルートを渡すことができます。これが設定されていない場合、バイナリは、これが最初に呼び出されたバイナリであると推測し、隣接する runfiles ディレクトリを探します。

高度なトピック

出力ファイルのリクエスト

1 つのターゲットに複数の出力ファイルを含めることができます。bazel build コマンドが実行されると、コマンドに指定されたターゲットの出力の一部がリクエストされたと見なされます。Bazel は、リクエストされたファイルと、それらが直接的または間接的に依存するファイルのみをビルドします。（アクショングラフに関して、Bazel は、リクエストされたファイルの伝播依存関係として到達可能なアクションのみを実行します）。

デフォルトの出力に加えて、事前宣言された出力をコマンドラインから明示的にリクエストできます。ルールでは、出力属性を使用して事前宣言された出力を指定できます。その場合、ユーザーはルールをインスタンス化する際に、出力のラベルを明示的に選択します。出力属性の File オブジェクトを取得するには、ctx.outputs の対応する属性を使用します。ルールでは、ターゲット名に基づいて事前宣言された出力を暗黙的に定義することもできますが、この機能は非推奨です。

デフォルトの出力に加えて、出力グループがあります。これは、一緒にリクエストできる出力ファイルのコレクションです。これらは --output_groups でリクエストできます。たとえば、ターゲット //pkg:mytarget が debug_files 出力グループを持つルールタイプの場合、これらのファイルは bazel build //pkg:mytarget --output_groups=debug_files を実行してビルドできます。事前宣言されていない出力にはラベルがないため、デフォルト出力または出力グループに表示されるようにすることでのみリクエストできます。

出力グループは OutputGroupInfo プロバイダで指定できます。多くの組み込みプロバイダとは異なり、OutputGroupInfo は任意の名前のパラメータを取り、その名前の出力グループを定義できます。

def _example_library_impl(ctx):
    ...
    debug_file = ctx.actions.declare_file(name + ".pdb")
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        OutputGroupInfo(
            debug_files = depset([debug_file]),
            all_files = depset([output_file, debug_file]),
        ),
        ...
    ]

また、ほとんどのプロバイダとは異なり、OutputGroupInfo は、同じ出力グループを定義しない限り、アスペクトとそのアスペクトが適用されるルール ターゲットの両方で返すことができます。その場合、結果のプロバイダが統合されます。

通常、OutputGroupInfo は、特定の種類のファイルをターゲットからコンシューマのアクションに伝えるために使用しないでください。代わりに、ルール固有のプロバイダを定義します。

構成

別のアーキテクチャ用の C++ バイナリをビルドするとします。ビルドは複雑で、複数のステップが含まれる場合があります。コンパイラやコード生成ツールなどの中間バイナリは、実行プラットフォーム（ホストまたはリモート エグゼキュータ）で実行する必要があります。最終出力などの一部のバイナリは、ターゲット アーキテクチャ用にビルドする必要があります。

このため、Bazel には「構成」と遷移のコンセプトがあります。最上位のターゲット（コマンドラインでリクエストされたターゲット）は「target」構成に組み込まれ、実行プラットフォームで実行する必要があるツールは「exec」構成に組み込まれます。ルールは、コンパイラに渡される CPU アーキテクチャを変更するなど、構成に応じて異なるアクションを生成する場合があります。場合によっては、異なる構成に同じライブラリが必要になることがあります。その場合、分析され、複数回ビルドされる可能性があります。

デフォルトでは、Bazel はターゲット自体と同じ構成でターゲットの依存関係をビルドします。つまり、遷移はありません。依存関係がターゲットのビルドに必要なツールである場合は、対応する属性で exec 構成への移行を指定する必要があります。これにより、実行プラットフォーム用にツールとそのすべての依存関係がビルドされます。

依存関係属性ごとに、cfg を使用して、依存関係を同じ構成でビルドするか、exec 構成に移行するかを決定できます。依存関係属性にフラグ executable = True がある場合は、cfg を明示的に設定する必要があります。これは、誤った構成のツールを誤ってビルドしないようにするためのものです。例を表示

通常、実行時に必要なソース、依存ライブラリ、実行可能ファイルは同じ構成を使用できます。

ビルドの一部として実行されるツール（コンパイラやコード生成ツールなど）は、exec 構成用にビルドする必要があります。この場合は、属性に cfg = "exec" を指定します。

それ以外の場合は、実行時に使用される実行可能ファイル（テストの一部など）は、ターゲット構成用にビルドする必要があります。この場合は、属性に cfg = "target" を指定します。

cfg = "target" は実際には何もしません。これは、ルール設計者が意図を明示するのを支援するための純粋な便宜上の値です。executable = False（cfg は省略可）の場合は、判読性が本当に向上する場合にのみ設定します。

また、cfg = my_transition を使用してユーザー定義の遷移を使用することもできます。これにより、ルール作成者は構成を変更する際の柔軟性が大幅に向上しますが、ビルドグラフが大きくなり、わかりにくくなるという欠点があります。

注: これまで、Bazel には実行プラットフォームのコンセプトがなく、代わりにすべてのビルドアクションがホストマシンで実行されると見なされていました。6.0 より前のバージョンの Bazel では、これを表す個別の「ホスト」構成を作成しました。コードや古いドキュメントで「ホスト」という用語が使用されている場合は、このホストを指しています。この概念的なオーバーヘッドを回避するには、Bazel 6.0 以降を使用することをおすすめします。

構成フラグメント

ルールは、cpp や java などの構成フラグメントにアクセスできます。ただし、アクセスエラーを回避するために、必要なすべてのフラグメントを宣言する必要があります。

def _impl(ctx):
    # Using ctx.fragments.cpp leads to an error since it was not declared.
    x = ctx.fragments.java
    ...

my_rule = rule(
    implementation = _impl,
    fragments = ["java"],      # Required fragments of the target configuration
    ...
)

Runfiles シンボリック リンク

通常、runfiles ツリー内のファイルの相対パスは、ソースツリーまたは生成された出力ツリー内のそのファイルの相対パスと同じです。なんらかの理由でこれらを区別する必要がある場合は、root_symlinks または symlinks 引数を指定できます。root_symlinks は、ファイルへのパスをマッピングする辞書です。パスは runfiles ディレクトリのルートからの相対パスです。symlinks ディクショナリは同じですが、パスにはメイン ワークスペースの名前が暗黙的に接頭辞として追加されます（現在のターゲットを含むリポジトリの名前ではありません）。

    ...
    runfiles = ctx.runfiles(
        root_symlinks = {"some/path/here.foo": ctx.file.some_data_file2}
        symlinks = {"some/path/here.bar": ctx.file.some_data_file3}
    )
    # Creates something like:
    # sometarget.runfiles/
    #     some/
    #         path/
    #             here.foo -> some_data_file2
    #     <workspace_name>/
    #         some/
    #             path/
    #                 here.bar -> some_data_file3

symlinks または root_symlinks を使用する場合は、2 つの異なるファイルを runfiles ツリー内の同じパスにマッピングしないように注意してください。これにより、競合を示すエラーでビルドが失敗します。この問題を解決するには、ctx.runfiles 引数を変更して競合を解消する必要があります。このチェックは、ルールを使用するターゲットと、それらのターゲットに依存するあらゆる種類のターゲットに対して行われます。これは、ツールが別のツールによって間接的に使用される可能性が高い場合に特に危険です。シンボリック リンク名は、ツールの実行ファイルとそのすべての依存関係で一意である必要があります。

コード カバレッジ

coverage コマンドを実行すると、ビルドで特定のターゲットに対するカバレッジ インストルメンテーションの追加が必要になる場合があります。ビルドでは、計測対象のソースファイルのリストも収集されます。検討対象となるターゲットのサブセットは、--instrumentation_filter フラグで制御されます。--instrument_test_targets が指定されていない限り、テストターゲットは除外されます。

ルールの実装でビルド時にカバレッジ計測を追加する場合は、実装関数でそのことを考慮する必要があります。ターゲットのソースを計測する必要がある場合、ctx.coverage_instrumented はカバレッジ モードで True を返します。

# Are this rule's sources instrumented?
if ctx.coverage_instrumented():
  # Do something to turn on coverage for this compile action

カバレッジ モードで常にオンにする必要があるロジック（ターゲットのソースが特に計測されているかどうかに関係なく）は、ctx.configuration.coverage_enabled に条件を付けることができます。

コンパイル前にルールが依存関係のソース（ヘッダー ファイルなど）を直接含める場合、依存関係のソースを計測する必要がある場合は、コンパイル時計測を有効にする必要もあります。

# Are this rule's sources or any of the sources for its direct dependencies
# in deps instrumented?
if (ctx.configuration.coverage_enabled and
    (ctx.coverage_instrumented() or
     any([ctx.coverage_instrumented(dep) for dep in ctx.attr.deps]))):
    # Do something to turn on coverage for this compile action

また、ルールには、coverage_common.instrumented_files_info を使用して構築された InstrumentedFilesInfo プロバイダのカバレッジに関連する属性に関する情報も提供する必要があります。instrumented_files_info の dependency_attributes パラメータには、deps などのコード依存関係や data などのデータ依存関係など、すべてのランタイム依存関係属性を一覧表示する必要があります。カバレッジ計測を追加する可能性がある場合は、source_attributes パラメータにルールのソースファイル属性をリストします。

def _example_library_impl(ctx):
    ...
    return [
        ...
        coverage_common.instrumented_files_info(
            ctx,
            dependency_attributes = ["deps", "data"],
            # Omitted if coverage is not supported for this rule:
            source_attributes = ["srcs", "hdrs"],
        )
        ...
    ]

InstrumentedFilesInfo が返されない場合、dependency_attributes の属性スキーマで cfg が "exec" に設定されていないツール以外の依存関係属性ごとに、デフォルトの依存関係が作成されます。（srcs などの属性が source_attributes ではなく dependency_attributes に配置されるため、これは理想的な動作ではありませんが、依存関係チェーン内のすべてのルールに対して明示的なカバレッジ構成が不要になります）。

検証アクション

場合によっては、ビルドについて検証する必要があり、その検証に必要な情報はアーティファクト（ソースファイルまたは生成されたファイル）でのみ使用できます。この情報はアーティファクトに含まれているため、ルールはファイルを読み取ることができないため、分析時にこの検証を行うことはできません。代わりに、アクションは実行時にこの検証を行う必要があります。検証が失敗するとアクションも失敗し、ビルドも失敗します。

実行される検証の例としては、静的分析、lint チェック、依存関係と整合性のチェック、スタイル チェックなどがあります。

検証アクションは、アーティファクトのビルドに不要なアクションの一部を個別のアクションに移動することで、ビルドのパフォーマンスを改善することもできます。たとえば、コンパイルとリンティングを行う単一のアクションをコンパイル アクションとリンティング アクションに分割できる場合、リンティング アクションは検証アクションとして実行し、他のアクションと並行して実行できます。

これらの「検証アクション」は、入力に関することをアサートする必要があるだけであるため、ビルドの他の場所で使用されるものは生成されません。ただし、検証アクションがビルドの他の場所で使用されるものを生成しない場合、ルールはどのようにしてアクションを実行させるのでしょうか。従来のアプローチでは、検証アクションで空のファイルを出力し、その出力をビルド内の他の重要なアクションの入力に人為的に追加していました。

これは、Bazel がコンパイル アクションの実行時に常に検証アクションを実行するため機能しますが、重大な欠点があります。

1. 検証アクションがビルドのクリティカル パスにある。Bazel は、コンパイル アクションを実行するには空の出力が必要であると判断しているため、コンパイル アクションが入力を無視しても、最初に検証アクションを実行します。 これにより、並列処理が減り、ビルドが遅くなります。

2. コンパイル アクションの代わりにビルド内の他のアクションが実行される可能性がある場合は、検証アクションの空の出力もそれらのアクションに追加する必要があります（java_library のソース jar 出力など）。これは、コンパイル アクションの代わりに実行される可能性のある新しいアクションが後で追加され、空の検証出力が誤って中断される場合にも問題となります。

これらの問題を解決するには、検証出力グループを使用します。

検証出力グループ

Validations Output Group は、本来は使用されない検証アクションの出力を保持するように設計された出力グループです。これにより、他のアクションの入力に人為的に追加する必要がなくなります。

このグループは、--output_groups フラグの値や、ターゲットの依存関係（コマンドライン、依存関係、ターゲットの暗黙的な出力など）に関係なく、出力が常にリクエストされるという点で特別です。通常のキャッシュと増分処理は引き続き適用されます。検証アクションへの入力が変更されておらず、検証アクションが以前に成功した場合、検証アクションは実行されません。

この出力グループを使用する場合でも、空のファイルでも、検証アクションでファイルが出力される必要があります。これにより、通常は出力を作成しない一部のツールをラップして、ファイルが作成されるようにする必要があります。

ターゲットの検証アクションは、次の 3 つの場合に実行されません。

• ターゲットがツールとして依存している場合
• ターゲットが暗黙的な依存関係として依存されている場合（「_」で始まる属性など）
• ターゲットが exec 構成でビルドされている場合。

これらのターゲットには、検証エラーを検出する独自のビルドとテストがあることが前提とされています。

検証出力グループを使用する

検証出力グループの名前は _validation で、他の出力グループと同様に使用されます。

def _rule_with_validation_impl(ctx):

  ctx.actions.write(ctx.outputs.main, "main output\n")
  ctx.actions.write(ctx.outputs.implicit, "implicit output\n")

  validation_output = ctx.actions.declare_file(ctx.attr.name + ".validation")
  ctx.actions.run(
    outputs = [validation_output],
    executable = ctx.executable._validation_tool,
    arguments = [validation_output.path],
  )

  return [
    DefaultInfo(files = depset([ctx.outputs.main])),
    OutputGroupInfo(_validation = depset([validation_output])),
  ]


rule_with_validation = rule(
  implementation = _rule_with_validation_impl,
  outputs = {
    "main": "%{name}.main",
    "implicit": "%{name}.implicit",
  },
  attrs = {
    "_validation_tool": attr.label(
        default = Label("//validation_actions:validation_tool"),
        executable = True,
        cfg = "exec"
    ),
  }
)

検証出力ファイルは、DefaultInfo や他のアクションへの入力には追加されません。このルールの種類のターゲットがラベルに依存している場合、またはターゲットの暗黙的な出力が直接的または間接的に依存している場合、このルールタイプのターゲットに対する検証アクションは引き続き実行されます。

通常、検証アクションの出力は検証出力グループにのみ送信し、他のアクションの入力には追加しないことが重要です。そうしないと、並列処理のメリットが失われる可能性があります。ただし、Bazel には、これを適用するための特別なチェックはありません。したがって、Starlark ルールのテストで、検証アクションの出力がアクションの入力に追加されていないことをテストする必要があります。例:

load("@bazel_skylib//lib:unittest.bzl", "analysistest")

def _validation_outputs_test_impl(ctx):
  env = analysistest.begin(ctx)

  actions = analysistest.target_actions(env)
  target = analysistest.target_under_test(env)
  validation_outputs = target.output_groups._validation.to_list()
  for action in actions:
    for validation_output in validation_outputs:
      if validation_output in action.inputs.to_list():
        analysistest.fail(env,
            "%s is a validation action output, but is an input to action %s" % (
                validation_output, action))

  return analysistest.end(env)

validation_outputs_test = analysistest.make(_validation_outputs_test_impl)

検証アクション フラグ

検証アクションの実行は、--run_validations コマンドライン フラグによって制御されます。このフラグのデフォルト値は true です。

サポートが終了した機能

非推奨の事前宣言済み出力

事前宣言された出力を使用する方法は、非推奨の 2 つあります。

• rule の outputs パラメータは、事前宣言された出力ラベルを生成するための出力属性名と文字列テンプレートのマッピングを指定します。事前宣言されていない出力を使用し、出力を DefaultInfo.files に明示的に追加することをおすすめします。事前に宣言された出力のラベルの代わりに、出力を使用するルールの入力として、ルール ターゲットのラベルを使用します。

• 実行可能ルールの場合、ctx.outputs.executable は、ルール ターゲットと同じ名前の宣言済み実行可能出力を参照します。ctx.actions.declare_file(ctx.label.name) などを使用して出力を明示的に宣言し、実行可能ファイルを生成するコマンドで、実行を許可するように権限を設定してください。実行可能ファイルの出力を DefaultInfo の executable パラメータに明示的に渡します。

避けるべき Runfile の機能

ctx.runfiles 型と runfiles 型には複雑な機能セットがあり、その多くは以前の理由から保持されています。複雑さを軽減するには、次の推奨事項に沿って対応してください。

• ctx.runfiles の collect_data モードと collect_default モードは使用しないでください。これらのモードでは、特定のハードコードされた依存関係エッジ全体で、混乱を招く方法でランファイルを暗黙的に収集します。代わりに、ctx.runfiles の files または transitive_files パラメータを使用してファイルを追加するか、runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles) を使用して依存関係のランファイルをマージします。

• DefaultInfo コンストラクタの data_runfiles と default_runfiles の使用を避ける。代わりに DefaultInfo(runfiles = ...) を指定します。「デフォルト」と「データ」のランファイルの区別は、以前の理由から維持されています。たとえば、一部のルールでは、デフォルトの出力が data_runfiles に配置されますが、default_runfiles には配置されません。data_runfiles を使用する代わりに、ルールにはデフォルトの出力を含める両方と、実行ファイルを提供する属性（多くの場合 data）から default_runfiles にマージする必要があります。

• DefaultInfo から runfiles を取得する場合（通常は、現在のルールとその依存関係間での実行ファイルのマージの場合のみ）、DefaultInfo.data_runfiles ではなく DefaultInfo.default_runfiles を使用します。

以前のプロバイダからの移行

これまで、Bazel プロバイダは Target オブジェクトの単純なフィールドでした。これらのフィールドにはドット演算子を使用してアクセスし、プロバイダ オブジェクトのリストではなく、ルールの実装関数によって返された struct にフィールドを配置して作成しました。

return struct(example_info = struct(headers = depset(...)))

このようなプロバイダは、Target オブジェクトの対応するフィールドから取得できます。

transitive_headers = [hdr.example_info.headers for hdr in ctx.attr.hdrs]

このスタイルは非推奨であり、新しいコードでは使用しないでください。移行に役立つ情報については、以下をご覧ください。新しいプロバイダ メカニズムにより、名前の競合を回避できます。また、プロバイダ インスタンスにアクセスするコードにプロバイダ シンボルを使用してプロバイダを取得するよう要求することで、データの非公開化もサポートしています。

現時点では、従来のプロバイダは引き続きサポートされています。ルールは、次のように従来のプロバイダと最新のプロバイダの両方を返すことができます。

def _old_rule_impl(ctx):
  ...
  legacy_data = struct(x = "foo", ...)
  modern_data = MyInfo(y = "bar", ...)
  # When any legacy providers are returned, the top-level returned value is a
  # struct.
  return struct(
      # One key = value entry for each legacy provider.
      legacy_info = legacy_data,
      ...
      # Additional modern providers:
      providers = [modern_data, ...])

dep がこのルールのインスタンスの結果として生成された Target オブジェクトの場合、プロバイダとそのコンテンツは dep.legacy_info.x と dep[MyInfo].y として取得できます。

返される構造体には、providers に加えて、特別な意味を持つ（対応するレガシー プロバイダが作成されない）他のフィールドもいくつか指定できます。

• フィールド files、runfiles、data_runfiles、default_runfiles、executable は、DefaultInfo の同名のフィールドに対応しています。DefaultInfo プロバイダを返すときに、これらのフィールドのいずれかを指定することはできません。

• フィールド output_groups は構造体値を受け取り、OutputGroupInfo に対応します。

ルールの provides 宣言と、依存関係属性の providers 宣言では、従来のプロバイダは文字列として渡され、最新のプロバイダは Info シンボルで渡されます。移行する際は、文字列からシンボルに変更してください。すべてのルールをアトミックに更新することが難しい複雑なルールセットや大規模なルールセットの場合は、次の一連の手順に従うと簡単なことがあります。

1. 上記の構文を使用して、レガシー プロバイダを生成するルールを変更し、レガシー プロバイダとモダン プロバイダの両方を生成するようにします。以前のプロバイダを返すことを宣言するルールの場合は、その宣言を更新して、以前のプロバイダと最新のプロバイダの両方を含めます。

2. 以前のプロバイダを使用するルールを変更して、代わりに最新のプロバイダを使用する。属性宣言で以前のプロバイダが必要な場合は、代わりに最新のプロバイダを必要とするように更新します。必要に応じて、コンシューマがプロバイダを受け入れるか、プロバイダを要求するようにして、この作業をステップ 1 と交互に行うことができます。hasattr(target, 'foo') を使用して以前のプロバイダの存在をテストするか、FooInfo in target を使用して新しいプロバイダをテストします。

3. 以前のプロバイダをすべてのルールから完全に削除します。