तारीख सेव करें: BazelCon 2023, 24 से 25 अक्टूबर तक Google म्यूनिख में होगा! रजिस्ट्रेशन अब शुरू हो गया है! ज़्यादा जानें

इस पेज का अनुवाद Cloud Translation API से किया गया है.

Switch to English

सामान्य C++ बिल्ड यूज़ केस

किसी समस्या की शिकायत करें स्रोत देखें

यहां आपको Bazel के साथ C++ प्रोजेक्ट बनाने के कुछ सबसे सामान्य इस्तेमाल के उदाहरण मिलेंगे. अगर आपने अभी तक ऐसा नहीं किया है, तो ट्यूटोरियल पूरा करके Bzel के साथ C++ प्रोजेक्ट बनाना शुरू करें Bzel का परिचय: एक C++ प्रोजेक्ट बनाएं.

cc_library और hdrs हेडर फ़ाइलों के बारे में जानकारी के लिए, cc_library देखें.

किसी टारगेट में एक से ज़्यादा फ़ाइलें शामिल करना

आप ग्लोब के साथ एक ही टारगेट में कई फ़ाइलें शामिल कर सकते हैं. उदाहरण के लिए :

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

इस टारगेट के साथ, बेज़ल उन .cc और .h सभी फ़ाइलों को BUILD फ़ाइल में बनाएगी जिनमें यह टारगेट शामिल है (इसमें सबडायरेक्ट्री शामिल नहीं हैं).

स्थायी लेन-देन का इस्तेमाल करना

अगर किसी फ़ाइल में हेडर है, तो उस फ़ाइल के स्रोत के तौर पर मौजूद कोई भी नियम (यानी, उस फ़ाइल को hdrs, textual_hdrs या srcs एट्रिब्यूट में शामिल करना) हेडर के लाइब्रेरी के नियम पर निर्भर होना चाहिए. वहीं, डिपेंडेंसी सीधे तौर पर डिपेंडेंसी के तौर पर दर्ज होनी चाहिए. उदाहरण के लिए, मान लें कि sandwich.h में bread.h शामिल है और bread.h में flour.h शामिल है. sandwich.h में flour.h शामिल नहीं है (जिसे अपने सैंडविच में आटा चाहिए?), इसलिए BUILD फ़ाइल ऐसी दिखेगी:

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

यहां, sandwich लाइब्रेरी bread लाइब्रेरी पर निर्भर करती है, जो flour लाइब्रेरी पर निर्भर करती है.

शामिल किए गए पाथ जोड़ना

कभी-कभी फ़ाइल रूट में, पाथ शामिल नहीं किए जा सकते या रूट नहीं किए जा सकते. हो सकता है कि मौजूदा लाइब्रेरी में कोई ऐसी डायरेक्ट्री शामिल हो जो आपके फ़ाइल फ़ोल्डर में मौजूद पाथ से मैच न करती हो. उदाहरण के लिए, मान लें कि आपके पास डायरेक्ट्री का स्ट्रक्चर है:

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel में some_lib.h को legacy/some_lib/include/some_lib.h के तौर पर शामिल किए जाने की उम्मीद है, लेकिन मान लें कि some_lib.cc में "some_lib.h" शामिल है. शामिल पाथ को मान्य बनाने के लिए, legacy/some_lib/BUILD को यह बताना होगा कि some_lib/include डायरेक्ट्री, शामिल की गई डायरेक्ट्री है:

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

यह खास तौर पर बाहरी डिपेंडेंसी के लिए फ़ायदेमंद है, क्योंकि हेडर की फ़ाइलों को / प्रीफ़िक्स के साथ शामिल करना ज़रूरी है.

बाहरी लाइब्रेरी शामिल हैं

मान लें कि Google टेस्ट का इस्तेमाल किया जा रहा हो. Google फ़ाइल डाउनलोड करने और उसे अपने रिपॉज़िटरी में उपलब्ध कराने के लिए, WORKSPACE फ़ाइल में किसी एक रिपॉज़िटरी फ़ंक्शन का इस्तेमाल किया जा सकता है:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

इसके बाद, gtest.BUILD एक BUILD फ़ाइल बनाएं, जिसका इस्तेमाल Google टेस्ट को कंपाइल करने में किया जाता है. Google टेस्ट की कुछ "खास" शर्तें हैं, जो cc_library के नियम को और मुश्किल बनाती हैं:

googletest-release-1.10.0/src/gtest-all.cc #include, googletest-release-1.10.0/src/ में मौजूद दूसरी सभी फ़ाइलें: डुप्लीकेट के लिए, लिंक की गड़बड़ियों से बचने के लिए, कंपाइल से इसे बाहर कर दें.
इसमें उन डायरेक्ट्री फ़ाइलों का इस्तेमाल होता है जो googletest-release-1.10.0/include/ डायरेक्ट्री ("gtest/gtest.h") से जुड़ी होती हैं. इसलिए, आपको इस डायरेक्ट्री को शामिल किए गए पाथ से जोड़ना होगा.
इसे pthread में जोड़ना होगा, इसलिए इसे linkopt के तौर पर जोड़ें.

इसलिए अंतिम नियम कुछ इस तरह दिखेगा:

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

यह कुछ हद तक गड़बड़ है: इसमें हर चीज़ के शुरू में googletest-release-1.10.0 का इस्तेमाल किया गया है. strip_prefix एट्रिब्यूट जोड़कर, इस प्रीफ़िक्स को http_archiveस्ट्रिप किया जा सकता है:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

तो, gtest.BUILD कुछ ऐसा दिखेगा:

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

cc_ के नियम, @gtest//:main पर निर्भर हो सकते हैं.

C++ टेस्ट लिखना और चलाना

उदाहरण के लिए, आप एक टेस्ट ./test/hello-test.cc बना सकते हैं:

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

इसके बाद, अपने टेस्ट के लिए ./test/BUILD फ़ाइल बनाएं:

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet को hello-test में दिखाने के लिए, आपको ./main/BUILD की visibility विशेषता में "//test:__pkg__", जोड़ना होगा.

अब bazel test का इस्तेमाल करके, जांच की जा सकती है.

bazel test test:hello-test

इससे यह आउटपुट मिलता है:

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

पहले से कंपाइल की गई लाइब्रेरी पर डिपेंडेंसी जोड़ना

अगर आपको किसी ऐसी लाइब्रेरी का इस्तेमाल करना है जिसका सिर्फ़ एक कंपाइल किया गया वर्शन है (उदाहरण के लिए, हेडर और .so फ़ाइल), तो उसे cc_library नियम में रैप करें:

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

इस तरह, आपके फ़ाइल फ़ोल्डर में दूसरे C++ टारगेट पर निर्भर हो सकते हैं.