Bazel을 사용한 Android 네이티브 개발 키트 사용

컬렉션을 사용해 정리하기 내 환경설정을 기준으로 콘텐츠를 저장하고 분류하세요.
문제 신고 출처 보기

Bazel을 처음 사용하는 경우 Bazel을 사용하여 Android 빌드 튜토리얼부터 시작하세요.

개요

Bazel은 Android Native Development Kit (NDK) 도구 모음을 사용하는 빌드 빌드를 포함하여 여러 다양한 빌드 구성에서 실행할 수 있습니다. 즉, 일반적인 cc_librarycc_binary 규칙을 Bazel 내에서 직접 Android용으로 컴파일할 수 있습니다. Bazel은 android_ndk_repository 저장소 규칙을 사용하여 이를 수행합니다.

기본 요건

Android SDK와 NDK를 설치했는지 확인합니다.

SDK 및 NDK를 설정하려면 WORKSPACE에 다음 스니펫을 추가하세요.

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

android_ndk_repository 규칙에 관한 자세한 내용은 백과사전 빌드 항목을 참고하세요.

빠른 시작

Android용 C++를 빌드하려면 android_binary 또는 android_library 규칙에 cc_library 종속 항목을 추가하기만 하면 됩니다.

예를 들어 Android 앱의 다음 BUILD 파일은 다음과 같습니다.

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

BUILD 파일은 다음과 같은 타겟 그래프를 생성합니다.

결과 예시

그림 1. cc_library 종속 항목이 있는 Android 프로젝트의 그래프를 빌드합니다.

앱을 빌드하려면 다음을 실행합니다.

bazel build //app/src/main:app

bazel build 명령어는 자바 파일, Android 리소스 파일, cc_library 규칙을 컴파일하고 모든 항목을 APK로 패키징합니다.

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel은 모든 cc_library를 기본적으로 armeabi-v7a ABI를 타겟팅하는 단일 공유 객체 (.so) 파일로 컴파일합니다. 이를 변경하거나 여러 ABI에 관해 동시에 빌드하려면 대상 ABI 구성 섹션을 참조하세요.

설정 예시

이 예시는 Bazel 예시 저장소에 있습니다.

BUILD.bazel 파일에서 세 가지 대상은 android_binary, android_library, cc_library 규칙으로 정의됩니다.

android_binary 최상위 타겟은 APK를 빌드합니다.

cc_library 타겟에는 JNI 함수 구현이 있는 단일 C++ 소스 파일이 포함되어 있습니다.

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 대상은 자바 소스, 리소스 파일, cc_library 대상에 대한 종속 항목을 지정합니다. 이 예에서 MainActivity.java는 공유 객체 파일 libapp.so를 로드하고 JNI 함수의 메서드 서명을 정의합니다.

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

STL 구성

C++ STL을 구성하려면 --android_crosstool_top 플래그를 사용합니다.

bazel build //:app --android_crosstool_top=target label

@androidndk에서 사용 가능한 STL은 다음과 같습니다.

대상 라벨
STLport @androidndk//:toolchain-stlport
libc++ @androidndk//:toolchain-libcpp
gnustl @androidndk//:toolchain-gnu-libstdcpp

r16 이하의 경우 기본 STL은 gnustl입니다. r17 이상에서는 libc++입니다. 편의를 위해 대상 @androidndk//:default_crosstool는 각 기본 STL로 별칭이 지정됩니다.

r18부터는 STLport 및 gnustl이 삭제되어 libc++이 NDK의 유일한 STL이 됩니다.

STL에 관한 자세한 내용은 NDK 문서를 참고하세요.

대상 ABI 구성

타겟 ABI를 구성하려면 다음과 같이 --fat_apk_cpu 플래그를 사용합니다.

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

기본적으로 Bazel은 armeabi-v7a에 대해 네이티브 Android 코드를 빌드합니다. x86용(예: 에뮬레이터용) 빌드하려면 --fat_apk_cpu=x86을 전달합니다. 여러 아키텍처의 PP APK를 만들려면 여러 CPU를 지정하면 됩니다. --fat_apk_cpu=armeabi-v7a,x86

ABI가 두 개 이상 지정된 경우 Bazel은 각 ABI의 공유 객체가 포함된 APK를 빌드합니다.

NDK 버전 및 Android API 수준에 따라 다음 ABI를 사용할 수 있습니다.

NDK 버전 ABI
16 이하 armeabi, armeabi-v7a, arm64-v8a, mips, mips64, x86, x86_64
만 17세 이상 armeabi-v7a, arm64-v8a, x86, x86_64

이러한 ABI에 관한 자세한 내용은 NDK 문서를 참고하세요.

출시 버전 빌드에는 APK 크기가 늘어나므로 다중 ABI 지방 APK는 권장되지 않지만 개발 및 QA 빌드에 유용할 수 있습니다.

C++ 표준 선택

C++ 표준에 따라 빌드하려면 다음 플래그를 사용합니다.

C++ 표준 플래그
C++98 기본값, 플래그 필요 없음
C++11 --cxxopt=-std=c++11
C++14 --cxxopt=-std=c++14

예를 들면 다음과 같습니다.

bazel build //:app --cxxopt=-std=c++11

사용자 설명서에서 컴파일러 및 링커 플래그에 --cxxopt, --copt, --linkopt을 전달하는 방법을 자세히 알아보세요.

컴파일러 및 링커 플래그는 coptslinkopts를 사용하여 cc_library의 속성으로 지정할 수도 있습니다. 예를 들면 다음과 같습니다.

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

플랫폼 및 도구 모음과 통합

Bazel의 구성 모델이 플랫폼도구 모음으로 이동하고 있습니다. 빌드할 아키텍처 또는 운영체제를 선택하기 위해 빌드에서 --platforms 플래그를 사용하는 경우 NDK를 사용하려면 --extra_toolchains 플래그를 Bazel에 전달해야 합니다.

예를 들어 Go 규칙에서 제공하는 android_arm64_cgo 도구 모음과 통합하려면 --platforms 플래그와 함께 --extra_toolchains=@androidndk//:all를 전달합니다.

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

WORKSPACE 파일에 직접 등록할 수도 있습니다.

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

이러한 도구 모음을 등록하면 아키텍처 및 운영체제 제약 조건을 해결할 때 Bazel이 NDK BUILD 파일 (NDK 20의 경우)에서 이 도구 모음을 검색하도록 합니다.

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

작동 방식: Android 구성 전환 소개

android_binary 규칙은 Bazel 빌드가 특별한 플래그 없이 단순하게 작동하도록 ABI와 STL 구성의 --fat_apk_cpu--android_crosstool_top를 제외하고 Android 호환 구성에서 종속 항목을 빌드하도록 명시적으로 요청할 수 있습니다.

내부적으로 이 자동 구성은 Android 구성 전환을 사용합니다.

android_binary와 같은 호환 규칙은 종속 항목 구성을 Android 구성으로 자동 변경하므로 빌드의 Android 관련 하위 트리만 영향을 받습니다. 빌드 그래프의 다른 부분은 최상위 대상 구성을 사용하여 처리됩니다. 빌드 그래프를 통해 이를 지원하는 경로가 있는 경우 두 구성 모두에서 단일 대상을 처리할 수도 있습니다.

최상위 수준에 지정되거나 더 높은 수준의 전환 포인트로 인해 Bazel이 Android 호환 구성에 포함되면 추가 전환 지점이 구성을 더 이상 수정하지 않습니다.

Android 구성으로의 전환을 트리거하는 유일한 내장 위치는 android_binarydeps 속성입니다.

예를 들어 플래그 없이 cc_library 종속 항목을 사용하여 android_library 대상을 빌드하려고 하면 JNI 헤더 누락에 대한 오류가 발생할 수 있습니다.

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

이러한 자동 전환을 통해 Bazel이 대부분의 경우에 올바른 작업을 수행하는 것이 이상적입니다. 그러나 Bazel 명령줄의 대상이 이미 이러한 전환 규칙보다 낮으면(예: 특정 cc_library을 테스트하는 C++ 개발자) 커스텀 --crosstool_top을 사용해야 합니다.

android_binary를 사용하지 않고 Android용 cc_library 빌드

android_binary을 사용하지 않고 Android용 독립형 cc_binary 또는 cc_library를 빌드하려면 --crosstool_top, --cpu, --host_crosstool_top 플래그를 사용합니다.

예를 들면 다음과 같습니다.

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

이 예시에서는 최상위 cc_librarycc_binary 대상이 NDK 도구 모음을 사용하여 빌드됩니다. 하지만 이 경우 Bazel의 자체 호스트 도구가 NDK 도구 모음 (및 Android의 경우)에 따라 빌드됩니다. 호스트 도구 모음이 대상 도구 모음에서 복사되기 때문입니다. 이 문제를 해결하려면 --host_crosstool_top 값을 @bazel_tools//tools/cpp:toolchain로 지정하여 호스트의 C++ 도구 모음을 명시적으로 설정하세요.

이 방법을 사용하면 전체 빌드 트리가 영향을 받습니다.

이러한 플래그는 project/.bazelrcbazelrc 구성 (각 ABI에 하나씩)에 포함할 수 있습니다.

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

예를 들어, x86cc_library를 빌드하려면 다음을 실행합니다.

bazel build //my/cc/jni:target --config=android_x86

일반적으로 하위 수준 타겟 (예: cc_library)이나 빌드 중인 대상을 정확히 알고 있는 경우 이 방법을 사용합니다. 제어하지 않는 다량의 타겟을 빌드해야 하는 상위 수준 타겟의 경우 android_binary의 자동 구성 전환을 사용합니다.