การลงทะเบียน BazelCon 2024 เปิดให้ลงทะเบียนแล้วในตอนนี้

หน้านี้ได้รับการแปลโดย Cloud Translation API

การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

วันที่ รายงานปัญหา ดูแหล่งที่มา ตอนกลางคืน · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

ถ้าคุณเพิ่งเริ่มใช้ Bazel เป็นครั้งแรก ให้เริ่มจากการสร้าง Android ด้วย บทแนะนำ Bazel

ภาพรวม

Bazel สามารถทำงานในการกำหนดค่าบิลด์ต่างๆ มากมาย รวมถึงการกำหนดค่าบิลด์แบบต่างๆ ที่ใช้ เครื่องมือเชน Android Native Development Kit (NDK) ซึ่งหมายความว่า สามารถรวบรวมกฎ cc_library และ cc_binary สำหรับ Android ได้โดยตรงภายใน Bazel Bazel ดำเนินการนี้ได้โดยใช้ที่เก็บ android_ndk_repository กฎ

ข้อกำหนดเบื้องต้น

โปรดตรวจสอบว่าคุณได้ติดตั้ง Android SDK และ NDK แล้ว

หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

สำหรับข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository โปรดดูที่สร้าง ข้อมูลสารานุกรม

การเริ่มใช้งานอย่างง่าย

หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มทรัพยากร Dependency ของ cc_library ไปยัง กฎ android_binary หรือ android_library ข้อ

เช่น ระบุไฟล์ BUILD ต่อไปนี้สำหรับแอป Android

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้ให้ผลลัพธ์ในกราฟเป้าหมายต่อไปนี้

ตัวอย่างผลการแข่ง

รูปที่ 1 สร้างกราฟของโปรเจ็กต์ Android ที่มีทรัพยากร Dependency ของ cc_library

หากต้องการสร้างแอป เพียงเรียกใช้

bazel build //app/src/main:app

คำสั่ง bazel build จะรวมไฟล์ Java, ไฟล์ทรัพยากร Android และ cc_library กฎ และรวมทุกอย่างลงใน APK:

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel รวบรวม cc_libraries ทั้งหมด ลงในไฟล์ออบเจ็กต์ที่ใช้ร่วมกัน (.so) ไฟล์เดียว กำหนดเป้าหมายสำหรับ ABI ของ armeabi-v7a โดยค่าเริ่มต้น ในการเปลี่ยนผลิตภัณฑ์นี้หรือสร้างสำหรับ ABI หลายรายการพร้อมกัน โปรดดูส่วนในการกำหนดค่าเป้าหมาย ABI

ตัวอย่างการตั้งค่า

ตัวอย่างนี้มีอยู่ในตัวอย่างบาเซล ที่เก็บ

ในไฟล์ BUILD.bazel จะมีการกำหนด 3 เป้าหมายด้วย android_binary กฎ android_library และ cc_library

เป้าหมายระดับบนสุด android_binary จะสร้าง APK

เป้าหมาย cc_library มีไฟล์ต้นฉบับ C++ ไฟล์เดียวที่มีฟังก์ชัน JNI การใช้งาน:

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

เป้าหมาย android_library ระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และ ขึ้นอยู่กับเป้าหมาย cc_library สำหรับตัวอย่างนี้ MainActivity.java โหลด ไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นเมธอดสำหรับ JNI ฟังก์ชัน:

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า STL

หากต้องการกำหนดค่า C++ STL ให้ใช้แฟล็ก --android_crosstool_top

bazel build //:app --android_crosstool_top=target label

STL ที่ใช้ได้ใน @androidndk ได้แก่

STL	ป้ายกำกับเป้าหมาย
STLport	`@androidndk//:toolchain-stlport`
libc++	`@androidndk//:toolchain-libcpp`
Gnustl	`@androidndk//:toolchain-gnu-libstdcpp`

STL เริ่มต้นสำหรับ r16 หรือต่ำกว่าคือ gnustl สำหรับ R17 ขึ้นไป libc++ เพื่อความสะดวก เป้าหมาย @androidndk//:default_crosstool คือ เป็นนามแฝงของ STL เริ่มต้นที่เกี่ยวข้อง

โปรดทราบว่าตั้งแต่ r18 เป็นต้นไป STLport และ gnustl จะ นำออกแล้ว, ทำให้ libc++ เป็น STL เดียวใน NDK

ดู NDK เอกสารประกอบ เพื่อดูข้อมูลเพิ่มเติมเกี่ยวกับ STL เหล่านี้

กำลังกำหนดค่า ABI เป้าหมาย

หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --fat_apk_cpu ดังนี้

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

โดยค่าเริ่มต้น Bazel จะสร้างโค้ด Android แบบเนทีฟสำหรับ armeabi-v7a วิธีสร้างสำหรับ x86 (เช่น สำหรับโปรแกรมจำลอง) ให้ผ่าน --fat_apk_cpu=x86 วิธีสร้าง APK แบบอ้วนสำหรับ สถาปัตยกรรมที่คุณสามารถระบุ CPU หลายรายการ: --fat_apk_cpu=armeabi-v7a,x86

หากระบุ ABI มากกว่า 1 รายการ Bazel จะสร้าง APK ที่มี สำหรับ ABI แต่ละรายการ

ABI ต่อไปนี้ขึ้นอยู่กับการแก้ไข NDK และระดับ Android API ว่าง:

การแก้ไข NDK	ABI
16 ปีหรือต่ำกว่า	Armeabi, Armeabi-v7a, arm64-v8a, Mips, Mips64, x86, x86_64
17 ปีขึ้นไป	Armeabi-v7a, arm64-v8a, x86, x86_64

ดูเอกสาร NDK สำหรับข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้

เราไม่แนะนำให้ใช้ APK ที่มีจำนวนไขมัน ABI หลายรายการสำหรับบิลด์ที่เผยแพร่เนื่องจากเพิ่มขึ้น ขนาดของ APK แต่ก็อาจเป็นประโยชน์ต่อการพัฒนาและการสร้าง QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

C++ มาตรฐาน	ธง
C++98	ค่าเริ่มต้น ไม่ต้องแจ้งว่าไม่เหมาะสม
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และ Linker ด้วย --cxxopt, --copt และ --linkopt ในคู่มือผู้ใช้

คุณยังระบุแฟล็กคอมไพเลอร์และ Linker เป็นแอตทริบิวต์ใน cc_library ได้ด้วย ด้วย copts และ linkopts เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การผสานรวมกับแพลตฟอร์มและ Toolchain

โมเดลการกำหนดค่าของ Bazel กำลังจะเข้าสู่ แพลตฟอร์มและ เครื่องมือเชน หาก บิลด์ใช้แฟล็ก --platforms เพื่อเลือกสถาปัตยกรรมหรือระบบปฏิบัติการ เพื่อสร้าง คุณจะต้องส่ง Flag --extra_toolchains ไปยัง Bazel ใน เพื่อใช้ NDK

เช่น เพื่อผสานรวมกับ Toolchain ของ android_arm64_cgo ซึ่งให้บริการโดย กฎ Go ให้ผ่านการตรวจสอบ --extra_toolchains=@androidndk//:all นอกเหนือจาก แฟล็ก --platforms

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

นอกจากนี้คุณยังลงทะเบียนในไฟล์ WORKSPACE ได้โดยตรง โดยทำดังนี้

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

การลงทะเบียนเครื่องมือเชนเหล่านี้จะบอกให้ Bazel มองหาเชนเครื่องมือดังกล่าวใน NDK BUILD (สำหรับ NDK 20) เมื่อแก้ไขข้อจำกัดของสถาปัตยกรรมและระบบปฏิบัติการ

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

วิธีการทำงาน: แนะนำการเปลี่ยนการกำหนดค่า Android

กฎ android_binary จะขอให้ Bazel สร้างทรัพยากร Dependency ใน การกำหนดค่าที่เข้ากันได้กับ Android เพื่อให้บิลด์ Bazel ทำงานได้ แฟล็กพิเศษทั้งหมด ยกเว้น --fat_apk_cpu และ --android_crosstool_top สำหรับ การกำหนดค่า ABI และ STL

การกำหนดค่าอัตโนมัตินี้จะใช้การกำหนดค่าของ Android ในเบื้องหลัง ทรานซิชัน

กฎที่เข้ากันได้ เช่น android_binary จะเปลี่ยน การกำหนดค่าทรัพยากร Dependency สำหรับการกำหนดค่า Android ได้ ดังนั้น โครงสร้างย่อยเฉพาะสำหรับ Android จะได้รับผลกระทบ ส่วนอื่นๆ ของบิลด์ กราฟจะได้รับการประมวลผลโดยใช้การกำหนดค่าเป้าหมายระดับบนสุด โดยอาจ ประมวลผลเป้าหมายเดียวในการกำหนดค่าทั้งสองแบบ หากมีเส้นทางผ่าน สร้างกราฟเพื่อรองรับการทำงาน

เมื่อ Bazel มีการกำหนดค่าที่ใช้ได้กับ Android ซึ่งระบุไว้ที่ ระดับบนสุดหรือเนื่องจากจุดเปลี่ยนในระดับที่สูงกว่า การเปลี่ยนเพิ่มเติม จุดที่พบไม่ได้แก้ไขการกำหนดค่าเพิ่มเติม

ตำแหน่งในตัวเพียงตำแหน่งเดียวที่ทริกเกอร์การเปลี่ยนไปใช้ Android การกำหนดค่าคือแอตทริบิวต์ deps ของ android_binary

ตัวอย่างเช่น หากคุณพยายามสร้างเป้าหมาย android_library ด้วย cc_library Dependency ที่ไม่มี Flag ใดๆ คุณอาจพบข้อผิดพลาดเกี่ยวกับ JNI ที่ขาดหายไป ส่วนหัว:

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

ตามหลักแล้ว การเปลี่ยนผ่านอัตโนมัติเหล่านี้ ควรทำให้ Bazel ทำสิ่งที่ถูกต้อง กรณีส่วนใหญ่ อย่างไรก็ตาม หากเป้าหมายในบรรทัดคำสั่ง Bazel นั้น ด้านล่างกฎการเปลี่ยนแปลงเหล่านี้ เช่น นักพัฒนาซอฟต์แวร์ C++ ที่ทำการทดสอบ cc_library คุณต้องใช้ --crosstool_top ที่กำหนดเอง

การสร้าง `cc_library` สำหรับ Android โดยไม่ใช้ `android_binary`

วิธีสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ใช้ --crosstool_top, --cpu และ --host_crosstool_top

เช่น

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

ในตัวอย่างนี้ เป้าหมาย cc_library และ cc_binary ระดับบนสุดสร้างขึ้น โดยใช้เครื่องมือเชน NDK ซึ่งทำให้เครื่องมือโฮสต์ของ Bazel สร้างขึ้น กับ Toolchain ของ NDK (และสำหรับ Android) เนื่องจาก Toolchain ของโฮสต์นั้น ที่คัดลอกมาจาก Toolchain เป้าหมาย วิธีแก้ไขปัญหานี้คือระบุค่าของ --host_crosstool_top จะเป็น @bazel_tools//tools/cpp:toolchain ต่อ ตั้งค่า Toolchain ของ C++ ของโฮสต์อย่างชัดเจน

ด้วยวิธีการนี้ แผนผังบิลด์ทั้งหมดจะได้รับผลกระทบ

แฟล็กเหล่านี้อยู่ในการกำหนดค่า bazelrc (1 รายการสำหรับ ABI แต่ละรายการ) ได้ใน project/.bazelrc:

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

จากนั้น หากต้องการสร้าง cc_library สำหรับ x86 ตัวอย่างเช่น ให้เรียกใช้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ใช้วิธีนี้สำหรับเป้าหมายระดับต่ำ (เช่น cc_library) หรือเมื่อ คุณรู้แน่ชัดว่าคุณกำลังสร้างอะไร ต้องอาศัยการกำหนดค่าอัตโนมัติ การเปลี่ยนแปลงจาก android_binary สำหรับเป้าหมายระดับสูงที่คุณคาดไว้ เพื่อสร้างเป้าหมายจำนวนมากที่คุณไม่สามารถควบคุมได้

การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

ภาพรวม

ข้อกำหนดเบื้องต้น

การเริ่มใช้งานอย่างง่าย

ตัวอย่างการตั้งค่า

การกำหนดค่า STL

กำลังกำหนดค่า ABI เป้าหมาย

การเลือกมาตรฐาน C++

การผสานรวมกับแพลตฟอร์มและ Toolchain

วิธีการทำงาน: แนะนำการเปลี่ยนการกำหนดค่า Android

การสร้าง cc_library สำหรับ Android โดยไม่ใช้ android_binary

การสร้าง `cc_library` สำหรับ Android โดยไม่ใช้ `android_binary`