Bazel 教程：构建 Android 应用

本教程介绍了如何使用 Bazel 构建简单的 Android 应用。

Bazel 支持使用 Android 规则构建 Android 应用。

本教程面向 Windows、macOS 和 Linux 用户，无需具备 Bazel 或 Android 应用开发经验。在本教程中，您无需编写任何 Android 代码。

学习内容

在本教程中，您将学习如何：

• 安装 Bazel 和 Android Studio 并下载示例项目，以设置您的环境。
• 设置一个 Bazel workspace（工作区），其中包含应用的源代码和用于标识工作区目录顶级的 WORKSPACE 文件。
• 更新 WORKSPACE 文件，使其包含对所需外部依赖项（例如 Android SDK）的引用。
• 创建 BUILD 文件。
• 使用 Bazel 构建应用。
• 在 Android 模拟器或实体设备上部署并运行应用。

准备工作

安装 Bazel

在开始本教程之前，请安装以下软件：

• Bazel。如需安装，请按照安装说明操作。
• Android Studio。如需安装，请按照下载 Android Studio 的步骤操作。运行设置向导以下载 SDK 并配置您的环境。
• （可选）Git。使用 git 下载 Android 应用项目。

获取示例项目

对于示例项目，请使用 Bazel 的示例代码库中的基本 Android 应用项目。

此应用只有一个按钮，可在用户点击时输出问候语：

图 1. Android 应用按钮问候语。

使用 git 克隆代码库（或直接下载 ZIP 文件）：

git clone https://github.com/bazelbuild/examples

本教程的示例项目位于 examples/android/tutorial 中。在本教程的其余部分中，您将在此目录中执行命令。

查看源文件

查看应用的源文件。

.
├── README.md
└── src
    └── main
        ├── AndroidManifest.xml
        └── java
            └── com
                └── example
                    └── bazel
                        ├── AndroidManifest.xml
                        ├── Greeter.java
                        ├── MainActivity.java
                        └── res
                            ├── layout
                            │   └── activity_main.xml
                            └── values
                                ├── colors.xml
                                └── strings.xml

关键文件和目录如下：

使用 Bazel 构建

设置工作区

工作区是一个目录，其中包含一个或多个软件项目的源文件，并且其根目录下有一个 WORKSPACE 文件。

WORKSPACE 文件可能为空，或可能包含对构建项目所需的外部依赖项的引用。

首先，运行以下命令以创建一个空的 WORKSPACE 文件：

运行 Bazel

现在，您可以使用以下命令检查 Bazel 是否正常运行：

bazel info workspace

如果 Bazel 输出当前目录的路径，则表示一切正常！如果 WORKSPACE 文件不存在，您可能会看到如下错误消息：

ERROR: The 'info' command is only supported from within a workspace.

与 Android SDK 集成

Bazel 需要运行 Android SDK 构建工具才能构建应用。这意味着，您需要向 WORKSPACE 文件添加一些信息，以便 Bazel 知道在哪里可以找到这些信息。

将以下行添加到 WORKSPACE 文件中：

android_sdk_repository(name = "androidsdk")

这将使用 ANDROID_HOME 环境变量引用的路径中的 Android SDK，并自动检测该位置中安装的最高 API 级别和最新版本的构建工具。

您可以将 ANDROID_HOME 变量设置为 Android SDK 的位置。使用 Android Studio 的 SDK 管理器查找已安装 SDK 的路径。假设 SDK 安装到了默认位置，您可以使用以下命令设置 ANDROID_HOME 变量：

上述命令仅为当前的 shell 会话设置变量。如需将其设为永久性，请运行以下命令：

您还可以通过添加 path、api_level 和 build_tools_version 属性，明确指定 Android SDK 的绝对路径、API 级别以及要使用的 build 工具版本。如果未指定 api_level 和 build_tools_version，android_sdk_repository 规则将使用 SDK 中提供的相应最新版本。您可以指定这些属性的任意组合，前提是这些属性在 SDK 中存在，例如：

android_sdk_repository(
    name = "androidsdk",
    path = "/path/to/Android/sdk",
    api_level = 25,
    build_tools_version = "30.0.3"
)

在 Windows 上，请注意 path 属性必须使用混合风格的路径，即包含正斜线的 Windows 路径：

android_sdk_repository(
    name = "androidsdk",
    path = "c:/path/to/Android/sdk",
)

可选：如果您想将原生代码编译到 Android 应用中，还需要下载 Android NDK，并将以下行添加到 WORKSPACE 文件，以告知 Bazel 在哪里可以找到它：

android_ndk_repository(name = "androidndk")

与 android_sdk_repository 类似，默认情况下，系统会从 ANDROID_NDK_HOME 环境变量推断出 Android NDK 的路径。您还可以使用 android_ndk_repository 上的 path 属性明确指定路径。

如需了解详情，请参阅将 Android 原生开发套件与 Bazel 搭配使用。

api_level 是 SDK 和 NDK 以之为目标平台的 Android API 版本，例如，Android 6.0 为 23，Android 7.1 为 25。如果未明确设置，api_level 会默认采用 android_sdk_repository 和 android_ndk_repository 的可用最高 API 级别。

无需将 SDK 和 NDK 的 API 级别设置为相同的值。此页面包含 Android 版本与 NDK 支持的 API 级别之间的映射。

创建 BUILD 文件

BUILD 文件用于描述一组 build 输出（例如 aapt 中的已编译 Android 资源或 javac 中的类文件）及其依赖项之间的关系。这些依赖项可能是工作区或其他 build 输出中的源文件（Java、C++）。BUILD 文件采用一种名为 Starlark 的语言编写。

BUILD 文件属于 Bazel 中的一个概念，称为软件包层次结构。软件包层次结构是一种逻辑结构，可叠加在工作区中的目录结构上。每个软件包都是一个目录（及其子目录），其中包含一组相关的源文件和一个 BUILD 文件。该软件包还包含所有子目录，但包含自己的 BUILD 文件的子目录除外。软件包名称是 BUILD 文件相对于 WORKSPACE 的路径。

请注意，Bazel 的软件包层次结构在概念上与 BUILD 文件所在的 Android 应用目录的 Java 软件包层次结构不同，尽管这些目录可以采用相同的结构组织。

对于本教程中的简单 Android 应用，src/main/ 中的源文件构成单个 Bazel 软件包。更复杂的项目可能包含许多嵌套的软件包。

添加 android_library 规则

BUILD 文件包含多种不同类型的 Bazel 声明。最重要的类型是构建规则，它会告诉 Bazel 如何基于一组源文件或其他依赖项构建中间或最终软件输出。Bazel 提供了两个构建规则（android_library 和 android_binary），可用于构建 Android 应用。

在本教程中，您将首先使用 android_library 规则告知 Bazel 从应用源代码和资源文件构建 Android 库模块。然后，您将使用 android_binary 规则告知 Bazel 如何构建 Android 应用软件包。

在 src/main/java/com/example/bazel 目录中创建一个新的 BUILD 文件，并声明一个新的 android_library 目标：

src/main/java/com/example/bazel/BUILD：

package(
    default_visibility = ["//src:__subpackages__"],
)

android_library(
    name = "greeter_activity",
    srcs = [
        "Greeter.java",
        "MainActivity.java",
    ],
    manifest = "AndroidManifest.xml",
    resource_files = glob(["res/**"]),
)

android_library build 规则包含一组属性，用于指定 Bazel 从源文件构建库模块所需的信息。另请注意，规则的名称为 greeter_activity。您将在 android_binary 规则中使用此名称作为依赖项来引用该规则。

添加 android_binary 规则

android_binary 规则会为您的应用构建 Android 应用软件包 (.apk 文件)。

在 src/main/ 目录中创建一个新的 BUILD 文件，并声明一个新的 android_binary 目标：

src/main/BUILD：

android_binary(
    name = "app",
    manifest = "AndroidManifest.xml",
    deps = ["//src/main/java/com/example/bazel:greeter_activity"],
)

在这里，deps 属性引用您添加到上述 BUILD 文件中的 greeter_activity 规则的输出。这意味着，当 Bazel 构建此规则的输出时，它会先检查 greeter_activity 库规则的输出是否已构建且是最新的。如果没有，Bazel 会构建它，然后使用该输出构建应用软件包文件。

现在，保存并关闭该文件。

构建应用

尝试构建应用吧！运行以下命令以构建 android_binary 目标：

bazel build //src/main:app

build 子命令会指示 Bazel 构建后续的目标。目标是指定为 BUILD 文件中的 build 规则的名称，以及相对于工作区目录的软件包路径。在此示例中，目标为 app，软件包路径为 //src/main/。

请注意，您有时可以省略软件包路径或目标名称，具体取决于命令行中的当前工作目录和目标的名称。如需详细了解目标标签和路径，请参阅标签。

Bazel 将开始构建示例应用。在构建过程中，其输出将类似于以下内容：

INFO: Analysed target //src/main:app (0 packages loaded, 0 targets configured).
INFO: Found 1 target...
Target //src/main:app up-to-date:
  bazel-bin/src/main/app_deploy.jar
  bazel-bin/src/main/app_unsigned.apk
  bazel-bin/src/main/app.apk

找到构建输出

Bazel 会将中间和最终构建操作的输出放入一组按用户和工作区划分的输出目录中。这些目录是从项目目录顶层的以下位置符号连接的，其中 WORKSPACE 是：

• bazel-bin 存储二进制可执行文件和其他可运行 build 输出
• bazel-genfiles 存储由 Bazel 规则生成的中间源文件
• bazel-out 存储其他类型的 build 输出

Bazel 会将使用 android_binary 规则生成的 Android .apk 文件存储在 bazel-bin/src/main 目录中，其中子目录名称 src/main 派生自 Bazel 软件包的名称。

在命令提示符中，列出此目录的内容并找到 app.apk 文件：

运行应用

现在，您可以使用 bazel mobile-install 命令从命令行将应用部署到已连接的 Android 设备或模拟器。此命令使用 Android 调试桥 (adb) 与设备通信。在部署之前，您必须按照 Android 调试桥中的说明将设备设置为使用 adb。您也可以选择在 Android Studio 中包含的 Android 模拟器上安装应用。请确保模拟器正在运行，然后再执行以下命令。

输入以下内容：

bazel mobile-install //src/main:app

接下来，找到并启动“Bazel 教程应用”：

图 2. Bazel 教程应用。

恭喜！您刚刚安装了第一个使用 Bazel 构建的 Android 应用。

请注意，mobile-install 子命令还支持 --incremental 标志，该标志可用于仅部署自上次部署以来发生更改的应用部分。

它还支持 --start_app 标志，以便在安装应用后立即启动应用。

深入阅读

如需了解详情，请参阅以下页面：

• 在 GitHub 上提交问题
• 详细了解 mobile-install
• 使用 rules_jvm_external 从 Maven 仓库集成 AppCompat、Guava 和 JUnit 等外部依赖项
• 使用 robolectric-bazel 集成运行 Robolectric 测试。
• 使用 Android 插桩测试测试应用
• 使用 NDK 将 C 和 C++ 代码集成到 Android 应用中
• 查看以下各类的更多 Bazel 示例项目：
  • Kotlin 应用
  • Robolectric 测试
  • Espresso 测试

祝您构建顺利！