กรณีการใช้งานทั่วไปของ C++ เกี่ยวกับการสร้าง

รายงานปัญหา ดูแหล่งที่มา ตอนกลางคืน · 7.4 ที่ใช้เวลาเพียง 2 นาที 7.3 · 7.2 · 7.1 · 7.0 · 6.5

ในที่นี้คุณจะพบกับกรณีการใช้งานที่พบบ่อยที่สุดบางส่วนสำหรับการสร้างโปรเจ็กต์ C++ กับ Bazel เริ่มต้นสร้าง C++ หากยังไม่ได้ทำ ด้วย Bazel ด้วยการดูบทแนะนำจนจบ ข้อมูลเบื้องต้นเกี่ยวกับ Bazel: สร้างโครงการ C++

สำหรับข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs โปรดดู cc_library

การรวมหลายไฟล์ไว้ในเป้าหมาย

คุณสามารถรวมหลายไฟล์ไว้ในเป้าหมายเดียวได้ด้วย glob เช่น

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ยกเว้นไดเรกทอรีย่อย)

การใช้ทรานซิทีฟประกอบด้วย

หากไฟล์มีส่วนหัว กฎใดก็ตามที่มีไฟล์นั้นเป็นแหล่งที่มา (กล่าวคือ การมีไฟล์นั้นในแอตทริบิวต์ srcs, hdrs หรือ textual_hdrs) ควร ขึ้นอยู่กับกฎไลบรารีของส่วนหัวที่รวม ในทางกลับกัน คุณต้องระบุเฉพาะการขึ้นต่อกันโดยตรงเท่านั้น ตัวอย่างเช่น สมมติว่า sandwich.h รวม bread.h และ bread.h รวม flour.h sandwich.h ไม่รวม flour.h (ใครอยากได้แป้งในแซนด์วิช) ดังนั้น BUILD ไฟล์จะมีลักษณะดังนี้

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ในส่วนนี้ ไลบรารี sandwich จะขึ้นอยู่กับไลบรารี bread ซึ่งอ้างอิง ในไลบรารี flour

การเพิ่มเส้นทางที่รวม

บางครั้งคุณไม่สามารถ (หรือไม่ต้องการ) กำหนดเส้นทางรวมที่รูทที่รูทของพื้นที่ทำงาน ไลบรารีที่มีอยู่อาจมีไดเรกทอรี "รวม" ที่ไม่มีอยู่แล้ว ตรงกับเส้นทางในพื้นที่ทำงาน ตัวอย่างเช่น สมมติว่าคุณมีโครงสร้างไดเรกทอรีดังต่อไปนี้

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel จะคาดหวังว่า some_lib.h จะรวมอยู่ใน legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc มี "some_lib.h" หากต้องการให้เส้นทางรวมนั้นถูกต้อง legacy/some_lib/BUILD จะต้องระบุว่าไดเรกทอรี some_lib/include เป็นไดเรกทอรีรวม

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ซึ่งมีประโยชน์อย่างยิ่งสำหรับทรัพยากร Dependency ภายนอก เช่น ไฟล์ส่วนหัว ต้องรวมกับคำนำหน้า /

รวมถึงไลบรารีภายนอก

สมมติว่าคุณใช้ Google Test คุณจะใช้ฟังก์ชันที่เก็บรายการใดรายการหนึ่งในไฟล์ WORKSPACE เพื่อทำสิ่งต่อไปนี้ได้ ดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บของคุณ:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

จากนั้นสร้าง gtest.BUILD ซึ่งเป็นไฟล์ BUILD ที่ใช้คอมไพล์ Google Test Google Test มีความ "พิเศษ" หลายอย่าง ข้อกำหนดที่ใช้กฎ cc_library ซับซ้อนมากขึ้น

  • อื่นๆ googletest-release-1.10.0/src/gtest-all.cc #include ไฟล์ใน googletest-release-1.10.0/src/: ให้ยกเว้นไฟล์ใน คอมไพล์เพื่อป้องกันข้อผิดพลาดของลิงก์หากมีสัญลักษณ์ที่ซ้ำกัน

  • โดยใช้ไฟล์ส่วนหัวที่สัมพันธ์กับ ไดเรกทอรี googletest-release-1.10.0/include/ ("gtest/gtest.h") คุณต้องดำเนินการต่อไปนี้ ให้เพิ่มไดเรกทอรีนั้นลงในเส้นทางรวม

  • ต้องลิงก์ใน pthread ดังนั้นโปรดเพิ่มเป็น linkopt

ดังนั้นกฎสุดท้ายจึงมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ซึ่งดูค่อนข้างยุ่งเหยิงเนื่องจากทุกอย่างจะมี googletest-release-1.10.0 อยู่ข้างหน้า ซึ่งเป็นผลพลอยได้จากโครงสร้างของที่เก็บ คุณสร้างแถบสี http_archive ได้ คำนำหน้านี้ด้วยการเพิ่มแอตทริบิวต์ strip_prefix:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD จะมีหน้าตาแบบนี้

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ตอนนี้กฎ cc_ จะอิงตาม @gtest//:main ได้

การเขียนและทำการทดสอบ C++

เช่น คุณอาจสร้าง ./test/hello-test.cc ทดสอบ เช่น

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

จากนั้นสร้างไฟล์ ./test/BUILD ไฟล์สำหรับการทดสอบ

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

หากต้องการให้ hello-test เห็นhello-greet คุณต้องเพิ่ม "//test:__pkg__", ไปยังแอตทริบิวต์ visibility ใน ./main/BUILD

ตอนนี้คุณใช้ bazel test เพื่อเรียกใช้การทดสอบได้แล้ว

bazel test test:hello-test

ซึ่งจะให้ผลลัพธ์ดังนี้

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

การเพิ่มทรัพยากร Dependency ในไลบรารีที่คอมไพล์ไว้ล่วงหน้า

หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (เช่น ส่วนหัวและไฟล์ .so) ให้ใส่ไว้ในกฎ cc_library ดังนี้

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

วิธีนี้จะทำให้เป้าหมาย C++ อื่นๆ ในพื้นที่ทำงานขึ้นอยู่กับกฎนี้