このページは Cloud Translation API によって翻訳されました。

Bazel によるコードカバレッジ

Bazel には、bazel coverage でテストできるリポジトリのコードカバレッジレポートを生成する coverage サブコマンドがあります。さまざまな言語エコシステムの特異性により、特定のプロジェクトでこれを行うことは必ずしも簡単ではありません。

このページでは、カバレッジレポートを作成および表示する一般的なプロセスについて説明します。また、構成がよく知られている言語について、言語固有の注意事項についても説明します。最初に一般的なセクションを読んでから、特定の言語の要件を読むことをおすすめします。リモート実行セクションにも注意してください。これには追加の考慮事項がいくつかあります。

さまざまなカスタマイズが可能ですが、このドキュメントでは lcov レポートの作成と使用に重点を置いています。現在、このレポートは最もサポートされている方法です。

カバレッジレポートを作成する

準備

カバレッジレポートを作成する基本的なワークフローでは、次のことが必要です。

テストターゲットを含む基本的なリポジトリ
言語固有のコードカバレッジツールがインストールされたツールチェーン
正しい「計測」構成

前者は言語固有でほとんどが単純ですが、後者は複雑なプロジェクトではより難しい場合があります。

この場合の「計測」とは、特定のターゲットに使用されるカバレッジツールを指します。Bazel では、--instrumentation_filter フラグを使用して、ファイルのサブセットに対してこの機能を有効にできます。このフラグは、インストルメンテーションを有効にしてテストされたターゲットのフィルタを指定します。テストのインストルメンテーションを有効にするには、--instrument_test_targets フラグが必要です。

デフォルトでは、bazel はターゲットパッケージの照合を試み、関連するフィルタを INFO メッセージとして出力します。

実行中のカバレッジ

カバレッジレポートを作成するには、bazel coverage --combined_report=lcov [target] を使用します。これにより、ターゲットのテストが実行され、ファイルごとに lcov 形式のカバレッジレポートが生成されます。

完了すると、Bazel は生成されたすべてのカバレッジファイルを収集するアクションを実行して、それらを 1 つにマージします。1 つにマージされた後、最終的に $(bazel info output_path)/_coverage/_coverage_report.dat の下に作成されます。

テストが失敗した場合にもカバレッジレポートが生成されますが、不合格になったテストは対象になりません。合格したテストのみが報告されます。

カバレッジの表示

カバレッジレポートは、人間が判読できない lcov 形式でのみ出力されます。ここから、genhtml ユーティリティ（lcov プロジェクトの一部）を使用して、ウェブブラウザで表示できるレポートを生成できます。

genhtml --output genhtml "$(bazel info output_path)/_coverage/_coverage_report.dat"

なお、genhtml はソースコードも読み取り、これらのファイルで欠落しているカバレッジにアノテーションを付けます。これが機能するためには、genhtml が bazel プロジェクトのルートで実行されることが想定されています。

結果を表示するには、任意のウェブブラウザで genhtml ディレクトリで生成された index.html ファイルを開きます。

genhtml ツールまたは lcov カバレッジ形式について詳しくは、lcov プロジェクトをご覧ください。

リモート実行

現在、リモートテスト実行で実行する場合、いくつかの注意点があります。

レポートの組み合わせの操作はまだリモートで実行できません。これは、Bazel がカバレッジ出力ファイルをグラフの一部として考慮せず（この問題を参照）、組み合わせアクションへの入力として正しく処理できないためです。この問題を回避するには、--strategy=CoverageReport=local を使用します。
- 注: Bazel が local,remote を試すように設定されている場合、Bazel によるストラテジーの解決方法により、--strategy=CoverageReport=local,remote などの指定が必要になることがあります。
前者の場合、--remote_download_minimal や同様のフラグも使用できません。
テストがすでにキャッシュに保存されている場合、Bazel は現在、カバレッジ情報の作成に失敗します。これを回避するために、カバレッジ実行専用に --nocache_test_results を設定できますが、もちろんテスト時間の面で大きなコストが発生します。
--experimental_split_coverage_postprocessing と --experimental_fetch_all_coverage_outputs
- 通常、カバレッジはテストアクションの一部として実行されるため、デフォルトでは、すべてのカバレッジがリモート実行の出力として返されるわけではありません。これらのフラグはデフォルトをオーバーライドし、カバレッジデータを取得します。詳しくは、この問題をご覧ください。

言語固有の構成

Java

Java は、デフォルトの構成ですぐに使用できます。Bazel ツールチェーンには、JUnit をはじめ、リモート実行に必要なすべてのものが含まれています。

Python

前提条件

Python でカバレッジを実行するには、いくつかの前提条件があります。

b01c859 を含む bazel バイナリ。3.0 以降の Bazel である必要があります。
coverage.py の修正バージョン。

変更した scope.py の使用

これを行うには、rules_python を使用します。これにより、requirements.txt ファイルを使用できます。ファイルにリストされている要件は、pip_install リポジトリルールを使用して bazel ターゲットとして作成されます。

requirements.txt のエントリは次のようになります。

git+https://github.com/ulfjack/coveragepy.git@lcov-support

rules_python、pip_install、requirements.txt ファイルは、WORKSPACE ファイルで次のように使用する必要があります。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_python",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.5.0/rules_python-0.5.0.tar.gz",
    sha256 = "cd6730ed53a002c56ce4e2f396ba3b3be262fd7cb68339f0377a45e8227fe332",
)

load("@rules_python//python:pip.bzl", "pip_install")

pip_install(
   name = "python_deps",
   requirements = "//:requirements.txt",
)

また、BUILD ファイルで次の設定を行うことで、coverage.py 要件をテストターゲットで使用できます。

load("@python_deps//:requirements.bzl", "entry_point")

alias(
    name = "python_coverage_tools",
    actual = entry_point("coverage"),
)

py_test(
    name = "test",
    srcs = ["test.py"],
    env = {
        "PYTHON_COVERAGE": "$(location :python_coverage_tools)",
    },
    deps = [
        ":main",
        ":python_coverage_tools",
    ],
)

密閉型の Python ツールチェーンを使用している場合は、すべての py_test ターゲットにカバレッジの依存関係を追加する代わりに、ツールチェーン構成にカバレッジツールを追加できます。

pip_install ルールは Python ツールチェーンに依存するため、coverage モジュールの取得には使用できません。代わりに、WORKSPACE を追加します（例:

http_archive(
    name = "coverage_linux_x86_64"",
    build_file_content = """
py_library(
    name = "coverage",
    srcs = ["coverage/__main__.py"],
    data = glob(["coverage/*", "coverage/**/*.py"]),
    visibility = ["//visibility:public"],
)
""",
    sha256 = "84631e81dd053e8a0d4967cedab6db94345f1c36107c71698f746cb2636c63e3",
    type = "zip",
    urls = [
        "https://files.pythonhosted.org/packages/74/0d/0f3c522312fd27c32e1abe2fb5c323b583a5c108daf2c26d6e8dfdd5a105/coverage-6.4.1-cp39-cp39-manylinux_2_5_x86_64.manylinux1_x86_64.manylinux_2_17_x86_64.manylinux2014_x86_64.whl",
    ],
)

次に、Python ツールチェーンを次のように構成します。

py_runtime(
    name = "py3_runtime_linux_x86_64",
    coverage_tool = "@coverage_linux_x86_64//:coverage",
    files = ["@python3_9_x86_64-unknown-linux-gnu//:files"],
    interpreter = "@python3_9_x86_64-unknown-linux-gnu//:bin/python3",
    python_version = "PY3",
)

py_runtime_pair(
    name = "python_runtimes_linux_x86_64",
    py2_runtime = None,
    py3_runtime = ":py3_runtime_linux_x86_64",
)

toolchain(
    name = "python_toolchain_linux_x86_64",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":python_runtimes_linux_x86_64",
    toolchain_type = "@bazel_tools//tools/python:toolchain_type",
)