กรณีการใช้งานทั่วไปของ C++ เกี่ยวกับการสร้าง

ในส่วนนี้ คุณจะเห็น Use Case ที่พบบ่อยที่สุดบางส่วนสำหรับการสร้างโปรเจ็กต์ C++ ด้วย Bazel หากยังไม่ได้เริ่มสร้างโปรเจ็กต์ C++ ด้วย Bazel ให้ดูบทแนะนำข้อมูลเบื้องต้นเกี่ยวกับ Bazel: สร้างโปรเจ็กต์ C++

ดูข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs ได้ที่ cc_library

การรวมไฟล์หลายไฟล์ไว้ในเป้าหมาย

คุณสามารถรวมไฟล์หลายไฟล์ไว้ในเป้าหมายเดียวได้โดยใช้ glob เช่น

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ยกเว้นไดเรกทอรีย่อย)

การใช้การรวมแบบทรานซิทีฟ

หากไฟล์มีส่วนหัว กฎที่มีไฟล์นั้นเป็นแหล่งที่มา (กล่าวคือ มีไฟล์นั้นในแอตทริบิวต์ srcs, hdrs หรือ textual_hdrs) ควรขึ้นอยู่กับกฎคลังภาพของส่วนหัวที่รวมไว้ ในทางกลับกัน คุณต้องระบุเฉพาะการขึ้นต่อกันโดยตรงเท่านั้น ตัวอย่างเช่น สมมติว่า sandwich.h รวม bread.h และ bread.h รวม flour.h sandwich.h ไม่รวม flour.h (ใครอยากใส่แป้งลงในแซนวิชบ้าง) ดังนั้นไฟล์ BUILD จึงมีลักษณะดังนี้

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ในกรณีนี้ ไลบรารี sandwich ขึ้นต่อกันกับไลบรารี bread ซึ่งขึ้นต่อกันกับไลบรารี flour

การเพิ่มเส้นทางรวม

บางครั้งคุณไม่สามารถ (หรือไม่ต้องการ) กำหนดเส้นทางรวมที่รูทที่รูทของพื้นที่ทำงาน ไลบรารีที่มีอยู่อาจมีไดเรกทอรีรวมที่ไม่ตรงกับเส้นทางในเวิร์กスペースอยู่แล้ว ตัวอย่างเช่น สมมติว่าคุณมีโครงสร้างไดเรกทอรีดังต่อไปนี้

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel จะคาดหวังว่า some_lib.h จะรวมอยู่ใน legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc รวม "some_lib.h" ไว้ หากต้องการให้เส้นทางรวมนั้นถูกต้อง legacy/some_lib/BUILD จะต้องระบุว่าไดเรกทอรี some_lib/include เป็นไดเรกทอรีรวม

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ซึ่งจะเป็นประโยชน์อย่างยิ่งสำหรับไลบรารีภายนอก เนื่องจากไฟล์ส่วนหัวของไลบรารีเหล่านั้นต้องรวมไว้พร้อมกับคำนำหน้า /

รวมถึงไลบรารีภายนอก

สมมติว่าคุณใช้ Google Test คุณสามารถใช้ฟังก์ชันที่เก็บข้อมูลอย่างใดอย่างหนึ่งในไฟล์ WORKSPACE เพื่อดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บข้อมูลได้ ดังนี้

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

จากนั้นสร้าง gtest.BUILD ซึ่งเป็นไฟล์ BUILD ที่ใช้คอมไพล์ Google Test Google Test มีข้อกําหนด "พิเศษ" หลายประการที่ทำให้cc_libraryกฎของ Google Test มีความซับซ้อนมากขึ้น

• googletest-release-1.10.0/src/gtest-all.cc ไฟล์อื่นๆ ทั้งหมดของ #include ใน googletest-release-1.10.0/src/: ยกเว้นไฟล์ดังกล่าวจากการคอมไพล์เพื่อป้องกันข้อผิดพลาดเกี่ยวกับลิงก์สำหรับสัญลักษณ์ที่ซ้ำกัน

• ไฟล์นี้ใช้ไฟล์ส่วนหัวซึ่งสัมพันธ์กับไดเรกทอรี googletest-release-1.10.0/include/ ("gtest/gtest.h") คุณจึงต้องเพิ่มไดเรกทอรีนั้นลงในเส้นทางรวม

• รายการดังกล่าวต้องลิงก์ใน pthread ดังนั้นให้เพิ่มรายการนั้นเป็น linkopt

ดังนั้นกฎสุดท้ายจึงมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

การดำเนินการนี้ค่อนข้างยุ่งยาก เนื่องจากทุกอย่างจะมี googletest-release-1.10.0 อยู่ข้างหน้า ซึ่งเป็นผลพลอยได้จากโครงสร้างของที่เก็บ คุณสามารถทําให้ http_archive นำส่วนนำหน้านี้ออกได้โดยการเพิ่มแอตทริบิวต์ strip_prefix

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD จึงจะมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ตอนนี้กฎ cc_ จะอิงตาม @gtest//:main ได้

การเขียนและเรียกใช้การทดสอบ C++

เช่น คุณอาจสร้าง ./test/hello-test.cc ทดสอบ เช่น

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

จากนั้นสร้างไฟล์ ./test/BUILD สำหรับการทดสอบ โดยทำดังนี้

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

หากต้องการให้ hello-greet แสดงใน hello-test คุณต้องเพิ่ม "//test:__pkg__", ลงในแอตทริบิวต์ visibility ใน ./main/BUILD

ตอนนี้คุณใช้ bazel test เพื่อเรียกใช้การทดสอบได้แล้ว

bazel test test:hello-test

ซึ่งจะให้ผลลัพธ์ดังนี้

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

การเพิ่มทรัพยากร Dependency ในไลบรารีที่คอมไพล์ไว้ล่วงหน้า

หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (เช่น ส่วนหัวและไฟล์ .so) ให้ใส่ไว้ในกฎ cc_library ดังนี้

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

วิธีนี้ช่วยให้เป้าหมาย C++ อื่นๆ ในเวิร์กスペースใช้กฎนี้ได้