Bazel 教學課程：設定 C++ 工具鍊

回報問題 查看原始碼 Nightly · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本教學課程會以示例情境說明如何為專案設定 C++ 工具鍊。這項測試是根據C++ 專案範例進行，該範例使用 clang 建構無錯誤的專案。

課程內容

在本教學課程中，您將學習如何：

  • 設定建構環境
  • 設定 C++ 工具鍊
  • 建立 Starlark 規則，為 cc_toolchain 提供額外設定，以便 Bazel 使用 clang 建構應用程式
  • 在 Linux 電腦上執行 bazel build --config=clang_config //main:hello-world，確認預期結果
  • 建構 C++ 應用程式

事前準備

設定建構環境

本教學課程假設您使用的是 Linux，且已成功建構 C++ 應用程式，並安裝適當的工具和程式庫。本教學課程使用 clang version 9.0.1，您可以將其安裝在系統中。

請按照下列步驟設定建構環境：

  1. 如果您尚未下載並安裝 Bazel 0.23 以上版本，請先完成這項操作。

  2. 從 GitHub 下載範例 C++ 專案，並將其放在本機電腦的空白目錄中。

  3. 將下列 cc_binary 目標新增至 main/BUILD 檔案：

    cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

  4. 在工作區目錄的根目錄中建立 .bazelrc 檔案，並加入以下內容，以便使用 --config 標記：

    # Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

對於 build:{config_name} --flag=value 項目，指令列旗標 --config={config_name} 會與該特定旗標建立關聯。請參閱說明文件，瞭解所使用的標記：crosstool_top、cpu 和 host_crosstool_top。

使用 bazel build --config=clang_config //main:hello-world 建構目標時，Bazel 會使用 cc_toolchain_suite //toolchain:clang_suite 中的自訂工具鍊。套件可能會為不同的 CPU 列出不同的工具鍊，因此會使用 --cpu=k8 標記進行區分。

由於 Bazel 會在建構期間使用許多以 C++ 編寫的內部工具 (例如 process-wrapper)，因此會為主機平台指定先前存在的預設 C++ 工具鍊，以便使用該工具鍊建構這些工具，而非本教學課程中建立的工具鍊。

設定 C++ 工具鍊

如要設定 C++ 工具鍊，請反覆建構應用程式，並逐一排除每個錯誤，如下所述。

  1. 使用下列指令執行建構作業：

    bazel build --config=clang_config //main:hello-world

    由於您在 .bazelrc 檔案中指定了 --crosstool_top=//toolchain:clang_suite，因此 Bazel 會擲回以下錯誤：

    No such package `toolchain`: BUILD file not found on package path.

    在工作區目錄中，為套件建立 toolchain 目錄，並在 toolchain 目錄中建立空白的 BUILD 檔案。

  2. 再次執行版本。由於 toolchain 套件尚未定義 clang_suite 目標，因此 Bazel 會擲回以下錯誤：

    No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD

    在 toolchain/BUILD 檔案中，定義空白的檔案群組，如下所示：

    package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")

  3. 再次執行版本。Bazel 會擲回以下錯誤：

    '//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'

    Bazel 發現 --crosstool_top 標記指向的規則未提供必要的 ToolchainInfo 供應器。因此，您必須將 --crosstool_top 指向確實提供 ToolchainInfo 的規則，也就是 cc_toolchain_suite 規則。在 toolchain/BUILD 檔案中，將空白檔案群組替換為以下內容：

    cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)

    toolchains 屬性會自動將 --cpu (以及指定的 --compiler) 值對應至 cc_toolchain。您尚未定義任何 cc_toolchain 目標，Bazel 很快就會對此提出警告。

  4. 再次執行版本。Bazel 會擲回以下錯誤：

    Rule '//toolchain:k8_toolchain' does not exist

    接著，您需要為 cc_toolchain_suite.toolchains 屬性中的每個值定義 cc_toolchain 目標。將下列內容新增至 toolchain/BUILD 檔案：

    filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

  5. 再次執行版本。Bazel 會擲回以下錯誤：

    Rule '//toolchain:k8_toolchain_config' does not exist

    接下來，請在 toolchain/BUILD 檔案中新增「:k8_toolchain_config」目標：

    filegroup(name = "k8_toolchain_config")

  6. 再次執行版本。Bazel 會擲回以下錯誤：

    '//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'

    CcToolchainConfigInfo 是用來設定 C++ 工具鍊的供應器。如要修正這項錯誤，請建立 Starlark 規則，透過以下內容的 toolchain/cc_toolchain_config.bzl 檔案，將 CcToolchainConfigInfo 提供給 Bazel：

    def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

    cc_common.create_cc_toolchain_config_info() 會建立所需的提供者 CcToolchainConfigInfo。如要使用 cc_toolchain_config 規則，請將載入陳述式新增至 toolchains/BUILD：

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")

    並將「k8_toolchain_config」檔案群組替換為 cc_toolchain_config 規則的宣告：

    cc_toolchain_config(name = "k8_toolchain_config")

  7. 再次執行版本。Bazel 會擲回以下錯誤：

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

    此時，Bazel 已取得足夠資訊，可嘗試建構程式碼，但仍不知道要使用哪些工具來完成必要的建構動作。您將修改 Starlark 規則實作，告訴 Bazel 要使用哪些工具。為此，您需要使用 @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl 中的 tool_path() 建構函式：

    # toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

    請確認 /usr/bin/clang 和 /usr/bin/ld 是系統的正確路徑。

  8. 再次執行版本。Bazel 會擲回以下錯誤：

     ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....

    Bazel 需要知道要從何處搜尋所包含的標頭。解決這個問題的方法有很多，例如使用 cc_binary 的 includes 屬性，但這裡是透過 cc_common.create_cc_toolchain_config_info 的 cxx_builtin_include_directories 參數，在工具鍊層級解決這個問題。請注意，如果您使用的是其他版本的 clang，包含路徑就會有所不同。這些路徑也可能因發布版本而異。

    修改 toolchain/cc_toolchain_config.bzl 中的傳回值，如下所示：

     return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )

  9. 再次執行建構指令，您會看到類似以下的錯誤訊息：

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

    這是因為連結器缺少 C++ 標準程式庫，因此無法找到其符號。解決這個問題的方法有很多，例如使用 cc_binary 的 linkopts 屬性。這裡的解決方法是確保使用工具鍊的任何目標都不需要指定這個旗標。

    將下列程式碼複製到 cc_toolchain_config.bzl：

      # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

  10. 如果您執行 bazel build --config=clang_config //main:hello-world，應該會最終建構。

查看作業

在本教學課程中，您已瞭解如何設定基本 C++ 工具鍊，但工具鍊比這個簡單範例更強大。

重點摘要如下：- 您需要在指令列中指定 --crosstool_top 旗標，並指向 cc_toolchain_suite- 您可以使用 .bazelrc 檔案為特定設定建立捷徑- cc_toolchain_suite 可能會為不同的 CPU 和編譯器列出 cc_toolchains。您可以使用 --cpu 等指令列旗標來區分。- 您必須讓工具鍊知道工具所在位置。本教學課程提供簡易版，可讓您從系統存取工具。如果您想採用更獨立的方法，請參閱這篇文章，瞭解如何使用工作區。您的工具可能來自不同的工作區，因此您必須將其檔案提供給 cc_toolchain，並在屬性 (例如 compiler_files) 中設定目標依附元件。tool_paths 也需要變更。- 您可以建立功能，自訂應傳遞至不同動作的標記，無論是連結或任何其他類型的動作皆可。

延伸閱讀

詳情請參閱「C++ 工具鍊設定」