BazelCon 2024 登録の受け付けを開始しました。

このページは Cloud Translation API によって翻訳されました。

パフォーマンスの最適化

問題を報告するソースを表示 ナイトリー · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

ルールを記述する際、パフォーマンスに関する最も一般的な落とし穴は、依存関係から蓄積されたデータを走査またはコピーすることです。ビルド全体で集計すると、これらのオペレーションは簡単に O(N^2) の時間またはスペースを消費する可能性があります。これを回避するには、depset を効果的に使用する方法を理解することが重要です。

この処理は簡単ではありません。そのため、Bazel には、誤りの可能性がある箇所を見つけるのに役立つ Memory Profiler も用意されています。注意: 非効率的なルールを記述した場合、そのコストは広く使用されるまで明らかにならない場合があります。

depset を使用する

ルールの依存関係から情報をロールアップするときは、depsets を使用する必要があります。現在のルールに対してローカルで情報を公開する場合は、書式なしリストまたは辞書のみを使用してください。

depset は、共有を可能にするネストされたグラフとして情報を表します。

次のグラフについて考えてみましょう。

C -> B -> A
D ---^

各ノードは 1 つの文字列を公開します。depset を使用すると、データは次のようになります。

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

各項目は 1 回のみ言及されます。リストを使用すると、次のように表示されます。

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

この場合、'a' は 4 回参照されています。グラフが大きいほど、この問題は悪化します。

以下に、depset を正しく使用して伝播情報を公開するルールの実装例を示します。リストを使用してルールローカル情報を公開しても問題ありません。これは O(N^2) ではないためです。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

詳細については、depset の概要のページをご覧ください。

`depset.to_list()` を呼び出さない

to_list() を使用してデプセットをフラットリストに強制変換できますが、その場合、通常は O(N^2) コストが発生します。可能であれば、デバッグ目的以外で depset をフラット化しない。

よくある誤解として、<xx>_binary ルールなどのトップレベルターゲットでのみ Depset をフラット化すれば、ビルドグラフの各レベルで費用が累積されないため、Depset を自由にフラット化できるというものがあります。しかし、依存関係が重複しているターゲットセットをビルドする場合は、O(N^2) のままです。これは、テスト //foo/tests/... のビルド時や IDE プロジェクトのインポート時に発生します。

`depset` への通話の数を減らす

ループ内で depset を呼び出すのは間違いです。これにより、ネストの深い depset が作成され、パフォーマンスが低下する可能性があります。例:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

このコードは簡単に置き換えることができます。まず、伝播 depset を収集し、すべて一度に統合します。

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

これは、リストの理解を使用することで軽減できる場合があります。

x = depset(transitive = [i.deps for i in inputs])

コマンドラインで ctx.actions.args() を使用する

コマンドラインをビルドする場合は、ctx.actions.args() を使用する必要があります。これにより、depset の展開が実行フェーズに延期されます。

これにより、速度が大幅に向上するだけでなく、ルールのメモリ消費量が削減されます（90% 以上削減されることもあります）。

コツをご紹介します。

依存関係とリストを自分でフラット化するのではなく、引数として直接渡します。ctx.actions.args() 展開されます。依存関係のコンテンツを変更する必要がある場合は、ctx.actions.args#add を参照して、問題に適合するものがあるかどうかを確認します。
File#path を引数として渡していますか？必要ありません。ファイルは自動的にパスに変換され、展開時に延期されます。
文字列を連結して構成しないでください。文字列引数には定数を使用することをおすすめします。これは、ルールのすべてのインスタンス間でメモリが共有されるためです。
引数がコマンドラインに対して長すぎる場合は、ctx.actions.args#use_param_file を使用して、ctx.actions.args() オブジェクトを条件付きまたは無条件でパラメータファイルに書き込むことができます。これは、アクションの実行時にバックグラウンドで実行されます。params ファイルを明示的に制御する必要がある場合は、ctx.actions.write を使用して手動で書き込むことができます。

例:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

伝播アクションの入力は depset である必要があります

ctx.actions.run を使用してアクションをビルドする場合は、inputs フィールドが depset を受け入れることを忘れないでください。入力が依存関係から伝播的に収集される場合は常に使用します。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

吊り下げ

Bazel がハングしていると思われる場合は、Ctrl-\ キーを押すか、Bazel に SIGQUIT シグナル（kill -3 $(bazel info server_pid)）を送信して、ファイル $(bazel info output_base)/server/jvm.out にスレッドダンプを取得します。

bazel がハングしている場合、bazel info を実行できない可能性があるため、通常、output_base ディレクトリはワークスペースディレクトリ内の bazel-<workspace> シンボリックリンクの親になります。

パフォーマンスプロファイリング

JSON トレースプロファイルは、呼び出し中に Bazel が何に時間を費やしたかをすばやく把握するのに非常に役立ちます。

--experimental_command_profile フラグを使用すると、さまざまな種類の Java Flight Recorder プロファイル（CPU 時間、経過時間、メモリ割り当て、ロック競合）をキャプチャできます。

--starlark_cpu_profile フラグを使用すると、すべての Starlark スレッドによる CPU 使用率の pprof プロファイルを書き込むことができます。

メモリのプロファイリング

Bazel には、ルールのメモリ使用量を確認できるメモリプロファイラが組み込まれています。問題がある場合は、ヒープダンプを実行して、問題の原因となっているコード行を特定できます。

メモリトラッキングの有効化

Bazel の呼び出しごとに、次の 2 つの起動フラグを渡す必要があります。

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

これらは、メモリトラッキングモードでサーバーを起動します。1 回の Bazel 呼び出しでこれらのオプションを忘れると、サーバーが再起動され、最初からやり直す必要があります。

メモリトラッカーの使用

たとえば、ターゲット foo を見て、その動作を確認します。分析のみを実行し、ビルド実行フェーズを実行しないようにするには、--nobuild フラグを追加します。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

次に、Bazel インスタンス全体で消費されるメモリ量を確認します。

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules を使用してルールクラスごとに分類します。

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory を使用して pprof ファイルを生成して、メモリがどこに移動しているかを確認します。

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

pprof ツールを使用してヒープを調査します。最初は、pprof -flame $HOME/prof.gz を使用してフレームグラフを取得することをおすすめします。

https://github.com/google/pprof から pprof を取得します。

次の行のアノテーションが付けられた、最もホットなコールサイトのテキストダンプを取得します。

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)