การสร้างมาโคร

รายงานปัญหา ดูแหล่งที่มา /3} /4} {3/4} {3/4} {3/4} {3/4} /4.

สมมติว่าคุณต้องเรียกใช้เครื่องมือในการสร้าง เช่น คุณอาจต้องการสร้างหรือประมวลผลไฟล์ต้นฉบับล่วงหน้า หรือบีบอัดไบนารี ในบทแนะนำนี้ คุณจะสร้างมาโครที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทำอะไรที่มีความซับซ้อนมากขึ้น เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้พิจารณาสร้างกฎ กฎจะช่วยให้คุณควบคุมและมีความยืดหยุ่นได้มากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้ genrule

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องนำโค้ดมาใช้ซ้ำ ซึ่งทำได้โดยกำหนดฟังก์ชันในไฟล์ .bzl แยกต่างหาก และเรียกใช้ไฟล์ miniature.bzl ดังนี้

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

ข้อควรทราบบางประการมีดังนี้

  • ตามปกติแล้ว มาโครมีอาร์กิวเมนต์ name เหมือนกับกฎ

  • หากต้องการบันทึกลักษณะการทำงานของมาโคร ให้ใช้ docstring อย่างเช่นใน Python

  • หากต้องการเรียกใช้ genrule หรือกฎเนทีฟอื่นๆ ให้ใช้ native.

  • ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule ที่สำคัญ (ทำงานเหมือนกับใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้ใช้แอตทริบิวต์มาตรฐาน เช่น visibility หรือ tags ได้

ตอนนี้ ให้ใช้มาโครจากไฟล์ BUILD ดังนี้

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)