การครอบคลุมของโค้ดด้วย Bazel

Bazel มีคำสั่งย่อย coverage เพื่อสร้างรายงานการครอบคลุมโค้ดในรีโพซิทอรีที่ทดสอบด้วย bazel coverage ได้ เนื่องจากลักษณะที่แตกต่างกันของระบบนิเวศของภาษาต่างๆ นั้นจึงไม่ใช่เรื่องง่ายเสมอไปที่จะทำโปรเจ็กต์หนึ่งๆ ได้

หน้านี้บันทึกขั้นตอนทั่วไปในการสร้างและดูรายงานการครอบคลุม นอกจากนี้ยังมีหมายเหตุเฉพาะภาษาสำหรับภาษาที่มีการกำหนดค่าซึ่งเป็นที่รู้จักกันดี วิธีที่ดีที่สุดในการอ่านคืออ่านส่วนทั่วไปก่อน แล้วจึงอ่านเกี่ยวกับข้อกำหนดสำหรับภาษาใดภาษาหนึ่ง โปรดดูส่วนการดำเนินการระยะไกลด้วย ซึ่งต้องมีข้อควรพิจารณาเพิ่มเติม

แม้ว่าคุณจะปรับแต่งได้มากมาย แต่เอกสารนี้จะมุ่งเน้นที่การสร้างและการใช้รายงาน lcov ซึ่งปัจจุบันเป็นเส้นทางที่รองรับได้ดีที่สุด

การสร้างรายงานความครอบคลุม

การเตรียมพร้อม

ขั้นตอนพื้นฐานในการสร้างรายงานความครอบคลุมต้องมีสิ่งต่อไปนี้

• ที่เก็บข้อมูลพื้นฐานที่มีเป้าหมายการทดสอบ
• เครื่องมือทางเทคนิคที่ติดตั้งเครื่องมือการครอบคลุมโค้ดเฉพาะภาษา
• การกำหนดค่า "การใช้เครื่องมือ" ที่ถูกต้อง

2 รายการแรกเป็นภาษาที่เฉพาะเจาะจงและตรงไปตรงมาส่วนใหญ่ แต่รายการหลังอาจใช้ยากกว่าสำหรับโปรเจ็กต์ที่ซับซ้อน

"เครื่องมือวัด" ในกรณีนี้หมายถึงเครื่องมือการครอบคลุมที่ใช้กับเป้าหมายที่เฉพาะเจาะจง Bazel อนุญาตให้เปิดการตั้งค่านี้สำหรับชุดย่อยของไฟล์ที่เจาะจงโดยใช้แฟล็ก --instrumentation_filter ซึ่งระบุตัวกรองสำหรับเป้าหมายที่มีการทดสอบโดยเปิดใช้การวัดคุมไว้ หากต้องการเปิดใช้การใช้เครื่องมือสำหรับการทดสอบ คุณต้องแจ้ง --instrument_test_targets ให้

โดยค่าเริ่มต้น bazel จะพยายามจับคู่แพ็กเกจเป้าหมาย และพิมพ์ตัวกรองที่เกี่ยวข้องเป็นข้อความ INFO

การรายงานข่าว

หากต้องการสร้างรายงานการครอบคลุม ให้ใช้ bazel coverage --combined_report=lcov [target] วิธีนี้จะเรียกใช้การทดสอบสำหรับเป้าหมาย และสร้างรายงานการครอบคลุมในรูปแบบ lcov สำหรับแต่ละไฟล์

เมื่อทำเสร็จแล้ว Bazel จะเรียกใช้การดำเนินการที่รวบรวมไฟล์การครอบคลุมทั้งหมดที่สร้างขึ้นและรวมไฟล์เหล่านั้นเป็นไฟล์เดียว ซึ่งสุดท้ายแล้วจะสร้างภายใต้ $(bazel info output_path)/_coverage/_coverage_report.dat

นอกจากนี้ เรายังสร้างรายงานการครอบคลุมอีกด้วยหากการทดสอบไม่ผ่าน โปรดทราบว่ารายงานจะไม่ครอบคลุมแค่การทดสอบที่ไม่ผ่าน แต่จะรายงานเฉพาะการทดสอบที่ผ่านเท่านั้น

การรายงานข่าว

รายงานการครอบคลุมจะแสดงในรูปแบบ lcov ที่มนุษย์อ่านไม่ได้เท่านั้น จากตัวอย่างนี้ เราจะใช้ยูทิลิตี genhtml (ซึ่งเป็นส่วนหนึ่งของโปรเจ็กต์ lcov) เพื่อสร้างรายงานที่ดูได้บนเว็บเบราว์เซอร์

genhtml --output genhtml "$(bazel info output_path)/_coverage/_coverage_report.dat"

โปรดทราบว่า genhtml จะอ่านซอร์สโค้ดด้วย เพื่อใส่คำอธิบายประกอบการครอบคลุมที่ขาดหายไปในไฟล์เหล่านี้ ระบบควรจะดำเนินการ genhtml ในรูทของโปรเจ็กต์ bazel เพื่อให้ใช้งานได้

หากต้องการดูผลลัพธ์ ให้เปิดไฟล์ index.html ที่สร้างขึ้นในไดเรกทอรี genhtml ในเว็บเบราว์เซอร์ใดก็ได้

หากต้องการความช่วยเหลือและข้อมูลเพิ่มเติมเกี่ยวกับเครื่องมือ genhtml หรือรูปแบบการครอบคลุม lcov โปรดดูโปรเจ็กต์ lcov

การดำเนินการจากระยะไกล

ปัจจุบันการเรียกใช้ด้วยการดําเนินการทดสอบจากระยะไกลมีข้อจํากัดบางประการ ดังนี้

• การดำเนินการรวมรายงานยังทํางานจากระยะไกลไม่ได้ เนื่องจาก Bazel ไม่ถือว่าไฟล์เอาต์พุตการครอบคลุมเป็นส่วนหนึ่งของกราฟ (ดูปัญหานี้) จึงไม่สามารถถือว่าไฟล์เหล่านี้เป็นอินพุตสําหรับการดำเนินการรวมได้อย่างถูกต้อง หากต้องการแก้ปัญหานี้ ให้ใช้ --strategy=CoverageReport=local
  • หมายเหตุ: คุณอาจต้องระบุค่าอย่างเช่น --strategy=CoverageReport=local,remote แทนหากตั้งค่า Bazel ให้ลองใช้ local,remote เนื่องจากวิธีที่ Bazel แก้ปัญหา
• --remote_download_minimal และธงที่คล้ายกันก็ใช้ไม่ได้เช่นกันเนื่องจากข้อจำกัดดังกล่าว
• ปัจจุบัน Bazel จะสร้างข้อมูลการครอบคลุมไม่สำเร็จหากมีการแคชการทดสอบไว้ก่อนหน้านี้ วิธีแก้ปัญหานี้คือคุณสามารถตั้งค่า--nocache_test_resultsสำหรับการเรียกใช้เพื่อหาความครอบคลุมโดยเฉพาะได้ แม้ว่าวิธีนี้จะทำให้เสียเวลาในการทดสอบอย่างมาก
• --experimental_split_coverage_postprocessing และ --experimental_fetch_all_coverage_outputs
  • โดยปกติแล้ว การครอบคลุมจะทำงานเป็นส่วนหนึ่งของการดำเนินการทดสอบ ดังนั้นโดยค่าเริ่มต้น เราจะไม่ได้รับการครอบคลุมทั้งหมดเป็นเอาต์พุตของการดำเนินการจากระยะไกล แฟล็กเหล่านี้จะลบล้างค่าเริ่มต้นและรับข้อมูลการครอบคลุม ดูรายละเอียดเพิ่มเติมจากปัญหานี้

การกำหนดค่าเฉพาะภาษา

Java

Java ควรทำงานได้ทันทีด้วยการกำหนดค่าเริ่มต้น bazel Toolchains มีทุกอย่างที่จําเป็นสําหรับการดําเนินการระยะไกล ซึ่งรวมถึง JUnit ด้วย

Python

ข้อกำหนดเบื้องต้น

การเรียกใช้การครอบคลุมด้วย Python มีข้อกำหนดเบื้องต้นดังนี้

• ไฟล์ปฏิบัติการ Bazel ที่มี b01c859 ซึ่งควรเป็น Bazel เวอร์ชันใดก็ได้ที่มากกว่า 3.0
• cover.py เวอร์ชันที่แก้ไขแล้ว

การใช้ coverage.py ที่แก้ไขแล้ว

วิธีดำเนินการนี้คือการใช้ rules_python ซึ่งจะทำให้สามารถใช้ไฟล์ requirements.txt และจากนั้นระบบจะสร้างข้อกำหนดที่ระบุไว้ในไฟล์เป็นเป้าหมายแบบ bazel โดยใช้กฎที่เก็บ pip_install

requirements.txt ควรมีรายการต่อไปนี้

git+https://github.com/ulfjack/coveragepy.git@lcov-support

จากนั้นควรใช้ไฟล์ rules_python, pip_install และ requirements.txt ในไฟล์ WORKSPACE ดังนี้

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_python",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.5.0/rules_python-0.5.0.tar.gz",
    sha256 = "cd6730ed53a002c56ce4e2f396ba3b3be262fd7cb68339f0377a45e8227fe332",
)

load("@rules_python//python:pip.bzl", "pip_install")

pip_install(
   name = "python_deps",
   requirements = "//:requirements.txt",
)

จากนั้นเป้าหมายการทดสอบจะใช้ข้อกําหนดของ coverage.py ได้โดยการตั้งค่าต่อไปนี้ในไฟล์ BUILD

load("@python_deps//:requirements.bzl", "entry_point")

alias(
    name = "python_coverage_tools",
    actual = entry_point("coverage"),
)

py_test(
    name = "test",
    srcs = ["test.py"],
    env = {
        "PYTHON_COVERAGE": "$(location :python_coverage_tools)",
    },
    deps = [
        ":main",
        ":python_coverage_tools",
    ],
)

หากคุณใช้เครื่องมือเชน Python แบบเต็มตัว แทนที่จะเพิ่มการครอบคลุมให้เป้าหมาย py_test ทุกรายการ ให้เพิ่มเครื่องมือการครอบคลุมในการกำหนดค่า Toolchain

เนื่องจากกฎ pip_install ขึ้นอยู่กับชุดเครื่องมือ Python จึงใช้ดึงข้อมูลโมดูล coverage ไม่ได้ แต่ให้เพิ่ม WORKSPACE แทน เช่น

http_archive(
    name = "coverage_linux_x86_64"",
    build_file_content = """
py_library(
    name = "coverage",
    srcs = ["coverage/__main__.py"],
    data = glob(["coverage/*", "coverage/**/*.py"]),
    visibility = ["//visibility:public"],
)
""",
    sha256 = "84631e81dd053e8a0d4967cedab6db94345f1c36107c71698f746cb2636c63e3",
    type = "zip",
    urls = [
        "https://files.pythonhosted.org/packages/74/0d/0f3c522312fd27c32e1abe2fb5c323b583a5c108daf2c26d6e8dfdd5a105/coverage-6.4.1-cp39-cp39-manylinux_2_5_x86_64.manylinux1_x86_64.manylinux_2_17_x86_64.manylinux2014_x86_64.whl",
    ],
)

จากนั้นกำหนดค่า Toolchain ของ Python เช่น

py_runtime(
    name = "py3_runtime_linux_x86_64",
    coverage_tool = "@coverage_linux_x86_64//:coverage",
    files = ["@python3_9_x86_64-unknown-linux-gnu//:files"],
    interpreter = "@python3_9_x86_64-unknown-linux-gnu//:bin/python3",
    python_version = "PY3",
)

py_runtime_pair(
    name = "python_runtimes_linux_x86_64",
    py2_runtime = None,
    py3_runtime = ":py3_runtime_linux_x86_64",
)

toolchain(
    name = "python_toolchain_linux_x86_64",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":python_runtimes_linux_x86_64",
    toolchain_type = "@bazel_tools//tools/python:toolchain_type",
)