परफ़ॉर्मेंस को ऑप्टिमाइज़ करना

समस्या की शिकायत करेंopen_in_new सोर्स देखेंopen_in_new ठीक

नियम लिखते समय, परफ़ॉर्मेंस से जुड़ी सबसे आम नुकसान, डिपेंडेंसी से इकट्ठा होने वाले डेटा को ट्रैवर्स या कॉपी करना होता है. पूरे बिल्ड में एग्रीगेट होने पर, ये कार्रवाइयां आसानी से O(N^2) समय या स्पेस ले सकती हैं. इससे बचने के लिए, यह समझना ज़रूरी है कि डिप्स का असरदार ढंग से इस्तेमाल कैसे किया जाए.

किसी सही जगह को ढूंढना मुश्किल हो सकता है. इसलिए, Basel ने आपको एक मेमोरी प्रोफ़ाइलर भी उपलब्ध कराया है. इससे आपको उन जगहों को ढूंढने में मदद मिलती है जहां आपसे कोई गलती हो सकती है. ध्यान रखें: जब तक किसी गलत नियम को बड़े पैमाने पर इस्तेमाल नहीं किया जाता, तब तक उस नियम को लिखने में आने वाली लागत का पता नहीं चलता.

डिपसेट का इस्तेमाल करें

नियम डिपेंडेंसी से जानकारी को रोल आउट करने के लिए, आपको डिपसेट का इस्तेमाल करना चाहिए. मौजूदा नियम के हिसाब से जानकारी पब्लिश करने के लिए, सिर्फ़ सादी सूचियों या निर्देशों का इस्तेमाल करें.

डिप्सेट, जानकारी को नेस्ट किए गए ग्राफ़ के रूप में दिखाता है, जिसकी मदद से जानकारी शेयर की जा सकती है.

नीचे दिया गया ग्राफ़ देखें:

C -> B -> A
D ---^

हर नोड एक स्ट्रिंग पब्लिश करता है. जानकारी में अंतर होने पर, डेटा ऐसा दिखता है:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

ध्यान दें कि हर आइटम का नाम सिर्फ़ एक बार दिया गया है. सूचियों के साथ आपको यह मिलेगा:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

ध्यान दें कि इस मामले में 'a' का उल्लेख चार बार हुआ है! बड़े ग्राफ़ के साथ, यह समस्या और भी बदतर होती जाएगी.

यहां एक नियम लागू करने का उदाहरण दिया गया है, जिसमें ट्रांज़िटिव जानकारी को पब्लिश करने के लिए, सही तरीके से डिप्स का इस्तेमाल किया जाता है. ध्यान दें कि अगर आप चाहें, तो सूचियों का इस्तेमाल करके, नियम-स्थानीय जानकारी को पब्लिश करने में कोई समस्या नहीं है. ऐसा इसलिए है, क्योंकि यह O(N^2) नहीं है.

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ज़्यादा जानकारी के लिए, डिससेट की खास जानकारी पेज देखें.

depset.to_list() को कॉल करने से बचें

to_list() का इस्तेमाल करके, किसी डिप्सेट को फ़्लैट सूची में रखा जा सकता है. हालांकि, आम तौर पर ऐसा करने से O(N^2) लागत आती है. अगर हो सके, तो डीबग करने के मकसद को छोड़कर, डेटा को फ़्लैट करने से बचें.

एक आम गलतफ़हमी यह है कि अगर आप <xx>_binary नियम जैसे टॉप-लेवल के टारगेट पर ही ऐसा करते हैं, तो अलग से कमी का लेवल तय किया जा सकता है. ऐसा करने से, बिल्ड ग्राफ़ के हर लेवल पर लागत इकट्ठा नहीं होती है. हालांकि, ओवरलैप होने वाली डिपेंडेंसी के साथ टारगेट का सेट बनाने पर, यह अब भी O(N^2) है. ऐसा, टेस्ट //foo/tests/... बनाते समय या IDE प्रोजेक्ट इंपोर्ट करते समय होता है.

depset पर कॉल करने की संख्या कम करें

depset को लूप में कॉल करना अक्सर गलती हो जाता है. इससे बहुत गहराई से घोंसला बनाने की समस्या पैदा हो सकती है, जो अच्छी तरह से काम नहीं करती है. उदाहरण के लिए:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

इस कोड को आसानी से बदला जा सकता है. सबसे पहले, ट्रांज़िटिव डिपसेट इकट्ठा करें और उन सभी को एक साथ मर्ज करें:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

सूची समझने की सुविधा का इस्तेमाल करके, कभी-कभी इसे कम किया जा सकता है:

x = depset(transitive = [i.deps for i in inputs])

कमांड लाइन के लिए ctx.action.orgs() का इस्तेमाल करें

कमांड लाइन बनाते समय आपको ctx.actions.args() का इस्तेमाल करना चाहिए. इससे, एक्ज़ीक्यूशन के चरण में किसी भी तरह की कमी को रोका जा सकता है.

पूरी तरह से तेज़ होने के अलावा, यह आपके नियमों की मेमोरी खपत को कम करेगा -- कभी-कभी 90% या उससे ज़्यादा तक.

यहां कुछ तरकीबें दी गई हैं:

• डेपसेट और सूचियों को खुद आर्ग्युमेंट के तौर पर पास करने के बजाय, उन्हें सीधे आर्ग्युमेंट के तौर पर पास करें. ये ctx.actions.args() तक बढ़ाई जा सकती हैं. अगर आपको बंद किए गए कॉन्टेंट में कोई बदलाव करने की ज़रूरत है, तो ctx.actions.args#add में जाकर देखें कि इसके हिसाब से यह कॉन्टेंट सही है या नहीं.

• क्या आपने File#path को आर्ग्युमेंट के तौर पर पास किया है? कोई ज़रूरत नहीं है. कोई भी फ़ाइल अपने-आप उसके पाथ में बदल जाती है, जिसे बड़ा करने में लगने वाला समय टाला जाता है.

• स्ट्रिंग को एक साथ जोड़कर उन्हें बनाने से बचें. सबसे अच्छा स्ट्रिंग आर्ग्युमेंट एक कॉन्स्टेंट होता है, क्योंकि इसकी मेमोरी को आपके नियम के सभी इंस्टेंस के बीच शेयर किया जाएगा.

• अगर कमांड लाइन के लिए आर्ग्युमेंट बहुत लंबे हैं, तो ctx.actions.args() ऑब्जेक्ट को ctx.actions.args#use_param_file का इस्तेमाल करके, पैरामीटर फ़ाइल में शर्त के साथ या बिना किसी शर्त के लिखा जा सकता है. यह काम, पर्दे के पीछे करके तब किया जाता है, जब कार्रवाई पूरी होती है. अगर आपको पैरामीटर फ़ाइल को साफ़ तौर पर कंट्रोल करना है, तो ctx.actions.write का इस्तेमाल करके उसे मैन्युअल तरीके से लिखा जा सकता है.

उदाहरण:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

ट्रांज़िटिव ऐक्शन के इनपुट को डिपसेट होने चाहिए

ctx.actions.run का इस्तेमाल करके कार्रवाई करते समय, यह न भूलें कि inputs फ़ील्ड में डिप्सेट स्वीकार किया जाता है. इसका इस्तेमाल तब करें, जब डिपेंडेंसी से ट्रांज़िट के तौर पर इनपुट इकट्ठा किए जाएं.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

हैंगिंग

अगर ऐसा लगता है कि Basel को निलंबित कर दिया गया है, तो $(bazel info output_base)/server/jvm.out फ़ाइल में थ्रेड डंप पाने के लिए, Ctrl-\ को दबाएं या बैज को SIGQUIT सिग्नल (kill -3 $(bazel info server_pid)) भेजें.

बेज़ल हैंग होने पर, हो सकता है कि आप bazel info न चला पाएं. इसलिए, आम तौर पर output_base डायरेक्ट्री, आपकी वर्कस्पेस डायरेक्ट्री में मौजूद bazel-<workspace> सिमलिंक की पैरंट होती है.

परफ़ॉर्मेंस प्रोफ़ाइलिंग

शुरू करने के दौरान, बेज़ल ने क्या समय बिताया, यह तुरंत समझने में JSON ट्रेस प्रोफ़ाइल मददगार हो सकती है.

--experimental_command_profile फ़्लैग का इस्तेमाल, Java फ़्लाइट रिकॉर्डर की कई तरह की प्रोफ़ाइलों को कैप्चर करने के लिए किया जा सकता है. जैसे, सीपीयू टाइम, वॉल टाइम, मेमोरी का बंटवारा, और लॉक का विवाद.

--starlark_cpu_profile फ़्लैग का इस्तेमाल, सभी Starlark थ्रेड के सीपीयू के इस्तेमाल की pprof प्रोफ़ाइल लिखने के लिए किया जा सकता है.

मेमोरी की प्रोफ़ाइल बनाना

Basel में एक मेमोरी प्रोफ़ाइलर होता है जो आपके नियम में मेमोरी के इस्तेमाल की जांच करने में आपकी मदद कर सकता है. अगर कोई समस्या है, तो उस कोड की सटीक लाइन का पता लगाने के लिए उस हीप को छोड़ें.

मेमोरी ट्रैकिंग की सुविधा चालू करना

आपको हर Baज़र के अनुरोध के लिए, इन दो स्टार्टअप फ़्लैग को पास करना होगा:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

ये सर्वर को मेमोरी ट्रैकिंग मोड में शुरू करते हैं. अगर एक बार भी बेज़ल इन्वेशन के लिए आप इन्हें भूल जाते हैं, तो सर्वर रीस्टार्ट हो जाएगा और आपको फिर से शुरू करना होगा.

मेमोरी ट्रैकर का इस्तेमाल करना

उदाहरण के लिए, टारगेट foo को देखें और जानें कि यह क्या करता है. बिल्ड प्रोसेस को पूरा करने के चरण के बजाय, सिर्फ़ विश्लेषण चलाने के लिए --nobuild फ़्लैग जोड़ें.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

इसके बाद, देखें कि पूरे Basel इंस्टेंस में कितनी मेमोरी इस्तेमाल होती है:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules का इस्तेमाल करके इसे नियम की क्लास के हिसाब से बांटें:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory का इस्तेमाल करके pprof फ़ाइल बनाकर देखें कि मेमोरी कहां जा रही है:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

हीप की जांच करने के लिए, pprof टूल का इस्तेमाल करें. pprof -flame $HOME/prof.gz का इस्तेमाल करके फ़्लेम ग्राफ़ बनाना एक अच्छा तरीका है.

https://github.com/google/pprof से pprof पाएं.

सबसे लोकप्रिय कॉल साइटों का एक टेक्स्ट डंप पाएं, जिसके साथ लाइनों की जानकारी दी गई हो:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)