実行グループ

問題を報告するソースを表示 Nightly · 8.0 . 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

実行グループを使用すると、1 つのターゲット内で複数の実行プラットフォームを使用できます。各実行グループには独自のツールチェーン依存関係があり、独自のツールチェーンの解決を行います。

背景

実行グループを使用すると、ルール作成者はアクションのセットを定義できます。各アクションの実行プラットフォームは異なる場合があります。複数の実行プラットフォームを使用すると、リモート（Linux）ワーカーで iOS アプリをコンパイルしてから、ローカルの Mac ワーカーでリンクまたはコード署名するなど、アクションを異なる方法で実行できます。

アクションのグループを定義できると、アクションを指定するプロキシとしてアクションの頭文字を使用する必要がなくなります。メモネークは一意であるとは限らず、参照できるアクションは 1 つだけです。これは、負荷の少ないタスクに過剰に割り当てることなく、特定のメモリと処理負荷の高いアクション（C++ ビルドでのリンクなど）に追加のリソースを割り当てる場合に特に役立ちます。

実行グループの定義

ルールの作成者は、ルールの定義時に一連の実行グループを宣言できます。ルール作成者は、各実行グループで、その実行グループの実行プラットフォームの選択に必要なすべてのものを指定できます。つまり、exec_compatible_with で制約を指定したり、toolchain でツールチェーンタイプを指定したりできます。

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        “link”: exec_group(
            exec_compatible_with = [ "@platforms//os:linux" ]
            toolchains = ["//foo:toolchain_type"],
        ),
        “test”: exec_group(
            toolchains = ["//foo_tools:toolchain_type"],
        ),
    },
    attrs = {
        "_compiler": attr.label(cfg = config.exec("link"))
    },
)

上のコードスニペットでは、ツールの依存関係で cfg 属性パラメータと config モジュールを使用して、実行グループの遷移を指定することもできます。このモジュールは、依存関係をビルドする exec グループの名前である単一の文字列パラメータを取る exec 関数を公開します。

ネイティブルールと同様に、test 実行グループは Starlark テストルールにデフォルトで存在します。

実行グループの継承

新しい実行グループは、独自の制約とツールチェーンを定義するだけでなく、copy_from_rule = True パラメータを渡すことで、ルールのデフォルトの実行グループから継承することを宣言できます。copy_from_rule を true に設定し、exec_compatible_with または toolchains も渡すとエラーになります。

デフォルトの実行グループから継承する実行グループは、デフォルトから制約、ツールチェーン、実行プロパティをコピーします。これには、ルール自体で指定されたものだけでなく、ターゲットレベルで設定された制約と実行プロパティが含まれます。つまり、次のようにします。

# foo.bzl
my_rule = rule(
    _impl,
    exec_groups = {
        “copied”: exec_group(
            copy_from_rule = True,
            # This will inherit exec_compatible_with and toolchains.
            # Setting them here directly would be an error, however.
        ),
    },
    toolchains = ["//foo_tools:toolchain_type"],
    exec_compatible_with = ["@platforms//os:linux"],
)

# BUILD

my_rule(
    name = "demo",
    exec_compatible_with = [":local_constraint"],
)

構成されたターゲット demo の copied 実行グループには、次のすべてが含まれます。 - //fool_tools:toolchain_type - @platforms//os:linux - :local_constraint

実行グループへのアクセス

ルールの実装で、実行グループの実行プラットフォームでアクションを実行するように宣言できます。これを行うには、アクション生成メソッド（特に ctx.actions.run と ctx.actions.run_shell）の exec_group パラメータを使用します。

# foo.bzl
def _impl(ctx):
  ctx.actions.run(
     inputs = [ctx.attr._some_tool, ctx.srcs[0]]
     exec_group = "compile",
     # ...
  )

ルール作成者は、ターゲットの解決済みツールチェーンにアクセスするのと同様に、実行グループの解決済みツールチェーンにもアクセスできるようになります。

# foo.bzl
def _impl(ctx):
  foo_info = ctx.exec_groups["link"].toolchains["//foo:toolchain_type"].fooinfo
  ctx.actions.run(
     inputs = [foo_info, ctx.srcs[0]]
     exec_group = "link",
     # ...
  )

実行グループを使用して実行プロパティを設定する

実行グループは、すべてのルールに存在する exec_properties 属性と統合されており、ターゲットライターはプロパティの文字列辞書を指定して、実行メカニズムに渡すことができます。たとえば、ターゲットにプロパティ（メモリなど）を設定して、特定のアクションにメモリ割り当てを増やす場合は、実行グループ拡張キーを使用して exec_properties エントリを記述します。次に例を示します。

# BUILD
my_rule(
    name = 'my_target',
    exec_properties = {
        'mem': '12g',
        'link.mem': '16g'
    }
    …
)

exec_group = "link" を含むすべてのアクションでは、exec プロパティディクショナリが {"mem": "16g"} として表示されます。ご覧のとおり、実行グループ単位の設定はターゲット単位の設定をオーバーライドします。

ネイティブルールの実行グループ

ネイティブルールで定義されたアクションには、次の実行グループを使用できます。

test: テストランナーのアクション。
cpp_link: C++ リンクアクション。

exec グループを作成して exec プロパティを設定する

実行グループを使用して特定のアクションに異なる実行プロパティを指定したいが、ルールとは異なるツールチェーンや制約は実際には必要ない場合もあります。このような場合は、copy_from_rule パラメータを使用して exec グループを作成できます。

# foo.bzl

# Creating an exec group with `copy_from_rule=True` is the same as explicitly
# setting the exec group's toolchains and constraints to the same values as the
# rule's respective parameters.
my_rule = rule(
    _impl,
    exec_compatible_with = ["@platforms//os:linux"],
    toolchains = ["//foo:toolchain_type"],
    exec_groups = {
        # The following two groups have the same toolchains and constraints:
        “foo”: exec_group(copy_from_rule = True),
        "bar": exec_group(
            exec_compatible_with = ["@platforms//os:linux"],
            toolchains = ["//foo:toolchain_type"],
        ),
    },
)

#

実行グループとプラットフォーム実行プロパティ

プラットフォームターゲットで任意の実行グループに exec_properties を定義できます（ターゲットに直接設定された exec_properties とは異なり、未知の実行グループのプロパティは拒否されます）。ターゲットは、デフォルトの実行グループとその他の関連する実行グループに影響する実行プラットフォームの exec_properties を継承します。

たとえば、C++ テストの実行にリソースが必要だが、コンパイルやリンクには必要ない場合、次のようにモデル化できます。

constraint_setting(name = "resource")
constraint_value(name = "has_resource", constraint_setting = ":resource")

platform(
    name = "platform_with_resource",
    constraint_values = [":has_resource"],
    exec_properties = {
        "test.resource": "...",
    },
)

cc_test(
    name = "my_test",
    srcs = ["my_test.cc"],
    exec_compatible_with = [":has_resource"],
)

ターゲットで直接定義された exec_properties は、実行プラットフォームから継承された exec_properties よりも優先されます。