यहां आपको Bazel के साथ C++ प्रोजेक्ट बनाने के, सबसे आम इस्तेमाल के कुछ उदाहरण मिलेंगे. अगर आपने अब तक ऐसा नहीं किया है, तो ट्यूटोरियल पूरा करके Bazel के साथ C++ प्रोजेक्ट बनाना शुरू करें Bzel के बारे में जानकारी: C++ प्रोजेक्ट बनाएं.
cc_library और hdrs हेडर फ़ाइलों के बारे में जानकारी पाने के लिए, cc_library देखें.
किसी टारगेट में कई फ़ाइलें शामिल करना
ग्लोब की मदद से, एक टारगेट में कई फ़ाइलें शामिल की जा सकती हैं. उदाहरण के लिए:
cc_library(
name = "build-all-the-files",
srcs = glob(["*.cc"]),
hdrs = glob(["*.h"]),
)
इस टारगेट का इस्तेमाल करके, Bazel उसी डायरेक्ट्री में मिलने वाली सभी .cc
और .h
फ़ाइलें
बनाएगा जो इस टारगेट वाली BUILD
फ़ाइल में मौजूद हैं.
इनमें सबडायरेक्ट्री शामिल नहीं हैं.
ट्रांज़िटिव का इस्तेमाल करने में शामिल है
अगर किसी फ़ाइल में हेडर है, तो सोर्स के रूप में उस फ़ाइल वाला कोई भी नियम (यानी कि उस फ़ाइल का srcs
, hdrs
या textual_hdrs
एट्रिब्यूट में) होना, शामिल किए गए हेडर की लाइब्रेरी के नियम पर निर्भर होना चाहिए. इसके उलट, सिर्फ़ डायरेक्ट डिपेंडेंसी को डिपेंडेंसी के तौर पर तय करना होता है. उदाहरण के लिए, मान लें कि
sandwich.h
में bread.h
शामिल है और bread.h
में flour.h
शामिल है. sandwich.h
में flour.h
(कौन अपने सैंडविच में आटा डालना चाहता है?) शामिल नहीं है, इसलिए BUILD
फ़ाइल ऐसी दिखेगी:
cc_library(
name = "sandwich",
srcs = ["sandwich.cc"],
hdrs = ["sandwich.h"],
deps = [":bread"],
)
cc_library(
name = "bread",
srcs = ["bread.cc"],
hdrs = ["bread.h"],
deps = [":flour"],
)
cc_library(
name = "flour",
srcs = ["flour.cc"],
hdrs = ["flour.h"],
)
यहां sandwich
लाइब्रेरी, bread
लाइब्रेरी पर निर्भर करती है, जो flour
लाइब्रेरी पर निर्भर करती है.
शामिल करने वाले पाथ जोड़े जा रहे हैं
कभी-कभी आप वर्कस्पेस रूट में मौजूद पाथ शामिल नहीं कर सकते या नहीं करना चाहते. हो सकता है कि मौजूदा लाइब्रेरी में पहले से ही एक शामिल करें डायरेक्ट्री हो जो आपके फ़ाइल फ़ोल्डर में इसके पाथ से मेल नहीं खाती हो. उदाहरण के लिए, मान लें कि आपके पास नीचे दी गई डायरेक्ट्री का स्ट्रक्चर है:
└── my-project
├── legacy
│ └── some_lib
│ ├── BUILD
│ ├── include
│ │ └── some_lib.h
│ └── some_lib.cc
└── WORKSPACE
Bazel को उम्मीद है कि some_lib.h
को
legacy/some_lib/include/some_lib.h
के तौर पर शामिल किया जाएगा, लेकिन मान लें कि some_lib.cc
में
"some_lib.h"
शामिल है. शामिल किए गए पाथ को मान्य बनाने के लिए, legacy/some_lib/BUILD
को यह बताना होगा कि some_lib/include
डायरेक्ट्री, शामिल की गई डायरेक्ट्री है:
cc_library(
name = "some_lib",
srcs = ["some_lib.cc"],
hdrs = ["include/some_lib.h"],
copts = ["-Ilegacy/some_lib/include"],
)
यह खास तौर पर बाहरी डिपेंडेंसी के लिए फ़ायदेमंद होता है, क्योंकि उनकी हेडर फ़ाइलें
/
प्रीफ़िक्स के साथ शामिल होनी चाहिए.
इसमें बाहरी लाइब्रेरी शामिल हैं
मान लें कि Google टेस्ट का इस्तेमाल किया जा रहा है.
Google Test को डाउनलोड करने और उसे अपने डेटा स्टोर करने की जगह में उपलब्ध कराने के लिए, WORKSPACE
फ़ाइल में रिपॉज़िटरी फ़ंक्शन में से किसी एक का इस्तेमाल किया जा सकता है:
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
)
इसके बाद, gtest.BUILD
बनाएं. यह एक BUILD
फ़ाइल है, जिसका इस्तेमाल Google टेस्ट को कंपाइल करने में किया जाता है.
Google टेस्ट में कई "खास" ज़रूरी शर्तें हैं, जो इसके cc_library
नियम को
और जटिल बनाती हैं:
googletest-release-1.10.0/src/gtest-all.cc
googletest-release-1.10.0/src/
में मौजूद अन्य सभी#include
फ़ाइलें: डुप्लीकेट सिंबल के लिए लिंक की गड़बड़ियों से बचने के लिए इसे कंपाइल से बाहर रखें.यह उन हेडर फ़ाइलों का इस्तेमाल करता है जो
googletest-release-1.10.0/include/
डायरेक्ट्री ("gtest/gtest.h"
) से जुड़ी होती हैं. इसलिए, आपको उस डायरेक्ट्री को शामिल किए गए पाथ में जोड़ना होगा.इसे
pthread
से लिंक करना होगा, इसलिए इसेlinkopt
के तौर पर जोड़ें.
इसलिए, फ़ाइनल नियम ऐसा दिखता है:
cc_library(
name = "main",
srcs = glob(
["googletest-release-1.10.0/src/*.cc"],
exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
),
hdrs = glob([
"googletest-release-1.10.0/include/**/*.h",
"googletest-release-1.10.0/src/*.h"
]),
copts = [
"-Iexternal/gtest/googletest-release-1.10.0/include",
"-Iexternal/gtest/googletest-release-1.10.0"
],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
यह थोड़ा मुश्किल है: हर चीज़ के साथ googletest-release-1.10.0
जोड़ा गया है,
वह भी संग्रह के स्ट्रक्चर के बायप्रॉडक्ट. strip_prefix
एट्रिब्यूट जोड़कर, इस प्रीफ़िक्स
से http_archive
स्ट्रिप बनाई जा सकती है:
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
strip_prefix = "googletest-release-1.10.0",
)
तो gtest.BUILD
ऐसा दिखेगा:
cc_library(
name = "main",
srcs = glob(
["src/*.cc"],
exclude = ["src/gtest-all.cc"]
),
hdrs = glob([
"include/**/*.h",
"src/*.h"
]),
copts = ["-Iexternal/gtest/include"],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
अब cc_
नियम @gtest//:main
पर निर्भर हो सकते हैं.
C++ टेस्ट लिखना और चलाना
उदाहरण के लिए, आप एक टेस्ट ./test/hello-test.cc
बना सकते हैं, जैसे:
#include "gtest/gtest.h"
#include "main/hello-greet.h"
TEST(HelloTest, GetGreet) {
EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}
इसके बाद, अपनी जांच के लिए ./test/BUILD
फ़ाइल बनाएं:
cc_test(
name = "hello-test",
srcs = ["hello-test.cc"],
copts = ["-Iexternal/gtest/include"],
deps = [
"@gtest//:main",
"//main:hello-greet",
],
)
hello-test
को hello-greet
दिखाने के लिए, आपको ./main/BUILD
के visibility
एट्रिब्यूट में "//test:__pkg__",
जोड़ना होगा.
अब जांच करने के लिए, bazel test
का इस्तेमाल किया जा सकता है.
bazel test test:hello-test
इससे यह आउटपुट मिलता है:
INFO: Found 1 test target...
Target //test:hello-test up-to-date:
bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s
Executed 1 out of 1 tests: 1 test passes.
पहले से कंपाइल की गई लाइब्रेरी पर डिपेंडेंसी जोड़ना
अगर आपको किसी ऐसी लाइब्रेरी का इस्तेमाल करना है जिसका सिर्फ़ कंपाइल किया गया वर्शन (उदाहरण के लिए, हेडर और .so
फ़ाइल) है, तो उसे cc_library
नियम में शामिल करें:
cc_library(
name = "mylib",
srcs = ["mylib.so"],
hdrs = ["mylib.h"],
)
इस तरह, आपके फ़ाइल फ़ोल्डर के अन्य C++ टारगेट इस नियम पर निर्भर हो सकते हैं.