従来のマクロ

問題を報告するソースを表示 ナイトリー · 8.0 · 7.4 · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

従来のマクロは、ターゲットを作成できる BUILD ファイルから呼び出される非構造化関数です。読み込みフェーズの終了までに、レガシーマクロは存在しなくなり、Bazel にはインスタンス化されたルールの具体的なセットのみが表示されます。

以前のマクロを使用しないこと（代わりにシンボリックマクロを使用する）

可能な限り、シンボリックマクロを使用する必要があります。

シンボリックマクロ

遠隔操作を防止する
詳細な可視性により実装の詳細を非表示にできるようにする
入力された属性を取得します。つまり、自動ラベル付けと選択変換が行われます。
読みやすくなること
まもなく遅延評価が利用可能

用途

マクロの一般的なユースケースは、ルールを再利用する場合です。

たとえば、BUILD ファイルの genrule は、コマンドにハードコードされた some_arg 引数を使用して //:generator を使用してファイルを生成します。

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

異なる引数を使用してファイルをさらに生成する場合は、このコードをマクロ関数に抽出することをおすすめします。name パラメータと arg パラメータを持つ file_generator というマクロを作成するには、genrule を次のように置き換えます。

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

ここでは、//path パッケージにある .bzl ファイルから file_generator シンボルを読み込みます。マクロ関数の定義を別の .bzl ファイルに配置することで、BUILD ファイルをクリーンで宣言的に保つことができます。.bzl ファイルは、ワークスペース内の任意のパッケージから読み込むことができます。

最後に、path/generator.bzl で、元の genrule 定義をカプセル化してパラメータ化するマクロの定義を記述します。

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

マクロを使用してルールを連結することもできます。この例は、連鎖された genrule を示しています。ここで、genrule は前の genrule の出力を入力として使用します。

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

この例では、2 番目の genrule にのみ公開設定値を割り当てています。これにより、マクロ作成者は、ワークスペース内の他のターゲットが中間ルールの出力に依存しないようにすることができます。

マクロの展開

マクロの動作を確認するには、--output=build を指定して query コマンドを使用して展開形式を表示します。

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

ネイティブルールのインスタンス化

ネイティブルール（load() ステートメントを必要としないルール）は、ネイティブモジュールからインスタンス化できます。

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

パッケージ名（マクロを呼び出す BUILD ファイルなど）を確認する必要がある場合は、native.package_name() 関数を使用します。native は .bzl ファイルでのみ使用でき、BUILD ファイルでは使用できません。

マクロでのラベルの解決

従来のマクロは読み込みフェーズで評価されるため、従来のマクロで発生する "//foo:bar" などのラベル文字列は、マクロが定義されている .bzl ファイルではなく、マクロが使用されている BUILD ファイルに対して相対的に解釈されます。公開された Starlark ルールセットの一部であるなど、他のリポジトリで使用することを目的としたマクロでは、通常、この動作は望ましくありません。

Starlark ルールと同じ動作を実現するには、ラベル文字列を Label コンストラクタでラップします。

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main repo, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

デバッグ

bazel query --output=build //my/path:all には、評価後の BUILD ファイルの状態が表示されます。以前のマクロ、グロブ、ループはすべて展開されます。既知の制限事項: select 式は出力に表示されません。
generator_function（ルールを生成する関数）または generator_name（マクロの名前属性）に基づいて出力をフィルタできます。 bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'
BUILD ファイルでルール foo が生成される正確な場所を確認するには、次の方法を試します。BUILD ファイルの上部付近に、次の行を挿入します。cc_library(name = "foo")Bazel を実行します。ルール foo が作成されると（名前の競合が原因で）、例外が発生し、完全なスタックトレースが表示されます。
デバッグには print を使用することもできます。読み込みフェーズ中に、メッセージが DEBUG ログ行として表示されます。まれなケースを除き、コードをデポに送信する前に、print 呼び出しを削除するか、debugging パラメータ（デフォルトは False）で条件付きにします。

エラー

エラーをスローする場合は、fail 関数を使用します。問題の内容と BUILD ファイルを修正する方法について、お客様に明確に説明します。エラーをキャッチすることはできません。

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

規則

ルールをインスタンス化するすべての公開関数（アンダースコアで始まらない関数）には、name 引数が必要です。この引数は省略不可にする必要があります（デフォルト値は指定しないでください）。
公開関数では、Python の規則に従って docstring を使用する必要があります。
BUILD ファイルでは、マクロの name 引数はキーワード引数（位置引数ではない）にする必要があります。
マクロによって生成されたルールの name 属性には、名前引数を接頭辞として含める必要があります。たとえば、macro(name = "foo") は cc_library foo と genrule foo_gen を生成できます。
ほとんどの場合、オプションパラメータのデフォルト値は None にする必要があります。None はネイティブルールに直接渡すことができます。この場合、引数を渡さなかった場合と同じように処理されます。そのため、この目的で 0、False、[] に置き換える必要はありません。代わりに、デフォルトが複雑であるか、時間の経過とともに変更される可能性があるため、マクロは作成したルールに委ねる必要があります。また、デフォルト値に明示的に設定されたパラメータは、クエリ言語またはビルドシステムの内部からアクセスしたときに、設定されていないパラメータ（または None に設定されたパラメータ）とは異なるように見えます。
マクロには、省略可能な visibility 引数が必要です。