डेपट्स

Depsets, एक खास तरह का डेटा स्ट्रक्चर होता है. इसका इस्तेमाल, किसी टारगेट की ट्रांज़िटिव डिपेंडेंसी से डेटा इकट्ठा करने के लिए किया जाता है. ये नियम प्रोसेस करने का एक ज़रूरी हिस्सा हैं.

डिपसेट की खास बात यह है कि इसमें यूनियन ऑपरेशन, समय और जगह के हिसाब से बेहतर तरीके से काम करता है. depset कंस्ट्रक्टर, एलिमेंट ("direct") की सूची और अन्य depset ("transitive") की सूची स्वीकार करता है. साथ ही, एक ऐसा depset दिखाता है जिसमें सभी डायरेक्ट एलिमेंट और सभी ट्रांज़िटिव सेट का यूनीयन होता है. कॉन्सेप्ट के तौर पर, कंस्ट्रक्टर एक नया ग्राफ़ नोड बनाता है. इसमें डायरेक्ट और ट्रांज़िटिव नोड, इसके सक्सेसर के तौर पर होते हैं. डिपसेट में, क्रम से लगाने के लिए सिमैंटिक तय किए जाते हैं. ये सिमैंटिक, इस ग्राफ़ के ट्रैवर्सल पर आधारित होते हैं.

डिपसेट के इस्तेमाल के उदाहरण:

• यह प्रोग्राम की लाइब्रेरी के लिए, सभी ऑब्जेक्ट फ़ाइलों के पाथ सेव करता है. इसके बाद, इन्हें प्रोवाइडर के ज़रिए लिंकर ऐक्शन को पास किया जा सकता है.

• इंटरप्रेट की गई भाषा के लिए, ट्रांज़िटिव सोर्स फ़ाइलों को सेव करना. ये फ़ाइलें, एक्ज़ीक्यूटेबल की रनफ़ाइल में शामिल होती हैं.

ब्यौरा और कार्रवाइयां

सैद्धांतिक तौर पर, डेपसेट एक डायरेक्टेड एसाइक्लिक ग्राफ़ (डीएजी) होता है. यह आम तौर पर टारगेट ग्राफ़ जैसा दिखता है. इसे पत्तियों से लेकर जड़ों तक बनाया जाता है. डिपेंडेंसी चेन में मौजूद हर टारगेट, पिछले टारगेट के कॉन्टेंट में अपना कॉन्टेंट जोड़ सकता है. इसके लिए, उसे पिछले टारगेट के कॉन्टेंट को पढ़ने या कॉपी करने की ज़रूरत नहीं होती.

DAG में मौजूद हर नोड में, डायरेक्ट एलिमेंट की सूची और चाइल्ड नोड की सूची होती है. depset के कॉन्टेंट, ट्रांज़िटिव एलिमेंट होते हैं. जैसे, सभी नोड के डायरेक्ट एलिमेंट. depset कंस्ट्रक्टर का इस्तेमाल करके, एक नया depset बनाया जा सकता है: यह डायरेक्ट एलिमेंट की सूची और चाइल्ड नोड की दूसरी सूची स्वीकार करता है.

s = depset(["a", "b", "c"])
t = depset(["d", "e"], transitive = [s])

print(s)    # depset(["a", "b", "c"])
print(t)    # depset(["d", "e", "a", "b", "c"])

किसी डिप्सेट का कॉन्टेंट वापस पाने के लिए, to_list() तरीके का इस्तेमाल करें. यह डुप्लीकेट के बिना, सभी ट्रांज़िटिव एलिमेंट की सूची दिखाता है. डीएजी के सटीक स्ट्रक्चर की सीधे तौर पर जांच करने का कोई तरीका नहीं है. हालांकि, इस स्ट्रक्चर से उस क्रम पर असर पड़ता है जिसमें एलिमेंट दिखाए जाते हैं.

s = depset(["a", "b", "c"])

print("c" in s.to_list())              # True
print(s.to_list() == ["a", "b", "c"])  # True

डिपसेट में सिर्फ़ कुछ आइटम इस्तेमाल किए जा सकते हैं. इसी तरह, डिक्शनरी में सिर्फ़ कुछ कुंजियां इस्तेमाल की जा सकती हैं. खास तौर पर, depset के कॉन्टेंट में बदलाव नहीं किया जा सकता.

डेपसेट, रेफ़रंस समानता का इस्तेमाल करते हैं: एक डेपसेट, खुद के बराबर होता है. हालांकि, यह किसी अन्य डेपसेट के बराबर नहीं होता, भले ही उनमें एक जैसा कॉन्टेंट और एक जैसा इंटरनल स्ट्रक्चर हो.

s = depset(["a", "b", "c"])
t = s
print(s == t)  # True

t = depset(["a", "b", "c"])
print(s == t)  # False

d = {}
d[s] = None
d[t] = None
print(len(d))  # 2

डिपसेट की तुलना उनके कॉन्टेंट के हिसाब से करने के लिए, उन्हें क्रम से लगाई गई सूचियों में बदलें.

s = depset(["a", "b", "c"])
t = depset(["c", "b", "a"])
print(sorted(s.to_list()) == sorted(t.to_list()))  # True

डेटासेट से एलिमेंट हटाने की सुविधा उपलब्ध नहीं है. अगर ऐसा करना ज़रूरी है, तो आपको डेटासेट का पूरा कॉन्टेंट पढ़ना होगा. इसके बाद, उन एलिमेंट को फ़िल्टर करना होगा जिन्हें आपको हटाना है. इसके बाद, एक नया डेटासेट बनाना होगा. यह तरीका ज़्यादा असरदार नहीं है.

s = depset(["a", "b", "c"])
t = depset(["b", "c"])

# Compute set difference s - t. Precompute t.to_list() so it's not done
# in a loop, and convert it to a dictionary for fast membership tests.
t_items = {e: None for e in t.to_list()}
diff_items = [x for x in s.to_list() if x not in t_items]
# Convert back to depset if it's still going to be used for union operations.
s = depset(diff_items)
print(s)  # depset(["a"])

क्रम

to_list ऑपरेशन, डीएजी पर ट्रैवर्सल करता है. ट्रावर्सल का तरीका, depset बनाते समय तय किए गए order पर निर्भर करता है. Bazel के लिए, एक से ज़्यादा ऑर्डर को सपोर्ट करना फ़ायदेमंद होता है. ऐसा इसलिए, क्योंकि कभी-कभी टूल अपने इनपुट के क्रम का ध्यान रखते हैं. उदाहरण के लिए, लिंक करने की कार्रवाई के लिए यह पक्का करना ज़रूरी हो सकता है कि अगर B, A पर निर्भर करता है, तो लिंक करने वाले की कमांड लाइन पर A.o, B.o से पहले आता है. अन्य टूल के लिए, इससे अलग शर्त हो सकती है.

तीन ट्रैवर्सल ऑर्डर इस्तेमाल किए जा सकते हैं: postorder, preorder, और topological. पहले दो तरीके, ट्री ट्रैवर्सल की तरह ही काम करते हैं. हालांकि, ये डीएजी पर काम करते हैं और पहले से देखे गए नोड को छोड़ देते हैं. तीसरा क्रम, रूट से लेकर लीफ़ तक टोपोलॉजिकल सॉर्ट के तौर पर काम करता है. यह प्रीऑर्डर जैसा ही होता है. हालांकि, इसमें शेयर किए गए बच्चों को उनके सभी पैरंट के बाद ही सूची में शामिल किया जाता है. प्रीऑर्डर और पोस्टऑर्डर, बाएं से दाएं ट्रैवर्सल के तौर पर काम करते हैं. हालांकि, ध्यान दें कि हर नोड में डायरेक्ट एलिमेंट का क्रम, चाइल्ड के हिसाब से नहीं होता है. टपॉलॉजिकल क्रम के लिए, बाएं से दाएं क्रम की गारंटी नहीं होती है. साथ ही, अगर डीएजी के अलग-अलग नोड में डुप्लीकेट एलिमेंट मौजूद हैं, तो पैरंट नोड को चाइल्ड नोड से पहले प्रोसेस करने की गारंटी भी लागू नहीं होती है.

# This demonstrates different traversal orders.

def create(order):
  cd = depset(["c", "d"], order = order)
  gh = depset(["g", "h"], order = order)
  return depset(["a", "b", "e", "f"], transitive = [cd, gh], order = order)

print(create("postorder").to_list())  # ["c", "d", "g", "h", "a", "b", "e", "f"]
print(create("preorder").to_list())   # ["a", "b", "e", "f", "c", "d", "g", "h"]

# This demonstrates different orders on a diamond graph.

def create(order):
  a = depset(["a"], order=order)
  b = depset(["b"], transitive = [a], order = order)
  c = depset(["c"], transitive = [a], order = order)
  d = depset(["d"], transitive = [b, c], order = order)
  return d

print(create("postorder").to_list())    # ["a", "b", "c", "d"]
print(create("preorder").to_list())     # ["d", "b", "a", "c"]
print(create("topological").to_list())  # ["d", "b", "c", "a"]

ट्रेवर्सल को लागू करने के तरीके की वजह से, कंस्ट्रक्टर के order कीवर्ड आर्ग्युमेंट का इस्तेमाल करके depset बनाते समय, क्रम तय किया जाना चाहिए. अगर इस आर्ग्युमेंट को शामिल नहीं किया जाता है, तो डीसेट में खास default क्रम होता है. ऐसे में, इसके किसी भी एलिमेंट के क्रम की कोई गारंटी नहीं होती. हालांकि, यह क्रम तय होता है.

पूरा उदाहरण

यह उदाहरण, https://github.com/bazelbuild/examples/tree/main/rules/depsets पर उपलब्ध है.

मान लें कि इंटरप्रेट की गई कोई काल्पनिक भाषा फ़ू है. हर foo_binary को बनाने के लिए, आपको उन सभी *.foo फ़ाइलों के बारे में पता होना चाहिए जिन पर वह सीधे या परोक्ष रूप से निर्भर करता है.

# //depsets:BUILD

load(":foo.bzl", "foo_library", "foo_binary")

# Our hypothetical Foo compiler.
py_binary(
    name = "foocc",
    srcs = ["foocc.py"],
)

foo_library(
    name = "a",
    srcs = ["a.foo", "a_impl.foo"],
)

foo_library(
    name = "b",
    srcs = ["b.foo", "b_impl.foo"],
    deps = [":a"],
)

foo_library(
    name = "c",
    srcs = ["c.foo", "c_impl.foo"],
    deps = [":a"],
)

foo_binary(
    name = "d",
    srcs = ["d.foo"],
    deps = [":b", ":c"],
)

# //depsets:foocc.py

# "Foo compiler" that just concatenates its inputs to form its output.
import sys

if __name__ == "__main__":
  assert len(sys.argv) >= 1
  output = open(sys.argv[1], "wt")
  for path in sys.argv[2:]:
    input = open(path, "rt")
    output.write(input.read())

यहां, बाइनरी d के ट्रांज़िटिव सोर्स, a, b, c, और d के srcs फ़ील्ड में मौजूद सभी *.foo फ़ाइलें हैं. d.foo के अलावा किसी अन्य फ़ाइल के बारे में foo_binary टारगेट को जानकारी देने के लिए, foo_library टारगेट को उन्हें किसी प्रोवाइडर में पास करना होगा. हर लाइब्रेरी को अपनी डिपेंडेंसी से प्रोवाइडर मिलते हैं. साथ ही, वह अपने सोर्स जोड़ती है और बढ़े हुए कॉन्टेंट के साथ एक नया प्रोवाइडर पास करती है. foo_binary नियम भी यही काम करता है. हालांकि, इसमें प्रोवाइडर को वापस भेजने के बजाय, कार्रवाई के लिए कमांड लाइन बनाने के लिए सोर्स की पूरी सूची का इस्तेमाल किया जाता है.

यहां foo_library और foo_binary नियमों को लागू करने का पूरा उदाहरण दिया गया है.

# //depsets/foo.bzl

# A provider with one field, transitive_sources.
foo_files = provider(fields = ["transitive_sources"])

def get_transitive_srcs(srcs, deps):
  """Obtain the source files for a target and its transitive dependencies.

  Args:
    srcs: a list of source files
    deps: a list of targets that are direct dependencies
  Returns:
    a collection of the transitive sources
  """
  return depset(
        srcs,
        transitive = [dep[foo_files].transitive_sources for dep in deps])

def _foo_library_impl(ctx):
  trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
  return [foo_files(transitive_sources=trans_srcs)]

foo_library = rule(
    implementation = _foo_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files=True),
        "deps": attr.label_list(),
    },
)

def _foo_binary_impl(ctx):
  foocc = ctx.executable._foocc
  out = ctx.outputs.out
  trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
  srcs_list = trans_srcs.to_list()
  ctx.actions.run(executable = foocc,
                  arguments = [out.path] + [src.path for src in srcs_list],
                  inputs = srcs_list + [foocc],
                  outputs = [out])

foo_binary = rule(
    implementation = _foo_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files=True),
        "deps": attr.label_list(),
        "_foocc": attr.label(default=Label("//depsets:foocc"),
                             allow_files=True, executable=True, cfg="host")
    },
    outputs = {"out": "%{name}.out"},
)

इसे आज़माने के लिए, इन फ़ाइलों को नए पैकेज में कॉपी करें. इसके बाद, लेबल का नाम बदलें. साथ ही, डमी कॉन्टेंट के साथ सोर्स *.foo फ़ाइलें बनाएं और d टारगेट बनाएं.

परफ़ॉर्मेंस

डिपसेट का इस्तेमाल करने की वजह जानने के लिए, सोचें कि अगर get_transitive_srcs() अपने सोर्स को सूची में इकट्ठा करता है, तो क्या होगा.

def get_transitive_srcs(srcs, deps):
  trans_srcs = []
  for dep in deps:
    trans_srcs += dep[foo_files].transitive_sources
  trans_srcs += srcs
  return trans_srcs

इसमें डुप्लीकेट फ़ाइलों को शामिल नहीं किया जाता. इसलिए, a के लिए सोर्स फ़ाइलें, कमांड लाइन पर दो बार और आउटपुट फ़ाइल के कॉन्टेंट में दो बार दिखेंगी.

इसके अलावा, सामान्य सेट का इस्तेमाल किया जा सकता है. इसे डिक्शनरी की मदद से सिम्युलेट किया जा सकता है. इसमें कुंजियां, एलिमेंट होती हैं और सभी कुंजियां True पर मैप होती हैं.

def get_transitive_srcs(srcs, deps):
  trans_srcs = {}
  for dep in deps:
    for file in dep[foo_files].transitive_sources:
      trans_srcs[file] = True
  for file in srcs:
    trans_srcs[file] = True
  return trans_srcs

इससे डुप्लीकेट फ़ाइलें हट जाती हैं. हालांकि, इससे कमांड लाइन के आर्ग्युमेंट (और इसलिए फ़ाइलों का कॉन्टेंट) का क्रम तय नहीं होता. हालांकि, यह अब भी तय होता है.

इसके अलावा, दोनों तरीके, डिपसेट पर आधारित तरीके से काफ़ी खराब हैं. मान लें कि Foo लाइब्रेरी पर निर्भरता की एक लंबी चेन है. हर नियम को प्रोसेस करने के लिए, उससे पहले के सभी ट्रांज़िटिव सोर्स को नए डेटा स्ट्रक्चर में कॉपी करना ज़रूरी होता है. इसका मतलब है कि किसी लाइब्रेरी या बाइनरी टारगेट का विश्लेषण करने के लिए, समय और जगह की लागत, चेन में उसकी ऊंचाई के हिसाब से होती है. n लंबाई वाली चेन foolib_1 ← foolib_2 ← … ← foolib_n के लिए, कुल लागत O(n^2) होती है.

आम तौर पर, जब भी आपको ट्रांज़िटिव डिपेंडेंसी के ज़रिए जानकारी इकट्ठा करनी हो, तब डिपसेट का इस्तेमाल करना चाहिए. इससे यह पक्का करने में मदद मिलती है कि आपका बिल्ड, टारगेट ग्राफ़ के बढ़ने के साथ-साथ अच्छी तरह से स्केल हो.

आखिर में, यह ज़रूरी है कि नियम लागू करते समय, depset के कॉन्टेंट को बिना किसी वजह के न निकाला जाए. बाइनरी नियम में आखिर में to_list() को एक बार कॉल करने से कोई फ़र्क़ नहीं पड़ता, क्योंकि कुल लागत सिर्फ़ O(n) होती है. ऐसा तब होता है, जब कई नॉन-टर्मिनल टारगेट, to_list() को कॉल करने की कोशिश करते हैं.

Depsets का असरदार तरीके से इस्तेमाल करने के बारे में ज़्यादा जानने के लिए, परफ़ॉर्मेंस पेज देखें.

एपीआई का संदर्भ

ज़्यादा जानकारी के लिए, कृपया यहां देखें.