Tạo Macro

Hãy tưởng tượng bạn cần chạy một công cụ trong quá trình xây dựng. Ví dụ: Bạn nên tạo hoặc xử lý trước một tệp nguồn hoặc nén một tệp nhị phân. Trong hướng dẫn này, bạn sẽ tạo một macro đổi kích thước hình ảnh.

Macro phù hợp với các tác vụ đơn giản. Nếu bạn muốn làm bất cứ việc gì phức tạp hơn, chẳng hạn như thêm tính năng hỗ trợ cho một ngôn ngữ lập trình mới, hãy cân nhắc tạo quy tắc. Quy tắc mang đến cho bạn nhiều quyền kiểm soát và sự linh hoạt hơn.

Cách dễ nhất để tạo một macro đổi kích thước hình ảnh là sử dụng genrule:

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

Nếu cần đổi kích thước nhiều hình ảnh hơn, bạn nên sử dụng lại mã này. Để làm việc đó, hãy xác định một hàm trong tệp .bzl riêng biệt và gọi tệp miniature.bzl:

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

Một vài lưu ý:

• Theo quy ước, macro có đối số name, giống như quy tắc.

• Để ghi lại hành vi của macro, hãy sử dụng docstring như trong Python.

• Để gọi genrule hoặc bất kỳ quy tắc gốc nào khác, hãy sử dụng native..

• Sử dụng **kwargs để chuyển tiếp các đối số bổ sung đến genrule cơ bản (cũng giống như trong Python). Điều này rất hữu ích để người dùng có thể sử dụng các thuộc tính chuẩn như visibility hoặc tags.

Bây giờ, hãy sử dụng macro từ tệp BUILD:

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)