Funciones

Contenido

• paquete
• package_group
• exports_files
• glob
• seleccionar
• subpaquetes

paquete

package(default_deprecation, default_package_metadata, default_testonly, default_visibility, features)

Esta función declara metadatos que se aplican a cada regla del paquete. Se utiliza como máximo una vez dentro de un paquete (archivo BUILD).

Se debe llamar a la función package() justo después de todas las sentencias load() en la parte superior del archivo, antes de cualquier regla.

Argumentos

Ejemplos

package(default_visibility = ["//foo:target"])

package_group

package_group(name, packages, includes)

Esta función define un conjunto de paquetes y asocia una etiqueta con el conjunto. Se puede hacer referencia a la etiqueta en los atributos visibility.

Los grupos de paquetes se usan principalmente para el control de visibilidad. Se puede hacer referencia a un destino visible de forma pública desde todos los paquetes del árbol de origen. Solo se puede hacer referencia a un objetivo visible de forma privada dentro de su propio paquete (no en subpaquetes). Entre estos extremos, un destino puede permitir el acceso a su propio paquete y a cualquiera de los paquetes descritos por uno o más grupos de paquetes. Para obtener una explicación más detallada del sistema de visibilidad, consulta el atributo visibility.

Se considera que un paquete determinado está en el grupo si coincide con el atributo packages o ya está contenido en uno de los otros grupos de paquetes mencionados en el atributo includes.

Técnicamente, los grupos de paquetes son objetivos, pero no se crean mediante reglas y no tienen protección de visibilidad en sí mismos.

Argumentos

Ejemplos

En la siguiente declaración package_group, se especifica un grupo de paquetes llamado “tropical” que contiene frutas tropicales.

package_group(
    name = "tropical",
    packages = [
        "//fruits/mango",
        "//fruits/orange",
        "//fruits/papaya/...",
    ],
)

Las siguientes declaraciones especifican los grupos de paquetes de una aplicación ficticia:

package_group(
    name = "fooapp",
    includes = [
        ":controller",
        ":model",
        ":view",
    ],
)

package_group(
    name = "model",
    packages = ["//fooapp/database"],
)

package_group(
    name = "view",
    packages = [
        "//fooapp/swingui",
        "//fooapp/webui",
    ],
)

package_group(
    name = "controller",
    packages = ["//fooapp/algorithm"],
)

exports_files

exports_files([label, ...], visibility, licenses)

exports_files() especifica una lista de archivos que pertenecen a este paquete y que se exportan a otros paquetes.

El archivo BUILD de un paquete solo puede hacer referencia directamente a archivos de origen que pertenecen a otro paquete si se exportan de forma explícita con una sentencia exports_files(). Obtén más información sobre la visibilidad de los archivos.

Como comportamiento heredado, los archivos que se mencionan como entrada a una regla se exportan con la visibilidad predeterminada hasta que se cambia la marca --incompatible_no_implicit_file_export. Sin embargo, no se debe depender de este comportamiento y se debe migrar de él de forma activa.

Argumentos

El argumento es una lista de nombres de archivos dentro del paquete actual. También se puede especificar una declaración de visibilidad. En este caso, los archivos serán visibles para los destinos especificados. Si no se especifica ninguna visibilidad, todos los paquetes podrán ver los archivos, incluso si se especificó una visibilidad predeterminada del paquete en la función package. También se pueden especificar las licencias.

Ejemplo

En el siguiente ejemplo, se exporta golden.txt, un archivo de texto del paquete test_data, para que otros paquetes puedan usarlo, por ejemplo, en el atributo data de las pruebas.

# from //test_data/BUILD

exports_files(["golden.txt"])

glob

glob(include, exclude=[], exclude_directories=1, allow_empty=True)

Glob es una función auxiliar que encuentra todos los archivos que coinciden con ciertos patrones de ruta y muestra una lista nueva, mutable y ordenada de sus rutas. Glob solo busca archivos en su propio paquete y solo busca archivos de origen (no archivos generados ni otros destinos).

La etiqueta de un archivo de origen se incluye en el resultado si la ruta de acceso relativa del paquete del archivo coincide con alguno de los patrones include y ninguno de los patrones exclude.

Las listas include y exclude contienen patrones de ruta que se relacionan con el paquete actual. Cada patrón puede constar de uno o más segmentos de ruta. Como de costumbre con las rutas de Unix, estos segmentos están separados por /. Los segmentos pueden contener el comodín *, que coincide con cualquier substring en el segmento de ruta de acceso (incluso la subcadena vacía), sin incluir el separador de directorio /. Este comodín se puede usar varias veces dentro de un segmento de ruta de acceso. Además, el comodín ** puede coincidir con cero o más segmentos de ruta de acceso completos, pero se debe declarar como un segmento de ruta de acceso independiente.

• foo/bar.txt coincide exactamente con el archivo foo/bar.txt de este paquete
• foo/*.txt coincide con todos los archivos del directorio foo/ si el archivo termina con .txt (a menos que foo/ sea un subpaquete).
• foo/a*.htm* coincide con todos los archivos del directorio foo/ que comienzan con a, luego tienen una cadena arbitraria (podría estar vacía), luego tienen .htm y terminan con otra cadena arbitraria, como foo/axx.htm y foo/a.html o foo/axxx.html.
• **/a.txt coincide con todos los archivos a.txt en cada subdirectorio de este paquete.
• **/bar/**/*.txt coincide con cada archivo .txt en cada subdirectorio de este paquete si al menos un directorio en la ruta resultante se llama bar, como xxx/bar/yyy/zzz/a.txt o bar/a.txt (recuerda que ** también coincide con cero segmentos) o bar/zzz/a.txt.
• ** coincide con todos los archivos de cada subdirectorio de este paquete.
• foo**/a.txt es un patrón no válido, ya que ** debe ser independiente como un segmento.

Si el argumento exclude_directories está habilitado (se establece en 1), se omitirán los archivos del directorio de tipo de los resultados (predeterminado: 1).

Si el argumento allow_empty se establece en False, la función glob mostrará un error si, de otro modo, el resultado sería la lista vacía.

Existen varias limitaciones y advertencias importantes:

1. Dado que glob() se ejecuta durante la evaluación del archivo BUILD, glob() solo coincide con los archivos en el árbol de origen, nunca con los archivos generados. Si compilas un destino que requiere archivos fuente y generados, debes agregar una lista explícita de archivos generados al glob. Consulta el ejemplo que aparece a continuación con :mylib y :gen_java_srcs.

2. Si una regla tiene el mismo nombre que un archivo de origen coincidente, la regla “sombra” el archivo.

   Para comprender esto, recuerda que glob() muestra una lista de rutas, por lo que usar glob() en el atributo de otras reglas (p.ej., srcs = glob(["*.cc"])) tiene el mismo efecto que enumerar las rutas coincidentes de forma explícita. Si, por ejemplo, glob() genera ["Foo.java", "bar/Baz.java"], pero también hay una regla en el paquete llamada "Foo.java" (lo que está permitido, aunque Bazel advierte al respecto), el consumidor de glob() usará la regla "Foo.java" (sus resultados) en lugar del archivo "Foo.java". Consulta el problema #10395 de GitHub para obtener más detalles.

3. Los comodines pueden coincidir con archivos en subdirectorios. Además, los nombres de los subdirectorios pueden usar comodines. Sin embargo…

4. No se permite que las etiquetas crucen el límite del paquete, y glob no coincide con los archivos de los subpaquetes.

   Por ejemplo, la expresión glob **/*.cc en el paquete x no incluye x/y/z.cc si x/y existe como un paquete (ya sea como x/y/BUILD o en algún otro lugar de la ruta de acceso del paquete). Esto significa que el resultado de la expresión de glob en realidad depende de la existencia de archivos BUILD, es decir, la misma expresión de glob incluiría x/y/z.cc si no hubiera un paquete llamado x/y o si se marcó como borrado con la marca --deleted_packages.

5. La restricción anterior se aplica a todas las expresiones glob, sin importar qué comodines usen.
6. Un archivo oculto cuyo nombre de archivo comienza con . coincide completamente con los comodines ** y *. Si quieres hacer coincidir un archivo oculto con un patrón compuesto, este debe comenzar con .. Por ejemplo, * y .*.txt coincidirán con .foo.txt, pero *.txt no. Los directorios ocultos también coinciden de la misma manera. Los directorios ocultos pueden incluir archivos que no son necesarios como entradas y pueden aumentar la cantidad de archivos globbed innecesarios y el consumo de memoria. Para excluir directorios ocultos, agrégalos al argumento de la lista "exclude".
7. El comodín “**” tiene un caso extremo: el patrón "**" no coincide con la ruta de acceso del directorio del paquete. Es decir, glob(["**"], exclude_directories = 0) hace coincidir de forma transitiva todos los archivos y directorios del directorio del paquete actual (pero, por supuesto, no ingresa a directorios de subpaquetes; consulta la nota anterior al respecto).

En general, debes intentar proporcionar una extensión adecuada (p.ej., *.html) en lugar de usar un "*" sin formato para un patrón de glob. El nombre más explícito se autodocumenta y garantiza que no coincidas accidentalmente con los archivos de copia de seguridad ni con los archivos de guardado automático de emacs/vi/….

Cuando escribes reglas de compilación, puedes enumerar los elementos del glob. Esto permite generar, por ejemplo, reglas individuales para cada entrada. Consulta la sección Ejemplo de glob expandido que aparece a continuación.

Ejemplos de glob

Crea una biblioteca de Java compilada a partir de todos los archivos Java de este directorio y todos los archivos generados por la regla :gen_java_srcs.

java_library(
    name = "mylib",
    srcs = glob(["*.java"]) + [":gen_java_srcs"],
    deps = "...",
)

genrule(
    name = "gen_java_srcs",
    outs = [
        "Foo.java",
        "Bar.java",
    ],
    ...
)

Incluye todos los archivos txt en el directorio testdata, excepto experimental.txt. Ten en cuenta que no se incluirán los archivos de los subdirectorios de testdata. Si quieres que se incluyan esos archivos, usa un comodín recursivo (**).

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(
        ["testdata/*.txt"],
        exclude = ["testdata/experimental.txt"],
    ),
)

Ejemplos de glob recursiva

Haz que la prueba dependa de todos los archivos txt del directorio testdata y de cualquiera de sus subdirectorios (y sus subdirectorios, etcétera). Se ignoran los subdirectorios que contienen un archivo BUILD. (Consulta las limitaciones y advertencias anteriores).

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(["testdata/**/*.txt"]),
)

Crea una biblioteca compilada a partir de todos los archivos Java de este directorio y todos los subdirectorios, excepto aquellos cuya ruta de acceso incluya un directorio llamado testing. Si es posible, se debe evitar este patrón, ya que puede reducir la incrementalidad de la compilación y, por lo tanto, aumentar los tiempos de compilación.

java_library(
    name = "mylib",
    srcs = glob(
        ["**/*.java"],
        exclude = ["**/testing/**"],
    ),
)

Ejemplos de glob expandido

Crea una genrule individual para *_test.cc en el directorio actual que cuente la cantidad de líneas del archivo.

# Conveniently, the build language supports list comprehensions.
[genrule(
    name = "count_lines_" + f[:-3],  # strip ".cc"
    srcs = [f],
    outs = ["%s-linecount.txt" % f[:-3]],
    cmd = "wc -l $< >$@",
 ) for f in glob(["*_test.cc"])]

Si el archivo de COMPILACIÓN anterior se encuentra en el paquete //foo y este contiene tres archivos coincidentes, a_test.cc, b_test.cc y c_test.cc, cuando se ejecute bazel query '//foo:all', se mostrarán todas las reglas que se generaron:

$ bazel query '//foo:all' | sort
//foo:count_lines_a_test
//foo:count_lines_b_test
//foo:count_lines_c_test

seleccionar

select(
    {conditionA: valuesA, conditionB: valuesB, ...},
    no_match_error = "custom message"
)

select() es la función auxiliar que hace que un atributo de regla sea configurable. Puede reemplazar el lado derecho de casi cualquier asignación de atributos, por lo que su valor depende de las marcas de Bazel de la línea de comandos. Puedes usar esto, por ejemplo, para definir dependencias específicas de la plataforma o para incorporar diferentes recursos según si una regla se compila en el modo "desarrollador" o "versión".

El uso básico es el siguiente:

sh_binary(
    name = "mytarget",
    srcs = select({
        ":conditionA": ["mytarget_a.sh"],
        ":conditionB": ["mytarget_b.sh"],
        "//conditions:default": ["mytarget_default.sh"]
    })
)

Esto hace que el atributo srcs de un sh_binary sea configurable reemplazando su asignación normal de lista de etiquetas por una llamada a select que asigna condiciones de configuración a valores coincidentes. Cada condición es una etiqueta que hace referencia a un config_setting o constraint_value, que "coincide" si la configuración del objetivo coincide con un conjunto esperado de valores. Luego, el valor de mytarget#srcs se convierte en la lista de etiquetas que coincida con la invocación actual.

Notas:

• Se selecciona exactamente una condición en cualquier invocación.
• Si coinciden varias condiciones y una es una especialización de las demás, la especialización tiene prioridad. La condición B se considera una especialización de la condición A si B tiene las mismas marcas y valores de restricción que A, además de algunas marcas o valores de restricción adicionales. Esto también significa que la resolución de especialización no está diseñada para crear un orden, como se muestra en el ejemplo 2 a continuación.
• Si coinciden varias condiciones y una no es una especialización de todas las demás, Bazel falla con un error, a menos que todas las condiciones se resuelvan en el mismo valor.
• Se considera que la seudoetiqueta especial //conditions:default coincide si no coincide ninguna otra condición. Si se omite esta condición, se debe hacer coincidir alguna otra regla para evitar un error.
• select se puede incorporar dentro de una asignación de atributos más grande. Por lo tanto, srcs = ["common.sh"] + select({ ":conditionA": ["myrule_a.sh"], ...}) y srcs = select({ ":conditionA": ["a.sh"]}) + select({ ":conditionB": ["b.sh"]}) son expresiones válidas.
• select funciona con la mayoría de los atributos, pero no con todos. Los atributos incompatibles se marcan como nonconfigurable en su documentación.

  subpaquetes

  subpackages(include, exclude=[], allow_empty=True)

  subpackages() es una función auxiliar, similar a glob(), que enumera subpaquetes en lugar de archivos y directorios. Usa los mismos patrones de ruta de acceso que glob() y puede coincidir con cualquier subpaquete que sea descendiente directo del archivo BUILD que se está cargando actualmente. Consulta glob para obtener una explicación detallada y ejemplos de patrones de inclusión y exclusión.

  La lista resultante de subpaquetes que se muestra está ordenada y contiene rutas de acceso relacionadas con el paquete de carga actual que coinciden con los patrones determinados en include y no con los de exclude.

  Ejemplo

  En el siguiente ejemplo, se enumeran todos los subpaquetes directos del paquete foo/BUILD.

  # The following BUILD files exist:
  # foo/BUILD
  # foo/bar/baz/BUILD
  # foo/sub/BUILD
  # foo/sub/deeper/BUILD
  #
  # In foo/BUILD a call to
  subs = subpackages(include = ["**"])
  
  # results in subs == ["sub", "bar/baz"]
  #
  # 'sub/deeper' is not included because it is a subpackage of 'foo/sub' not of
  # 'foo'
  

  En general, se prefiere que, en lugar de llamar a esta función directamente, los usuarios usen el módulo “subpackages” de skylib.