這裡會說明使用 Bazel 建構 C++ 專案的常見用途。如果您尚未使用 Bazel 建構 C++ 專案，請完成 Bazel 簡介：建構 C++ 專案教學課程。
如需 cc_library 和 hdrs 標頭檔案的相關資訊，請參閱 cc_library。
在目標中加入多個檔案
您可以使用 glob 在單一目標中加入多個檔案。例如：
cc_library(
name = "build-all-the-files",
srcs = glob(["*.cc"]),
hdrs = glob(["*.h"]),
)
使用這個目標時，Bazel 會在與包含此目標的 BUILD 檔案相同的目錄中找到所有 .cc 和 .h 檔案 (不含子目錄)。
使用遞移包括
如果檔案包含標頭，則任何具有該檔案做為來源的規則 (也就是將檔案放在 srcs、hdrs 或 textual_hdrs 屬性中) 都應依附於所含標頭的程式庫規則。反之，只有直接依附元件需要指定為依附元件。舉例來說，假設 sandwich.h 包含 bread.h，而 bread.h 包含 flour.h。sandwich.h 不包含 flour.h (誰想要吃三明治？)，因此 BUILD 檔案看起來會像這樣：
cc_library(
name = "sandwich",
srcs = ["sandwich.cc"],
hdrs = ["sandwich.h"],
deps = [":bread"],
)
cc_library(
name = "bread",
srcs = ["bread.cc"],
hdrs = ["bread.h"],
deps = [":flour"],
)
cc_library(
name = "flour",
srcs = ["flour.cc"],
hdrs = ["flour.h"],
)
這裡，sandwich 程式庫取決於依附 flour 程式庫的 bread 程式庫。
新增包含路徑
有時候，您可能無法 (或不想) 包含工作區根目錄的路徑。現有程式庫的包含目錄可能與工作區中的路徑不符。舉例來說，假設您有下列目錄結構：
└── my-project
├── legacy
│ └── some_lib
│ ├── BUILD
│ ├── include
│ │ └── some_lib.h
│ └── some_lib.cc
└── WORKSPACE
Bazel 會將 some_lib.h 新增為 legacy/some_lib/include/some_lib.h，但假設 some_lib.cc 包含 "some_lib.h"。如要讓包含路徑有效，legacy/some_lib/BUILD 必須指定 some_lib/include 目錄為包含目錄：
cc_library(
name = "some_lib",
srcs = ["some_lib.cc"],
hdrs = ["include/some_lib.h"],
copts = ["-Ilegacy/some_lib/include"],
)
這對於外部依附元件來說特別實用，因為其標頭檔案必須使用 / 前置字串。
納入外部程式庫
假設您使用的是 Google Test {: .external}。您可以使用 WORKSPACE 檔案中的其中一個存放區函式下載 Google 測試，並在存放區中提供：
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
)
然後建立 gtest.BUILD，這是用來編譯 Google 測試的 BUILD 檔案。Google 測試有幾個「特殊」要求，因此讓 cc_library 規則更複雜：
googletest-release-1.10.0/googletest/src/gtest-all.cc#include會對googletest-release-1.10.0/googletest/src/中的所有其他檔案進行#include：從編譯中排除，以防止出現重複符號的連結錯誤。它使用與
googletest-release-1.10.0/googletest/include/目錄 ("gtest/gtest.h") 相關的標頭檔案，因此您必須將該目錄新增至 include 路徑中。需要在
pthread中建立連結，因此將其新增為linkopt。
最終的規則看起來會像這樣：
cc_library(
name = "main",
srcs = glob(
["googletest-release-1.10.0/googletest/src/*.cc"],
exclude = ["googletest-release-1.10.0/googletest/src/gtest-all.cc"]
),
hdrs = glob([
"googletest-release-1.10.0/googletest/include/**/*.h",
"googletest-release-1.10.0/googletest/src/*.h"
]),
copts = [
"-Iexternal/gtest/googletest-release-1.10.0/googletest/include",
"-Iexternal/gtest/googletest-release-1.10.0/googletest"
],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
這有些雜亂無章：所有內容開頭都會加上 googletest-release-1.10.0，做為封存結構的副作用。您可以新增 strip_prefix 屬性，讓 http_archive 移除這個前置字串：
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
strip_prefix = "googletest-release-1.10.0",
)
然後 gtest.BUILD 會如下所示：
cc_library(
name = "main",
srcs = glob(
["googletest/src/*.cc"],
exclude = ["googletest/src/gtest-all.cc"]
),
hdrs = glob([
"googletest/include/**/*.h",
"googletest/src/*.h"
]),
copts = [
"-Iexternal/gtest/googletest/include",
"-Iexternal/gtest/googletest",
],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
現在 cc_ 規則可以依附於 @gtest//:main。
編寫及執行 C++ 測試
舉例來說，您可以建立 ./test/hello-test.cc 的測試，例如：
#include "gtest/gtest.h"
#include "main/hello-greet.h"
TEST(HelloTest, GetGreet) {
EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}
然後為測試建立 ./test/BUILD 檔案：
cc_test(
name = "hello-test",
srcs = ["hello-test.cc"],
copts = [
"-Iexternal/gtest/googletest/include",
"-Iexternal/gtest/googletest",
],
deps = [
"@gtest//:main",
"//main:hello-greet",
],
)
如要讓 hello-test 顯示 hello-greet，您必須在 ./main/BUILD 的 visibility 屬性中加入 "//test:__pkg__",。
您現在可以使用 bazel test 執行測試。
bazel test test:hello-test
這會產生下列輸出內容：
INFO: Found 1 test target...
Target //test:hello-test up-to-date:
bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s
Executed 1 out of 1 tests: 1 test passes.
在預先編譯的程式庫中新增依附元件
若要使用您只有已編譯版本 (例如標頭和 .so 檔案) 的程式庫，請將該程式庫納入 cc_library 規則中：
cc_library(
name = "mylib",
srcs = ["mylib.so"],
hdrs = ["mylib.h"],
)
如此一來，工作區中的其他 C++ 目標就可以依賴這項規則。