टेस्ट करना

Bazel में Starlark कोड की जांच करने के कई तरीके हैं. इस पेज पर, इस्तेमाल के उदाहरण के हिसाब से, सबसे सही मौजूदा तरीके और फ़्रेमवर्क इकट्ठा किए गए हैं.

नियमों की जांच करना

Skylib में एक टेस्ट फ़्रेमवर्क है, जिसे unittest.bzl कहा जाता है. इसका इस्तेमाल, विश्लेषण के समय नियमों के व्यवहार की जांच करने के लिए किया जाता है. जैसे, उनकी कार्रवाइयां और प्रोवाइडर. ऐसे टेस्ट को "विश्लेषण टेस्ट" कहा जाता है. फ़िलहाल, नियमों के काम करने के तरीके की जांच करने के लिए, ये सबसे बेहतर विकल्प हैं.

ध्यान रखने वाली कुछ बातें:

• टेस्ट एश्योरेशन, बिल्ड में होते हैं, न कि टेस्ट रनर की अलग प्रोसेस में. टेस्ट से बनाए गए टारगेट का नाम ऐसा होना चाहिए कि वे दूसरे टेस्ट या बिल्ड के टारगेट से मेल न खाएं. टेस्ट के दौरान होने वाली गड़बड़ी को Bazel, टेस्ट में हुई गड़बड़ी के बजाय, बिल्ड में हुई गड़बड़ी के तौर पर देखता है.

• जांच के दायरे में आने वाले नियमों और जांच के दावे वाले नियमों को सेट अप करने के लिए, ज़्यादातर कोड एक जैसा होता है. यह बोइलरप्लेट, पहली बार में डराने वाली लग सकती है. ध्यान रखें कि मैक्रो का आकलन और टारगेट जनरेट करने की प्रोसेस, लोडिंग के दौरान होती है. वहीं, नियम लागू करने वाले फ़ंक्शन, विश्लेषण के दौरान ही चलते हैं.

• विश्लेषण के टेस्ट, छोटे और कम वज़न वाले होने चाहिए. विश्लेषण टेस्टिंग फ़्रेमवर्क की कुछ सुविधाएं, ज़्यादा से ज़्यादा ट्रांज़िशन डिपेंडेंसी (फ़िलहाल 500) वाले टारगेट की पुष्टि करने तक सीमित हैं. ऐसा इसलिए है, क्योंकि बड़ी संख्या में टेस्ट के साथ इन सुविधाओं का इस्तेमाल करने पर, परफ़ॉर्मेंस पर असर पड़ता है.

बुनियादी सिद्धांत यह है कि टेस्टिंग का ऐसा नियम तय किया जाए जो जांचे जा रहे नियम पर निर्भर हो. इससे टेस्टिंग रूल को, टेस्ट किए जा रहे रूल के प्रोवाइडर का ऐक्सेस मिलता है.

जांच के नियम को लागू करने वाला फ़ंक्शन, दावे करता है. अगर कोई गड़बड़ी होती है, तो fail() को कॉल करके तुरंत गड़बड़ी नहीं दिखाई जाती है. ऐसा करने पर, विश्लेषण के समय बिल्ड में गड़बड़ी ट्रिगर हो सकती है. इसके बजाय, गड़बड़ियों को जनरेट की गई स्क्रिप्ट में सेव किया जाता है, जो टेस्ट के दौरान काम नहीं करती.

यहां एक छोटा सा उदाहरण दिया गया है. इसके बाद, एक ऐसा उदाहरण दिया गया है जिसमें कार्रवाइयों की जांच की जाती है.

कम से कम उदाहरण

//mypkg/myrules.bzl:

MyInfo = provider(fields = {
    "val": "string value",
    "out": "output File",
})

def _myrule_impl(ctx):
    """Rule that just generates a file and returns a provider."""
    out = ctx.actions.declare_file(ctx.label.name + ".out")
    ctx.actions.write(out, "abc")
    return [MyInfo(val="some value", out=out)]

myrule = rule(
    implementation = _myrule_impl,
)

//mypkg/myrules_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "analysistest")
load(":myrules.bzl", "myrule", "MyInfo")

# ==== Check the provider contents ====

def _provider_contents_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    # If preferred, could pass these values as "expected" and "actual" keyword
    # arguments.
    asserts.equals(env, "some value", target_under_test[MyInfo].val)

    # If you forget to return end(), you will get an error about an analysis
    # test needing to return an instance of AnalysisTestResultInfo.
    return analysistest.end(env)

# Create the testing rule to wrap the test logic. This must be bound to a global
# variable, not called in a macro's body, since macros get evaluated at loading
# time but the rule gets evaluated later, at analysis time. Since this is a test
# rule, its name must end with "_test".
provider_contents_test = analysistest.make(_provider_contents_test_impl)

# Macro to setup the test.
def _test_provider_contents():
    # Rule under test. Be sure to tag 'manual', as this target should not be
    # built using `:all` except as a dependency of the test.
    myrule(name = "provider_contents_subject", tags = ["manual"])
    # Testing rule.
    provider_contents_test(name = "provider_contents_test",
                           target_under_test = ":provider_contents_subject")
    # Note the target_under_test attribute is how the test rule depends on
    # the real rule target.

# Entry point from the BUILD file; macro for running each test case's macro and
# declaring a test suite that wraps them together.
def myrules_test_suite(name):
    # Call all test functions and wrap their targets in a suite.
    _test_provider_contents()
    # ...

    native.test_suite(
        name = name,
        tests = [
            ":provider_contents_test",
            # ...
        ],
    )

//mypkg/BUILD:

load(":myrules.bzl", "myrule")
load(":myrules_test.bzl", "myrules_test_suite")

# Production use of the rule.
myrule(
    name = "mytarget",
)

# Call a macro that defines targets that perform the tests at analysis time,
# and that can be executed with "bazel test" to return the result.
myrules_test_suite(name = "myrules_test")

इस टेस्ट को bazel test //mypkg:myrules_test के साथ चलाया जा सकता है.

शुरुआती load() स्टेटमेंट के अलावा, फ़ाइल के दो मुख्य हिस्से होते हैं:

• टेस्ट, जिनमें से हर एक में ये शामिल होते हैं: 1) टेस्टिंग नियम के लिए विश्लेषण के समय लागू करने वाला फ़ंक्शन, 2) analysistest.make() के ज़रिए टेस्टिंग नियम का एलान, और 3) टेस्ट किए जा रहे नियम (और उसकी डिपेंडेंसी) और टेस्टिंग नियम का एलान करने के लिए, लोडिंग के समय का फ़ंक्शन (मैक्रो). अगर टेस्ट केस के बीच एश्योरमेंट नहीं बदलते हैं, तो 1) और 2) को कई टेस्ट केस के साथ शेयर किया जा सकता है.

• टेस्ट सुइट फ़ंक्शन, जो हर टेस्ट के लिए लोडिंग के समय के फ़ंक्शन को कॉल करता है. साथ ही, सभी टेस्ट को एक साथ बंडल करने के लिए test_suite टारगेट का एलान करता है.

टेस्ट के नाम को एक जैसा रखने के लिए, नाम रखने के सुझाए गए तरीके का पालन करें: foo को टेस्ट के उस हिस्से के लिए रखें जिससे पता चलता है कि टेस्ट किस चीज़ की जांच कर रहा है (ऊपर दिए गए उदाहरण में provider_contents). उदाहरण के लिए, JUnit टेस्ट मेथड का नाम testFoo होगा.

इसके बाद:

• टेस्ट और टेस्ट किए जा रहे टारगेट को जनरेट करने वाले मैक्रो का नाम _test_foo (_test_provider_contents) होना चाहिए

• इसके टेस्ट नियम का टाइप foo_test (provider_contents_test) होना चाहिए

• इस तरह के नियम के टारगेट का लेबल foo_test होना चाहिए (provider_contents_test)

• टेस्टिंग नियम के लागू करने वाले फ़ंक्शन का नाम _foo_test_impl (_provider_contents_test_impl) होना चाहिए

• जांच के दायरे में आने वाले नियमों के टारगेट और उनकी डिपेंडेंसी के लेबल के आगे foo_ (provider_contents_) होना चाहिए

ध्यान दें कि सभी टारगेट के लेबल, एक ही BUILD पैकेज के अन्य लेबल से मेल खा सकते हैं. इसलिए, टेस्ट के लिए कोई यूनीक नाम इस्तेमाल करना मददगार होता है.

गड़बड़ी की जांच

यह पुष्टि करने के लिए यह सुविधा मददगार हो सकती है कि कोई नियम, कुछ इनपुट या किसी खास स्थिति में काम नहीं करता. विश्लेषण टेस्ट फ़्रेमवर्क का इस्तेमाल करके, ऐसा किया जा सकता है:

analysistest.make की मदद से बनाए गए टेस्ट नियम में expect_failure की जानकारी होनी चाहिए:

failure_testing_test = analysistest.make(
    _failure_testing_test_impl,
    expect_failure = True,
)

टेस्ट के नियम को लागू करने पर, उस गड़बड़ी के बारे में जानकारी मिलनी चाहिए जो हुई है. खास तौर पर, गड़बड़ी का मैसेज:

def _failure_testing_test_impl(ctx):
    env = analysistest.begin(ctx)
    asserts.expect_failure(env, "This rule should never work")
    return analysistest.end(env)

यह भी पक्का करें कि जांच में शामिल आपका टारगेट, खास तौर पर 'मैन्युअल' के तौर पर टैग किया गया हो. इसके बिना, :all का इस्तेमाल करके अपने पैकेज में सभी टारगेट बनाने पर, जान-बूझकर काम न करने वाले टारगेट का बिल्ड बन जाएगा और बिल्ड में गड़बड़ी दिखेगी. 'मैन्युअल' के साथ, जांचा जा रहा आपका टारगेट सिर्फ़ तब बनेगा, जब साफ़ तौर पर बताया गया हो या किसी ऐसे टारगेट की डिपेंडेंसी के तौर पर (जैसे, आपका टेस्ट नियम):

def _test_failure():
    myrule(name = "this_should_fail", tags = ["manual"])

    failure_testing_test(name = "failure_testing_test",
                         target_under_test = ":this_should_fail")

# Then call _test_failure() in the macro which generates the test suite and add
# ":failure_testing_test" to the suite's test targets.

रजिस्टर की गई कार्रवाइयों की पुष्टि करना

आपके पास ऐसी जांचें लिखने का विकल्प है जिनमें उन कार्रवाइयों के बारे में बताया गया हो जिन्हें आपका नियम रजिस्टर करता है. उदाहरण के लिए, ctx.actions.run() का इस्तेमाल करना. ऐसा, विश्लेषण के लिए टेस्ट किए गए नियम को लागू करने वाले फ़ंक्शन में किया जा सकता है. एक उदाहरण:

def _inspect_actions_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    actions = analysistest.target_actions(env)
    asserts.equals(env, 1, len(actions))
    action_output = actions[0].outputs.to_list()[0]
    asserts.equals(
        env, target_under_test.label.name + ".out", action_output.basename)
    return analysistest.end(env)

ध्यान दें कि analysistest.target_actions(env), Action ऑब्जेक्ट की सूची दिखाता है. ये ऑब्जेक्ट, जांच के दायरे में आने वाले टारगेट से रजिस्टर की गई कार्रवाइयों को दिखाते हैं.

अलग-अलग फ़्लैग के तहत नियम के व्यवहार की पुष्टि करना

हो सकता है कि आपको यह पुष्टि करनी हो कि कुछ खास बिल्ड फ़्लैग के हिसाब से, आपका असल नियम किसी खास तरीके से काम करता है. उदाहरण के लिए, अगर कोई उपयोगकर्ता यह बताता है कि:

bazel build //mypkg:real_target -c opt

बनाम

bazel build //mypkg:real_target -c dbg

पहली नज़र में, ऐसा करने के लिए, अपनी पसंद के बिल्ड फ़्लैग का इस्तेमाल करके, टेस्ट किए जा रहे टारगेट की जांच की जा सकती है:

bazel test //mypkg:myrules_test -c opt

हालांकि, ऐसा करने पर आपके टेस्ट सुइट में एक साथ ऐसा टेस्ट शामिल करना असंभव हो जाता है जो -c opt के तहत नियम के व्यवहार की पुष्टि करता है और दूसरा टेस्ट जो -c dbg के तहत नियम के व्यवहार की पुष्टि करता है. दोनों टेस्ट एक ही बिल्ड में नहीं चल पाएंगे!

इस समस्या को हल करने के लिए, टेस्ट के नियम तय करते समय, अपनी पसंद के बिल्ड फ़्लैग तय करें:

myrule_c_opt_test = analysistest.make(
    _myrule_c_opt_test_impl,
    config_settings = {
        "//command_line_option:compilation_mode": "opt",
    },
)

आम तौर पर, टेस्ट किए जा रहे टारगेट का विश्लेषण, मौजूदा बिल्ड फ़्लैग के आधार पर किया जाता है. config_settings की वैल्यू डालने पर, कमांड लाइन के दिए गए विकल्पों की वैल्यू बदल जाती हैं. (बिना बताए गए विकल्पों की वैल्यू, असल कमांड लाइन से ही ली जाएगी).

बताई गई config_settings डिक्शनरी में, कमांड लाइन फ़्लैग के आगे एक खास प्लेसहोल्डर वैल्यू //command_line_option: होनी चाहिए, जैसा कि ऊपर दिखाया गया है.

आर्टफ़ैक्ट की पुष्टि करना

जनरेट की गई फ़ाइलें सही हैं या नहीं, यह देखने के मुख्य तरीके ये हैं:

• शेल, Python या किसी अन्य भाषा में टेस्ट स्क्रिप्ट लिखी जा सकती है. साथ ही, सही *_test नियम टाइप का टारगेट बनाया जा सकता है.

• आपको जिस तरह का टेस्ट करना है उसके लिए, किसी खास नियम का इस्तेमाल किया जा सकता है.

टेस्ट टारगेट का इस्तेमाल करना

किसी आर्टफ़ैक्ट की पुष्टि करने का सबसे आसान तरीका यह है कि आप स्क्रिप्ट लिखें और अपनी BUILD फ़ाइल में *_test टारगेट जोड़ें. आपको जिन आर्टफ़ैक्ट की जांच करनी है वे इस टारगेट की डेटा डिपेंडेंसी होनी चाहिए. अगर पुष्टि करने का आपका लॉजिक, कई टेस्ट के लिए फिर से इस्तेमाल किया जा सकता है, तो यह एक ऐसी स्क्रिप्ट होनी चाहिए जो कमांड लाइन के उन आर्ग्युमेंट को स्वीकार करती हो जिन्हें टेस्ट टारगेट के args एट्रिब्यूट से कंट्रोल किया जाता है. यहां एक उदाहरण दिया गया है, जिससे यह पुष्टि होती है कि ऊपर दिए गए myrule का आउटपुट "abc" है.

//mypkg/myrule_validator.sh:

if [ "$(cat $1)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed for each target whose artifacts are to be checked.
sh_test(
    name = "validate_mytarget",
    srcs = [":myrule_validator.sh"],
    args = ["$(location :mytarget.out)"],
    data = [":mytarget.out"],
)

कस्टम नियम का इस्तेमाल करना

शेल स्क्रिप्ट को टेंप्लेट के तौर पर लिखना, एक और मुश्किल विकल्प है. इसे नए नियम से इंस्टैंशिएट किया जाता है. इसमें ज़्यादा इनडायरेक्टिव और Starlark लॉजिक शामिल होता है, लेकिन इससे BUILD फ़ाइलें बेहतर बनती हैं. एक फ़ायदा यह भी है कि किसी भी आर्ग्युमेंट की प्रीप्रोसेसिंग, स्क्रिप्ट के बजाय Starlark में की जा सकती है. साथ ही, स्क्रिप्ट में थोड़ा ज़्यादा दस्तावेज़ीकरण होता है, क्योंकि इसमें आर्ग्युमेंट के लिए अंकों के बजाय, सिंबल प्लेसहोल्डर (बदली जाने वाली वैल्यू के लिए) का इस्तेमाल किया जाता है.

//mypkg/myrule_validator.sh.template:

if [ "$(cat %TARGET%)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/myrule_validation.bzl:

def _myrule_validation_test_impl(ctx):
  """Rule for instantiating myrule_validator.sh.template for a given target."""
  exe = ctx.outputs.executable
  target = ctx.file.target
  ctx.actions.expand_template(output = exe,
                              template = ctx.file._script,
                              is_executable = True,
                              substitutions = {
                                "%TARGET%": target.short_path,
                              })
  # This is needed to make sure the output file of myrule is visible to the
  # resulting instantiated script.
  return [DefaultInfo(runfiles=ctx.runfiles(files=[target]))]

myrule_validation_test = rule(
    implementation = _myrule_validation_test_impl,
    attrs = {"target": attr.label(allow_single_file=True),
             # You need an implicit dependency in order to access the template.
             # A target could potentially override this attribute to modify
             # the test logic.
             "_script": attr.label(allow_single_file=True,
                                   default=Label("//mypkg:myrule_validator"))},
    test = True,
)

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed just once, to expose the template. Could have also used export_files(),
# and made the _script attribute set allow_files=True.
filegroup(
    name = "myrule_validator",
    srcs = [":myrule_validator.sh.template"],
)

# Needed for each target whose artifacts are to be checked. Notice that you no
# longer have to specify the output file name in a data attribute, or its
# $(location) expansion in an args attribute, or the label for the script
# (unless you want to override it).
myrule_validation_test(
    name = "validate_mytarget",
    target = ":mytarget",
)

इसके अलावा, टेंप्लेट एक्सपैंशन ऐक्शन का इस्तेमाल करने के बजाय, टेंप्लेट को स्ट्रिंग के तौर पर .bzl फ़ाइल में इनलाइन किया जा सकता था. साथ ही, विश्लेषण के दौरान, str.format तरीके या %-फ़ॉर्मैटिंग का इस्तेमाल करके, उसे बड़ा किया जा सकता था.

Starlark की सुविधाओं की जांच करना

Skylib के unittest.bzl फ़्रेमवर्क का इस्तेमाल, यूटिलिटी फ़ंक्शन की जांच करने के लिए किया जा सकता है. ये ऐसे फ़ंक्शन होते हैं जो मैक्रो या नियम लागू करने वाले फ़ंक्शन नहीं होते. unittest.bzl की analysistest लाइब्रेरी के बजाय, unittest का इस्तेमाल किया जा सकता है. ऐसे टेस्ट सुइट के लिए, बोइलरप्लेट को कम करने के लिए, सुविधा फ़ंक्शन unittest.suite() का इस्तेमाल किया जा सकता है.

//mypkg/myhelpers.bzl:

def myhelper():
    return "abc"

//mypkg/myhelpers_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "unittest")
load(":myhelpers.bzl", "myhelper")

def _myhelper_test_impl(ctx):
  env = unittest.begin(ctx)
  asserts.equals(env, "abc", myhelper())
  return unittest.end(env)

myhelper_test = unittest.make(_myhelper_test_impl)

# No need for a test_myhelper() setup function.

def myhelpers_test_suite(name):
  # unittest.suite() takes care of instantiating the testing rules and creating
  # a test_suite.
  unittest.suite(
    name,
    myhelper_test,
    # ...
  )

//mypkg/BUILD:

load(":myhelpers_test.bzl", "myhelpers_test_suite")

myhelpers_test_suite(name = "myhelpers_tests")

ज़्यादा उदाहरणों के लिए, Skylib के टेस्ट देखें.