Bazel によるコードカバレッジ

Nightly · 9.0 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 7.7

Bazel には、coverage サブコマンドがあり、bazel coverage でテストできるリポジトリのコードカバレッジレポートを生成します。さまざまな言語エコシステムの特性により、特定のプロジェクトでこの機能を動作させるのは簡単ではありません。

このページでは、カバレッジレポートの作成と表示の一般的なプロセスについて説明します。また、構成がよく知られている言語については、言語固有の注意事項も記載しています。まず一般的なセクションを読み、次に特定の言語の要件について読むことをおすすめします。リモート実行のセクションもご覧ください。このセクションでは、追加の考慮事項について説明しています。

多くのカスタマイズが可能ですが、このドキュメントでは、現在最もサポートされている lcov レポートの生成と使用に焦点を当てています。

カバレッジレポートを作成する

準備

カバレッジレポートを作成する基本的なワークフローには、次のものが必要です。

テストターゲットを含む基本的なリポジトリ
言語固有のコードカバレッジツールがインストールされたツールチェーン
正しい「インストルメンテーション」構成

最初の 2 つは言語固有で、ほとんどの場合簡単ですが、 3 つ目は複雑なプロジェクトでは難しい場合があります。

この場合の「インストルメンテーション」とは、特定のターゲットに使用されるカバレッジツールを指します。Bazel では、a 特定のファイルのサブセットに対して、 --instrumentation_filter フラグを使用してこの機能を有効にできます。このフラグは、インストルメンテーションを有効にしてテストされるターゲットのフィルタを指定します。テストでインストルメンテーションを有効にするには、 --instrument_test_targets フラグが必要です。

デフォルトでは、bazel はターゲットパッケージの一致を試み、関連するフィルタを INFO メッセージとして出力します。

カバレッジを実行する

カバレッジレポートを生成するには、bazel coverage --combined_report=lcov [target] を使用します。これにより、ターゲットのテストが実行され、各ファイルの lcov 形式でカバレッジレポートが生成されます。

完了すると、bazel は生成されたすべてのカバレッジファイルを収集して 1 つにマージするアクションを実行します。このファイルは、最終的に $(bazel info output_path)/_coverage/_coverage_report.datに作成されます。

テストが失敗した場合もカバレッジレポートが生成されますが、失敗したテストは含まれません。合格したテストのみがレポートされます。

カバレッジを表示する

カバレッジレポートは、人が読めない lcov 形式でのみ出力されます。ここから、genhtml ユーティリティ（lcov プロジェクトの一部）を使用して、ウェブブラウザで表示できるレポートを生成できます。

genhtml --output genhtml "$(bazel info output_path)/_coverage/_coverage_report.dat"

Note that genhtml はソースコードも読み取り、これらのファイルで欠落しているカバレッジにアノテーションを付けます。この機能を動作させるには、bazel プロジェクトのルートで genhtmlを実行する必要があります。

結果を表示するには、index.html ファイルを genhtml ディレクトリに生成された任意のウェブブラウザで開きます。

genhtml ツールまたは lcov カバレッジ形式の詳細については、lcov プロジェクトをご覧ください。

リモート実行

リモートテスト実行で実行する場合、現在いくつかの注意点があります。

レポート結合アクションはまだリモートで実行できません。これは、Bazel がカバレッジ出力ファイルをグラフの一部と見なさないため（この問題を参照）、結合アクションの入力として正しく処理できないためです。この問題を回避するには、--strategy=CoverageReport=local を使用します。
- 注: Bazel がを試すように設定されている場合は、Bazel が戦略を解決する方法により、 --strategy=CoverageReport=local,remote のように指定する必要がある場合があります。local,remote
--remote_download_minimal などのフラグも前述の理由により使用できません。
テストが以前にキャッシュされている場合、Bazel は現在カバレッジ情報を作成できません。この問題を回避するには、 --nocache_test_resultsをカバレッジ実行に設定できますが、テスト時間が大幅に増加します。
--experimental_split_coverage_postprocessing と --experimental_fetch_all_coverage_outputs
- 通常、カバレッジはテストアクションの一部として実行されるため、デフォルトでは、リモート実行の出力としてすべてのカバレッジが返されません。これらのフラグはデフォルトをオーバーライドして、カバレッジデータを取得します。詳細については、この問題をご覧ください。

言語固有の構成

Java

Java はデフォルト構成でそのまま動作します。 bazel ツールチェーンには、JUnit を含むリモート実行に必要なものがすべて含まれています。

Python

前提条件

Python でカバレッジを実行するには、いくつかの前提条件があります。

b01c859 を含む bazel バイナリ。 Bazel > 3.0 である必要があります。
coverage.py の変更バージョン。

変更された coverage.py を使用する

これを行う方法の 1 つは rules_python を使用することです。これにより、 requirements.txt ファイルを使用できます。ファイルにリストされている要件は、 pip_install リポジトリルールを使用して bazel ターゲットとして作成されます。

requirements.txt には次のエントリが必要です。

git+https://github.com/ulfjack/coveragepy.git@lcov-support

rules_python、pip_install、requirements.txt ファイルは、WORKSPACE ファイルで次のように使用する必要があります。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_python",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.5.0/rules_python-0.5.0.tar.gz",
    sha256 = "cd6730ed53a002c56ce4e2f396ba3b3be262fd7cb68339f0377a45e8227fe332",
)

load("@rules_python//python:pip.bzl", "pip_install")

pip_install(
   name = "python_deps",
   requirements = "//:requirements.txt",
)

coverage.py 要件は、テストターゲットで次の設定を BUILD ファイルに行うことで使用できます。

load("@python_deps//:requirements.bzl", "entry_point")

alias(
    name = "python_coverage_tools",
    actual = entry_point("coverage"),
)

py_test(
    name = "test",
    srcs = ["test.py"],
    env = {
        "PYTHON_COVERAGE": "$(location :python_coverage_tools)",
    },
    deps = [
        ":main",
        ":python_coverage_tools",
    ],
)

密閉型の Python ツールチェーンを使用している場合は、すべての py_test ターゲットにカバレッジ依存関係を追加する代わりに、カバレッジツールをツールチェーン構成に追加できます。

pip_install ルールは Python ツールチェーンに依存するため、coverage モジュールの取得には使用できません。代わりに、WORKSPACE に追加します（例:）。

http_archive(
    name = "coverage_linux_x86_64"",
    build_file_content = """
py_library(
    name = "coverage",
    srcs = ["coverage/__main__.py"],
    data = glob(["coverage/*", "coverage/**/*.py"]),
    visibility = ["//visibility:public"],
)
""",
    sha256 = "84631e81dd053e8a0d4967cedab6db94345f1c36107c71698f746cb2636c63e3",
    type = "zip",
    urls = [
        "https://files.pythonhosted.org/packages/74/0d/0f3c522312fd27c32e1abe2fb5c323b583a5c108daf2c26d6e8dfdd5a105/coverage-6.4.1-cp39-cp39-manylinux_2_5_x86_64.manylinux1_x86_64.manylinux_2_17_x86_64.manylinux2014_x86_64.whl",
    ],
)

次に、Python ツールチェーンを構成します（例:）。

py_runtime(
    name = "py3_runtime_linux_x86_64",
    coverage_tool = "@coverage_linux_x86_64//:coverage",
    files = ["@python3_9_x86_64-unknown-linux-gnu//:files"],
    interpreter = "@python3_9_x86_64-unknown-linux-gnu//:bin/python3",
    python_version = "PY3",
)

py_runtime_pair(
    name = "python_runtimes_linux_x86_64",
    py2_runtime = None,
    py3_runtime = ":py3_runtime_linux_x86_64",
)

toolchain(
    name = "python_toolchain_linux_x86_64",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":python_runtimes_linux_x86_64",
    toolchain_type = "@bazel_tools//tools/python:toolchain_type",
)