การเพิ่มประสิทธิภาพ

เมื่อเขียนกฎ ข้อผิดพลาดด้านประสิทธิภาพที่พบบ่อยที่สุดคือการเรียกดูหรือคัดลอกข้อมูลที่รวบรวมจากข้อกําหนด เมื่อรวบรวมข้อมูลทั้งหมดในบิลด์ การดำเนินการเหล่านี้อาจใช้เวลาหรือพื้นที่เก็บข้อมูล O(N^2) ได้อย่างง่ายดาย คุณจึงควรทำความเข้าใจวิธีใช้ Depset อย่างมีประสิทธิภาพเพื่อหลีกเลี่ยงปัญหานี้

การดำเนินการนี้อาจทำได้ยาก Bazel จึงมีเครื่องมือวิเคราะห์หน่วยความจำที่จะช่วยคุณค้นหาจุดที่คุณอาจทำผิดพลาด โปรดทราบว่าค่าใช้จ่ายในการเขียนกฎที่ไม่มีประสิทธิภาพอาจไม่ชัดเจนจนกว่ากฎดังกล่าวจะใช้งานกันอย่างแพร่หลาย

ใช้ชุดข้อมูล

คุณควรใช้ depsets ทุกครั้งที่รวมข้อมูลจากข้อกําหนดของกฎ ใช้เฉพาะลิสต์หรือพจนานุกรมแบบธรรมดาเพื่อเผยแพร่ข้อมูลในกฎปัจจุบัน

ชุดข้อมูล Dependency แสดงข้อมูลเป็นกราฟที่ฝังอยู่ซึ่งช่วยให้แชร์ได้

ลองดูกราฟต่อไปนี้

C -> B -> A
D ---^

แต่ละโหนดจะเผยแพร่สตริงเดียว เมื่อใช้ชุดข้อมูล ข้อมูลจะมีลักษณะดังนี้

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

โปรดทราบว่าแต่ละรายการจะกล่าวถึงเพียงครั้งเดียว เมื่อใช้รายการ คุณจะได้รับสิ่งต่อไปนี้

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

โปรดทราบว่าในกรณีนี้มีการพูดถึง 'a' 4 ครั้ง ปัญหานี้จะยิ่งแย่ลงเมื่อใช้กราฟขนาดใหญ่

ต่อไปนี้คือตัวอย่างการใช้งานกฎที่ใช้ depset อย่างถูกต้องเพื่อเผยแพร่ข้อมูลที่ส่งผ่าน โปรดทราบว่าคุณเผยแพร่ข้อมูลระดับกฎโดยใช้ลิสต์ได้หากต้องการ เนื่องจากการดำเนินการนี้ไม่ใช่ O(N^2)

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ดูข้อมูลเพิ่มเติมได้ที่หน้าภาพรวมของ Depset

หลีกเลี่ยงการโทรหา depset.to_list()

คุณสามารถบังคับให้ depset เป็นรายการแบบแบนโดยใช้ to_list() แต่โดยทั่วไปแล้วการดำเนินการนี้จะส่งผลให้มีต้นทุนแบบ O(N^2) หากเป็นไปได้ ให้หลีกเลี่ยงการยุบชุดข้อมูล ยกเว้นเพื่อวัตถุประสงค์ในการแก้ไขข้อบกพร่อง

คําเข้าใจผิดที่พบบ่อยคือคุณสามารถยุบชุดข้อมูลอย่างอิสระได้หากทํากับเป้าหมายระดับบนสุดเท่านั้น เช่น กฎ <xx>_binary เนื่องจากระบบจะไม่รวมค่าใช้จ่ายในแต่ละระดับของกราฟการสร้าง แต่วิธีนี้ยังคงเป็น O(N^2) เมื่อคุณสร้างชุดเป้าหมายที่มีความสัมพันธ์ซึ่งกันและกัน กรณีนี้จะเกิดขึ้นเมื่อคุณสร้างการทดสอบ //foo/tests/... หรือเมื่อนําเข้าโปรเจ็กต์ IDE

ลดจํานวนการโทรเป็น depset

การเรียก depset ภายในลูปมักเป็นข้อผิดพลาด ซึ่งอาจทําให้เกิด Depset ที่มีการฝังซ้อนกันมาก ซึ่งทํางานได้ไม่ดี เช่น

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

รหัสนี้เปลี่ยนได้ง่ายๆ ก่อนอื่น ให้รวบรวมชุดข้อมูล transitive แล้วผสานทั้งหมดพร้อมกัน

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

บางครั้งคุณอาจลดจำนวนการเรียกใช้นี้ได้ด้วยการใช้ลิสต์คอมเพรสชัน ดังนี้

x = depset(transitive = [i.deps for i in inputs])

ใช้ ctx.actions.args() สําหรับบรรทัดคําสั่ง

เมื่อสร้างบรรทัดคำสั่ง คุณควรใช้ ctx.actions.args() ซึ่งจะเลื่อนการขยายชุดข้อมูลไปยังระยะการดําเนินการ

นอกจากทำงานได้เร็วขึ้นแล้ว วิธีนี้ยังช่วยลดการใช้หน่วยความจําของกฎด้วย ซึ่งบางครั้งอาจลดได้กว่า 90%

ลองดูเคล็ดลับต่อไปนี้

• ส่งชุดข้อมูลและลิสต์เป็นอาร์กิวเมนต์โดยตรงแทนการผสานชุดข้อมูลและลิสต์ด้วยตนเอง ระบบจะเพิ่มพื้นที่เก็บข้อมูลให้ ctx.actions.args() GB หากต้องการเปลี่ยนรูปแบบเนื้อหา depset ให้ดูที่ ctx.actions.args#add เพื่อดูว่ามีอะไรที่ตรงกับความต้องการหรือไม่

• คุณส่ง File#path เป็นอาร์กิวเมนต์อยู่หรือไม่ ไม่จำเป็น ระบบจะเปลี่ยนไฟล์เป็นเส้นทางโดยอัตโนมัติ โดยจะเลื่อนไปไว้ที่เวลาขยาย

• หลีกเลี่ยงการสร้างสตริงโดยการต่อสตริงเข้าด้วยกัน อาร์กิวเมนต์สตริงที่ดีที่สุดคือค่าคงที่ เนื่องจากระบบจะแชร์หน่วยความจำของอาร์กิวเมนต์นี้ระหว่างอินสแตนซ์ทั้งหมดของกฎ

• หากอาร์กิวเมนต์ยาวเกินกว่าที่บรรทัดคำสั่งจะรองรับ ระบบจะเขียนออบเจ็กต์ ctx.actions.args() ไปยังไฟล์พารามิเตอร์แบบมีเงื่อนไขหรือไม่มีเงื่อนไขได้โดยใช้ ctx.actions.args#use_param_file ซึ่งการดำเนินการนี้จะทําในเบื้องหลังเมื่อมีการดําเนินการ หากต้องการควบคุมไฟล์ params อย่างชัดแจ้ง คุณสามารถเขียนไฟล์ด้วยตนเองได้โดยใช้ ctx.actions.write

ตัวอย่าง

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

อินพุตการดําเนินการแบบทรานซิทีฟควรเป็นชุดข้อมูล

เมื่อสร้างการดําเนินการโดยใช้ ctx.actions.run โปรดอย่าลืมว่าช่อง inputs ยอมรับ depset ใช้คำสั่งนี้ทุกครั้งที่รวบรวมอินพุตจากข้อกําหนดเบื้องต้นแบบทรานซิทีฟ

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

แขวน

หาก Bazel ดูเหมือนจะค้าง ให้กด Ctrl-\ หรือส่งสัญญาณ SIGQUIT (kill -3 $(bazel info server_pid)) ไปยัง Bazel เพื่อดูการถ่ายโอนข้อมูลชุดข้อความในไฟล์ $(bazel info output_base)/server/jvm.out

เนื่องจากคุณอาจไม่สามารถเรียกใช้ bazel info ได้หาก bazel ค้างอยู่ โดยปกติแล้วไดเรกทอรี output_base จะเป็นไดเรกทอรีหลักของ bazel-<workspace> ที่เป็นสัญลักษณ์ลิงก์ในไดเรกทอรีเวิร์กスペース

โปรไฟล์ประสิทธิภาพ

โปรไฟล์การติดตาม JSON มีประโยชน์มากในการทำความเข้าใจสิ่งที่ Bazel ใช้เวลาไปกับการดำเนินการเรียกใช้

อาจใช้ Flag --experimental_command_profile เพื่อบันทึกโปรไฟล์ Java Flight Recorder ประเภทต่างๆ (เวลา CPU, เวลาจริง, การจัดสรรหน่วยความจำ และการแย่งสิทธิ์เข้าถึงล็อก)

คุณอาจใช้ Flag --starlark_cpu_profile เพื่อเขียนโปรไฟล์ pprof ของการใช้งาน CPU โดยเธรด Starlark ทั้งหมด

การสร้างโปรไฟล์หน่วยความจำ

Bazel มาพร้อมกับเครื่องมือวิเคราะห์หน่วยความจำในตัวซึ่งช่วยตรวจสอบการใช้หน่วยความจำของกฎได้ หากพบปัญหา คุณสามารถถ่ายโอนข้อมูลกองเพื่อค้นหาบรรทัดโค้ดที่ทำให้เกิดปัญหาได้

การเปิดใช้การติดตามหน่วยความจํา

คุณต้องส่ง Flag เริ่มต้น 2 รายการนี้ไปยังการเรียกใช้ Bazel ทุกครั้ง

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

ซึ่งจะเริ่มต้นเซิร์ฟเวอร์ในโหมดการติดตามหน่วยความจํา หากคุณลืมดำเนินการเหล่านี้แม้แต่ในการเรียกใช้ Bazel เพียงครั้งเดียว เซิร์ฟเวอร์จะรีสตาร์ทและคุณจะต้องเริ่มใหม่

การใช้เครื่องมือติดตามหน่วยความจำ

ตัวอย่างเช่น ให้ดูที่เป้าหมาย foo และดูว่าทําอะไร หากต้องการเรียกใช้การวิเคราะห์เท่านั้นและไม่เรียกใช้ระยะการทำงานของบิลด์ ให้เพิ่ม Flag --nobuild

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

ต่อไป ให้ดูว่าอินสแตนซ์ Bazel ทั้งหมดใช้หน่วยความจำเท่าใด

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

แจกแจงตามคลาสกฎโดยใช้ bazel dump --rules

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

ดูว่าหน่วยความจําถูกใช้ไปที่ไหนโดยสร้างไฟล์ pprof ใช้ bazel dump --skylark_memory

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

ใช้เครื่องมือ pprof เพื่อตรวจสอบกอง จุดเริ่มต้นที่ดีคือการดูกราฟเปลวไฟโดยใช้ pprof -flame $HOME/prof.gz

ดาวน์โหลด pprof จาก https://github.com/google/pprof

รับการดัมพ์ข้อความของเว็บไซต์ที่มีการโทรเข้ามากที่สุดพร้อมคำอธิบายประกอบด้วยบรรทัดต่อไปนี้

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)