搭配 Bazel 使用 Android 原生開發套件

回報問題 查看原始碼 。 。 。 。 夜間 。 。 。 。 7.3 。 。 7.2 。 。 7.1 。 。 7.0 。 6.5 。 。

如果您是第一次使用 Bazel，請先從使用 Bazel 教學課程。

總覽

Bazel 可在許多不同的建構設定中執行，包括使用 Android Native Development Kit (NDK) 工具鍊。也就是說 cc_library 和 cc_binary 規則可直接在 Android 中編譯 Bazel。Bazel 會利用 android_ndk_repository 存放區來完成這項作業 規則。

必要條件

請確認您已安裝 Android SDK 和 NDK。

如要設定 SDK 和 NDK，請將下列程式碼片段新增至 WORKSPACE：

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

如要進一步瞭解 android_ndk_repository 規則，請參閱「建構 百科全書入口。

快速入門

如要建構 Android 適用的 C++，只要將 cc_library 依附元件新增至 android_binary 或 android_library 規則。

以下列 Android 應用程式專用 BUILD 檔案為例：

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

這個 BUILD 檔案會產生以下目標圖表：

搜尋結果範例

圖 1. 使用 cc_library 依附元件的 Android 專案建構圖表。

如要建構應用程式，只要執行：

bazel build //app/src/main:app

bazel build 指令會編譯 Java 檔案、Android 資源檔案 cc_library 規則，將所有內容封裝至 APK：

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel 會將所有 cc_libraries 編譯成單一共用物件 (.so) 檔案， 預設會指定 armeabi-v7a ABI。如要變更此類別，或是針對 同時參閱「設定目標 ABI。

設定範例

Bazel 範例提供了這個範例 存放區

在 BUILD.bazel 檔案中，android_binary 定義了三個目標， android_library和 cc_library 規則

android_binary 頂層目標會建構 APK。

cc_library 目標包含具有 JNI 函式的單一 C++ 來源檔案 實作：

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 目標會指定 Java 來源、資源檔案和 依附於 cc_library 目標。在這個範例中，MainActivity.java 會載入 共用物件檔案 libapp.so，並定義 JNI 的方法簽章 函式：

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

設定 STL

如要設定 C++ STL，請使用旗標 --android_crosstool_top。

bazel build //:app --android_crosstool_top=target label

@androidndk 中可用的 STL 如下：

STL 目標標籤
STLport @androidndk//:toolchain-stlport
libc++ @androidndk//:toolchain-libcpp
gnustl @androidndk//:toolchain-gnu-libstdcpp

r16 以下版本的預設 STL 為 gnustl。如果是 r17 以上版本，則 libc++。為了方便起見，目標 @androidndk//:default_crosstool 為 稱為個別預設 STL。

請注意，r18 以後的 STLport 和 gnustl 將作為 已移除、 將 libc++ 設為 NDK 中唯一的 STL。

詳情請參閱 NDK 說明文件 進一步瞭解這些 STL。

設定目標 ABI

如要設定目標 ABI，請使用下列 --fat_apk_cpu 標記：

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

根據預設，Bazel 會為 armeabi-v7a 建構原生 Android 程式碼。為了針對 x86 建構 (例如模擬器) 請傳遞 --fat_apk_cpu=x86。為多個圖像建立多個 APK 您可以指定多個 CPU：--fat_apk_cpu=armeabi-v7a,x86

如果指定多個 ABI，Bazel 將會建構含有共用 ABI 的 APK 物件

根據 NDK 修訂版本和 Android API 級別，下列 ABI 如下： 可使用：

NDK 修訂版本 ABI
16 以下 armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 以上版本 armeabi-v7a、arm64-v8a、x86、x86_64

請參閱 NDK 說明文件 ，進一步瞭解這些 ABI。

我們不建議對發布子版本使用多重 ABI Fat APK，因為這類 APK 會增加 APK 的大小，但對於開發和品質確保版本來說非常實用。

選取 C++ 標準

請使用以下旗標，依據 C++ 標準進行建構：

C++ 標準 檢舉
C++98 預設，不需要標記
C++11 --cxxopt=-std=c++11
C++14 --cxxopt=-std=c++14

例如：

bazel build //:app --cxxopt=-std=c++11

進一步瞭解如何運用 --cxxopt、--copt 和 使用者手冊中的 --linkopt。

在 cc_library 中，您也可以將編譯器和連結器標記指定為屬性 使用 copts 和 linkopts。例如：

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

與平台和工具鍊整合

Bazel 的設定模型將朝向 平台和 「工具鍊」。如果您的 版本會使用 --platforms 旗標選取架構或作業系統 您需要將 --extra_toolchains 標記傳送至 Bazel 的 Bazel 才能使用 NDK。

舉例來說，如要與 android_arm64_cgo 提供的工具鍊 Go 規則，除了--extra_toolchains=@androidndk//:all --platforms 旗標。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

您也可以直接在 WORKSPACE 檔案中註冊這些事件：

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

註冊這些工具鍊會指示 Bazel 在 NDK BUILD 中尋找它們 檔案 (適用於 NDK 20)，以便解析架構和作業系統限制：

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

運作方式：Android 設定轉換簡介

android_binary 規則可明確要求 Bazel 在 與 Android 相容設定，讓 Bazel 建構作業「可以正常運作」 任何特殊標記 (--fat_apk_cpu 和 --android_crosstool_top 除外) ABI 和 STL 設定。

在背景，這項自動設定會使用 Android 設定 轉場效果。

android_binary 等相容規則會自動變更 指向 Android 設定的依附元件設定 版本的 Android 專用子樹狀結構受到影響。建構的其他部分 處理圖表時，會使用頂層目標設定。甚至 處理單一目標時，如果 才能支援這種架構

Bazel 在 由於頂層轉換點或較高層級的轉換點，加上額外的轉場效果 遇到的點無法進一步修改設定。

唯一會觸發 Android 裝置轉換作業的內建位置 設定為 android_binary 的 deps 屬性。

舉例來說，如果您嘗試使用 cc_library 建構 android_library 目標 如果依附元件沒有任何旗標，您可能會遇到缺少 JNI 的錯誤 標題：

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

在理想情況下，這些自動轉換作業應能讓 Bazel 在 大多數情況不過，如果 Bazel 指令列上的目標 注意：在這些轉換規則下，比如 C++ 開發人員 cc_library，則必須使用自訂 --crosstool_top。

在不使用 android_binary 的情況下，為 Android 建構 cc_library

為 Android 建構獨立的 cc_binary 或 cc_library，但不使用 android_binary，使用 --crosstool_top、--cpu 和 --host_crosstool_top 旗標

例如：

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

在這個範例中，我們建構了頂層 cc_library 和 cc_binary 目標 使用 NDK 工具鍊。然而，這會導致系統建構 Bazel 自己的主機工具 與 NDK 工具鍊通訊 (如果是 Android 裝置)，因為主機工具鍊 從目標工具鍊複製而來。如要解決這個問題，請指定 將--host_crosstool_top變更為@bazel_tools//tools/cpp:toolchain到 明確設定主機的 C++ 工具鍊。

使用這個方法時，整個建構樹狀結構都會受到影響。

這些旗標可放入 bazelrc 設定 (每個 ABI 各一個)， project/.bazelrc:

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

接著，如要為 x86 建構 cc_library，請執行：

bazel build //my/cc/jni:target --config=android_x86

一般來說，這個方法適用於低層級目標 (例如 cc_library)，或 確切知道要建構什麼內容仰賴自動設定 將超出 android_binary 的層級用於預期成效目標 建立很多您無法控管的目標