บทแนะนำ Bazel: กำหนดค่าเชนเครื่องมือ C++

รายงานปัญหา ดูแหล่งที่มา ตอนกลางคืน · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

บทแนะนำนี้ใช้สถานการณ์ตัวอย่างในการอธิบายวิธีกำหนดค่า C++ Toolchains สำหรับโปรเจ็กต์

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีต่อไปนี้

ตั้งค่าสภาพแวดล้อมของบิลด์
ใช้ --toolchain_resolution_debug เพื่อแก้ไขข้อบกพร่องของความละเอียด Toolchain
กำหนดค่าเครื่องมือเชน C++
สร้างกฎ Starlark ที่กำหนดค่าเพิ่มเติมสำหรับองค์ประกอบ cc_toolchainเพื่อให้ Bazel สร้างแอปพลิเคชันด้วย clang ได้
สร้างไบนารี C++ โดยการเรียกใช้ bazel build //main:hello-world ใน เครื่อง Linux
คอมไพล์ไบนารีของ Android โดยเรียกใช้ bazel build //main:hello-world --platforms=//:android_x86_64

ก่อนเริ่มต้น

บทแนะนำนี้จะถือว่าคุณกำลังใช้ Linux และได้สร้าง C++ เรียบร้อยแล้ว และติดตั้งเครื่องมือและไลบรารีที่เหมาะสม บทแนะนำ ใช้ clang version 16 ซึ่งติดตั้งในระบบของคุณได้

ตั้งค่าสภาพแวดล้อมของบิลด์

ตั้งค่าสภาพแวดล้อมของบิลด์ดังนี้

หากคุณยังไม่ได้ดำเนินการ ให้ดาวน์โหลดและติดตั้ง Bazel 7.0.2 ขึ้นไป
เพิ่มไฟล์ MODULE.bazel ที่ว่างเปล่าในโฟลเดอร์รูท
เพิ่มเป้าหมาย cc_binary ต่อไปนี้ลงในไฟล์ main/BUILD:
```
cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)
```
เนื่องจาก Bazel ใช้เครื่องมือภายในจำนวนมากที่เขียนด้วย C++ ระหว่างการสร้าง ในฐานะ process-wrapper มีการระบุ Toolchain ของ C++ เริ่มต้นที่มีอยู่ล่วงหน้าแล้ว สำหรับแพลตฟอร์มโฮสต์ เครื่องมือภายในเหล่านี้จึงสามารถสร้าง โดยใช้ Toolchain ที่สร้างขึ้นในบทแนะนำนี้ ดังนั้น เป้าหมาย cc_binary ก็สร้างขึ้นด้วย Toolchain เริ่มต้นเช่นกัน
เรียกใช้บิลด์ด้วยคำสั่งต่อไปนี้
```
bazel build //main:hello-world
```
บิลด์ประสบความสำเร็จโดยไม่มี Toolchain ที่ลงทะเบียนไว้ใน MODULE.bazel

หากต้องการดูสิ่งที่อยู่เบื้องหลังเพิ่มเติม ให้เรียกใช้
```
bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type'

INFO: ToolchainResolution: Target platform @@platforms//host:host: Selected execution platform @@platforms//host:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8
```
หากไม่ได้ระบุ --platforms Bazel จะสร้างเป้าหมายสำหรับ @platforms//hostกำลังใช้ @bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8

กำหนดค่าเครื่องมือเชน C++

ในการกำหนดค่า Toolchain ของ C++ ให้สร้างแอปพลิเคชันซ้ำๆ และกำจัด ข้อผิดพลาดทีละรายการดังอธิบายต่อไปนี้

ก็ถือว่าเป็น clang version 9.0.1 เช่นกัน แต่ควรเปลี่ยนแปลงรายละเอียดเท่านั้น ระหว่างคำทับศัพท์เวอร์ชันต่างๆ เล็กน้อย

เพิ่ม toolchain/BUILD ด้วย

filegroup(name = "empty")

cc_toolchain(
    name = "linux_x86_64_toolchain",
    toolchain_identifier = "linux_x86_64-toolchain",
    toolchain_config = ":linux_x86_64_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

toolchain(
    name = "cc_toolchain_for_linux_x86_64",
    toolchain = ":linux_x86_64_toolchain",
    toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
    exec_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
)

จากนั้นเพิ่มทรัพยากร Dependency ที่เหมาะสมและลงทะเบียน Toolchain กับ MODULE.bazel ด้วย

bazel_dep(name = "platforms", version = "0.0.10")
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64"
)

ขั้นตอนนี้จะกำหนด cc_toolchain และเชื่อมโยงกับเป้าหมาย toolchain สำหรับ การกำหนดค่าโฮสต์

เรียกใช้บิลด์อีกครั้ง เนื่องจากแพ็กเกจ toolchain ยังไม่ได้กำหนด เป้าหมาย linux_x86_64_toolchain_config Bazel แสดงข้อผิดพลาดต่อไปนี้
```
ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.
```
ในไฟล์ toolchain/BUILD ให้กำหนดกลุ่มไฟล์ที่ว่างเปล่าดังนี้
```
package(default_visibility = ["//visibility:public"])

filegroup(name = "linux_x86_64_toolchain_config")
```
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
'//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.
```
CcToolchainConfigInfo เป็นผู้ให้บริการที่คุณใช้ในการกำหนดค่า C++ Toolchain หากต้องการแก้ไขข้อผิดพลาดนี้ ให้สร้างกฎ Starlark ที่ระบุ CcToolchainConfigInfo กับ Bazel ด้วยการสร้าง toolchain/cc_toolchain_config.bzl ซึ่งมีเนื้อหาต่อไปนี้
```
def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)
```
cc_common.create_cc_toolchain_config_info() สร้างผู้ให้บริการที่จำเป็น CcToolchainConfigInfo หากต้องการใช้กฎ cc_toolchain_config ให้เพิ่มโหลด คำสั่งไปยัง toolchain/BUILD ใต้ข้อความแพ็กเกจ:
```
load(":cc_toolchain_config.bzl", "cc_toolchain_config")
```
แล้วแทนที่ "linux_x86_64_toolchain_config" กลุ่มไฟล์ที่มีการประกาศ ของกฎ cc_toolchain_config ข้อต่อไปนี้
```
cc_toolchain_config(name = "linux_x86_64_toolchain_config")
```

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

ณ จุดนี้ Bazel มีข้อมูลเพียงพอที่จะพยายามสร้างโค้ด แต่ แต่ยังไม่รู้ว่าจะต้องใช้เครื่องมือใดในการสร้างบิลด์ที่จำเป็น การดำเนินการ คุณจะต้องแก้ไขการใช้กฎ Starlark เพื่อบอก Bazel เครื่องมือที่ใช้ได้ สำหรับการดำเนินการดังกล่าว คุณต้องใช้ตัวสร้าง tool_path() จาก @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl:

# toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

ตรวจสอบว่า /usr/bin/clang และ /usr/bin/ld เป็นเส้นทางที่ถูกต้องสำหรับ ระบบของคุณ

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world':
the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain):
  '/usr/include/c++/13/ctime'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h'
  ...
```
Bazel ต้องการทราบตำแหน่งที่จะค้นหาส่วนหัวที่รวมอยู่ มีตัวเลือกหลายรายการ จะแก้ปัญหานี้ได้ เช่น การใช้แอตทริบิวต์ includes ของ cc_binary แต่ในที่นี้จะแก้ที่ระดับ Toolchain ด้วย cxx_builtin_include_directories พารามิเตอร์ cc_common.create_cc_toolchain_config_info โปรดระวังว่าถ้าคุณ กำลังใช้ clang เวอร์ชันอื่น เส้นทางการรวมจะ แตกต่างกัน เส้นทางเหล่านี้อาจแตกต่างกันขึ้นอยู่กับการกระจาย

แก้ไขค่าการแสดงผลใน toolchain/cc_toolchain_config.bzl ให้มีลักษณะดังนี้ ดังนี้
```
return cc_common.create_cc_toolchain_config_info(
    ctx = ctx,
    cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-16/lib/clang/16/include",
        "/usr/include",
    ],
    toolchain_identifier = "local",
    host_system_name = "local",
    target_system_name = "local",
    target_cpu = "k8",
    target_libc = "unknown",
    compiler = "clang",
    abi_version = "unknown",
    abi_libc_version = "unknown",
    tool_paths = tool_paths,
)
```

เรียกใช้คำสั่งบิลด์อีกครั้ง คุณจะเห็นข้อผิดพลาดอย่างเช่น

/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

เนื่องจาก Linker ไม่มีมาตรฐาน C++ และไม่พบสัญลักษณ์ การแก้ไขปัญหานี้มีหลายวิธี เช่น การใช้แอตทริบิวต์ linkopts ของ cc_binary ในที่นี้จะแก้โดย ตรวจสอบให้แน่ใจว่าเป้าหมายใดๆ ที่ใช้ Toolchain ไม่จำเป็นต้องระบุข้อมูลนี้ แจ้ง

คัดลอกรหัสต่อไปนี้ไปยัง toolchain/cc_toolchain_config.bzl:

# NEW
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
# NEW
load(
    "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
    "feature",    # NEW
    "flag_group", # NEW
    "flag_set",   # NEW
    "tool_path",
)

all_link_actions = [ # NEW
    ACTION_NAMES.cpp_link_executable,
    ACTION_NAMES.cpp_link_dynamic_library,
    ACTION_NAMES.cpp_link_nodeps_dynamic_library,
]

def _impl(ctx):
    tool_paths = [
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/bin/false",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    features = [ # NEW
        feature(
            name = "default_linker_flags",
            enabled = True,
            flag_sets = [
                flag_set(
                    actions = all_link_actions,
                    flag_groups = ([
                        flag_group(
                            flags = [
                                "-lstdc++",
                            ],
                        ),
                    ]),
                ),
            ],
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        features = features, # NEW
        cxx_builtin_include_directories = [
            "/usr/lib/llvm-9/lib/clang/9.0.1/include",
            "/usr/include",
        ],
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths,
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

เมื่อเรียกใช้ bazel build //main:hello-world ระบบควรสร้างไบนารีได้ในที่สุด สำเร็จสำหรับโฮสต์
ใน toolchain/BUILD ให้คัดลอก cc_toolchain_config, cc_toolchain และ เป้าหมาย toolchain และแทนที่ linux_x86_64 ด้วย android_x86_64ใน ชื่อเป้าหมาย

ใน MODULE.bazel ให้ลงทะเบียน Toolchain สำหรับ Android
```
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64",
    "//toolchain:cc_toolchain_for_android_x86_64"
)
```
เรียกใช้ bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64 เพื่อสร้างไบนารีสำหรับ Android

ในทางปฏิบัติ Linux และ Android ควรมีการกำหนดค่า Toolchain ของ C++ ต่างกัน คุณ สามารถแก้ไข cc_toolchain_config ที่มีอยู่ตามความแตกต่าง หรือ สร้างกฎแยกต่างหาก (เช่น ผู้ให้บริการ CcToolchainConfigInfo) สำหรับ ใหม่

ตรวจสอบงานของคุณ

ในบทแนะนำนี้ คุณได้เรียนรู้วิธีกำหนดค่า Toolchain พื้นฐาน C++ แต่ Toolchains มีประสิทธิภาพมากกว่าตัวอย่างนี้

ประเด็นสำคัญมีดังนี้

คุณต้องระบุแฟล็ก platforms ที่ตรงกันในบรรทัดคำสั่งสำหรับ Bazel จะแปลงค่าเป็น Toolchain สำหรับค่าข้อจำกัดเดียวกันใน ที่มีการจัดการครบวงจรได้เลย เอกสารประกอบเพิ่มเติมเกี่ยวกับข้อมูลเฉพาะภาษา แฟล็กการกำหนดค่า
คุณต้องแจ้งให้ Toolchain ทราบว่าเครื่องมืออยู่ ณ ที่ใด ในบทแนะนำนี้ มีเวอร์ชันแบบง่ายที่คุณเข้าถึงเครื่องมือจากระบบ ถ้า คุณสนใจในแนวทางที่พัฒนาได้ด้วยตนเองมากยิ่งขึ้น คุณสามารถอ่านเกี่ยวกับ ทรัพยากร Dependency ภายนอก เครื่องมือของคุณอาจมาจาก โมดูลอื่น และคุณจะต้องทำให้ไฟล์ของพวกเขาพร้อมใช้งานสำหรับ cc_toolchain ที่มีทรัพยากร Dependency เป้าหมายในแอตทริบิวต์ เช่น compiler_files คุณจะต้องเปลี่ยน tool_paths ด้วย
คุณสร้างฟีเจอร์เพื่อกำหนดค่า Flag ที่ควรส่งไปได้ การกระทำต่างๆ ไม่ว่าจะเป็นการลิงก์หรือการกระทำประเภทอื่นๆ

อ่านเพิ่มเติม

ดูรายละเอียดเพิ่มเติมได้ที่ Toolchain ของ C++ การกำหนดค่า