実行グループ

Nightly · 9.0 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 7.7

実行グループを使用すると、1 つのターゲット内で複数の実行プラットフォームを使用できます。各実行グループには独自のツールチェーンの依存関係があり、独自のツールチェーン解決を実行します。

背景

実行グループを使用すると、ルール作成者は、それぞれ異なる実行プラットフォームを持つ可能性のある一連のアクションを定義できます。複数の実行プラットフォームを使用すると、アクションを異なる方法で実行できます。たとえば、リモート（Linux）ワーカーで iOS アプリをコンパイルし、ローカルの Mac ワーカーでリンク/コード署名を行うことができます。

アクションのグループを定義できると、アクションを指定するプロキシとしてアクションのニーモニックを使用する必要がなくなります。ニーモニックは一意であることが保証されておらず、1 つのアクションのみを参照できます。これは、 C++ ビルドでのリンクなど、特定のメモリと処理を必要とするアクションに余分なリソースを割り当てる場合に特に役立ちます。要求の少ないタスクに過剰に割り当てる必要はありません。

実行グループの定義

ルール定義時に、ルール作成者は一連の実行グループを宣言できます。各実行グループで、ルール作成者は、その実行グループの実行プラットフォームを選択するために必要なすべてのものを指定できます。つまり、exec_compatible_with による制約と toolchain によるツールチェーンタイプです。

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        “link”: exec_group(
            exec_compatible_with = [ "@platforms//os:linux" ]
            toolchains = ["//foo:toolchain_type"],
        ),
        “test”: exec_group(
            toolchains = ["//foo_tools:toolchain_type"],
        ),
    },
    attrs = {
        "_compiler": attr.label(cfg = config.exec("link"))
    },
)

上記のコードスニペットでは、ツール依存関係で実行グループの移行を cfg 属性パラメータと config モジュールを使用して指定することもできます。このモジュールは、依存関係をビルドする実行グループの名前である単一の文字列パラメータを受け取る exec 関数を公開します。

ネイティブルールと同様に、test 実行グループは Starlark テストルールにデフォルトで存在します。

実行グループの継承

新しい実行グループは、独自の制約とツールチェーンを定義するだけでなく、ルールのデフォルトの実行グループから継承することを、copy_from_rule = True パラメータを渡すことで宣言できます。 copy_from_rule を true に設定し、exec_compatible_with または toolchains を渡すとエラーになります。

デフォルトの実行グループから継承する実行グループは、デフォルトから制約、ツールチェーン、実行プロパティをコピーします。これには、ルール自体で指定されたものだけでなく、ターゲットレベルで設定された制約と実行プロパティも含まれます。つまり、次のようになります。

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        “copied”: exec_group(
            copy_from_rule = True,
            # This will inherit exec_compatible_with and toolchains.
            # Setting them here directly would be an error, however.
        ),
    },
    toolchains = ["//foo_tools:toolchain_type"],
    exec_compatible_with = ["@platforms//os:linux"],
)

# BUILD

my_rule(
    name = "demo",
    exec_compatible_with = [":local_constraint"],
)

構成されたターゲット demo の copied 実行グループには、次のすべてが含まれます。 - //fool_tools:toolchain_type - @platforms//os:linux - :local_constraint

実行グループへのアクセス

ルール実装では、実行グループの実行プラットフォームでアクションを実行することを宣言できます。これを行うには、アクション生成メソッドの exec_group param を使用します。具体的には、ctx.actions.run と ctx.actions.run_shell です。

# foo.bzl
def _impl(ctx):
  ctx.actions.run(
     inputs = [ctx.attr._some_tool, ctx.srcs[0]]
     exec_group = "compile",
     # ...
  )

ルール作成者は、ターゲットの解決済みツールチェーンにアクセスできるのと同様に、実行グループの解決済みツールチェーンにもアクセスできます。

# foo.bzl
def _impl(ctx):
  foo_info = ctx.exec_groups["link"].toolchains["//foo:toolchain_type"].fooinfo
  ctx.actions.run(
     inputs = [foo_info, ctx.srcs[0]]
     exec_group = "link",
     # ...
  )

実行グループを使用して実行プロパティを設定する

実行グループは、すべてのルールに存在する exec_properties 属性と統合されています。これにより、ターゲットライターは、実行メカニズムに渡されるプロパティの文字列ディクショナリを指定できます。たとえば、ターゲットにメモリなどのプロパティを設定し、特定のアクションに高いメモリ割り当てを行う場合は、次のように実行グループ拡張キーを使用して exec_properties エントリを作成します。

# BUILD
my_rule(
    name = 'my_target',
    exec_properties = {
        'mem': '12g',
        'link.mem': '16g'
    }
    …
)

exec_group = "link" のすべてのアクションで、実行プロパティディクショナリが {"mem": "16g"} として表示されます。ご覧のとおり、実行グループレベルの設定はターゲットレベルの設定よりも優先されます。

ネイティブルールの実行グループ

ネイティブルールで定義されたアクションには、次の実行グループを使用できます。

test: テストランナーアクション。
cpp_link: C++ リンクアクション。

実行プロパティを設定する実行グループを作成する

実行グループを使用して、特定のアクションに異なる実行プロパティを設定したいが、ルールとは異なるツールチェーンや制約は必要ない場合があります。このような場合は、copy_from_rule パラメータを使用して実行グループを作成できます。

# foo.bzl

# Creating an exec group with `copy_from_rule=True` is the same as explicitly
# setting the exec group's toolchains and constraints to the same values as the
# rule's respective parameters.
my_rule = rule(
    _impl,
    exec_compatible_with = ["@platforms//os:linux"],
    toolchains = ["//foo:toolchain_type"],
    exec_groups = {
        # The following two groups have the same toolchains and constraints:
        “foo”: exec_group(copy_from_rule = True),
        "bar": exec_group(
            exec_compatible_with = ["@platforms//os:linux"],
            toolchains = ["//foo:toolchain_type"],
        ),
    },
)

#

実行グループとプラットフォームの実行プロパティ

プラットフォームターゲットの任意の実行グループに exec_properties を定義できます（ターゲットに直接設定された exec_properties とは異なり、不明な実行グループのプロパティは拒否されます）。ターゲットは、デフォルトの実行グループとその他の関連する実行グループに影響する実行プラットフォームのexec_propertiesを継承します。

たとえば、C++ テストの実行にはリソースが必要だが、コンパイルとリンクには必要ない場合、次のようにモデル化できます。

constraint_setting(name = "resource")
constraint_value(name = "has_resource", constraint_setting = ":resource")

platform(
    name = "platform_with_resource",
    constraint_values = [":has_resource"],
    exec_properties = {
        "test.resource": "...",
    },
)

cc_test(
    name = "my_test",
    srcs = ["my_test.cc"],
    exec_compatible_with = [":has_resource"],
)

exec_properties ターゲットに直接定義されたは、実行プラットフォームから継承されたものよりも優先されます。