本教學課程會使用範例情境來說明如何為專案設定 C++ 工具鍊。是以使用 clang 建構不會錯誤的 C++ 專案範例為基礎。
課程內容
在本教學課程中，您將學習如何：
- 設定建構環境
- 設定 C++ 工具鍊
- 建立 Starlark 規則，為
cc_toolchain提供額外設定，以便 Bazel 使用clang建構應用程式 - 在 Linux 機器上執行
bazel build --config=clang_config //main:hello-world，確認預期結果 - 建構 C++ 應用程式
事前準備
設定建構環境
本教學課程假設您使用的是 Linux，且已成功建構 C++ 應用程式，並安裝適當的工具和程式庫。本教學課程使用 clang version 9.0.1，您可以將其安裝在系統中。
請按照下列方式設定建構環境：
如果您尚未下載並安裝 Bazel 0.23 以上版本，請先完成這個步驟。
從 GitHub 下載範例 C++ 專案，並將其放在本機電腦的空目錄中。
將下列
cc_binary目標新增至main/BUILD檔案：cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )在含有以下內容的工作區目錄根目錄中建立
.bazelrc檔案，以啟用--config標記：# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
若是項目 build:{config_name} --flag=value，指令列標記 --config={config_name} 與該特定標記相關聯。如要瞭解所用標記，請參閱說明文件：crosstool_top、cpu 和 host_crosstool_top。
使用 bazel build --config=clang_config //main:hello-world 建構目標時，Bazel 會使用 cc_toolchain_suite //toolchain:clang_suite 中的自訂工具鏈。套件可能會為不同的 CPU 列出不同的工具鏈，因此會使用 --cpu=k8 標記進行區分。
由於 Bazel 在建構期間會使用許多以 C++ 編寫的內部工具 (例如 process-wrapper)，因此會為主機平台指定先前存在的預設 C++ 工具鏈，以便使用該工具鏈建構這些工具，而非本教學課程中建立的工具鏈。
設定 C++ 工具鍊
如要設定 C++ 工具鍊，請重複建構應用程式，並逐一移除每個錯誤，如下所述。
使用下列指令執行建構：
bazel build --config=clang_config //main:hello-world由於您在
.bazelrc檔案中指定了--crosstool_top=//toolchain:clang_suite，因此 Bazel 會擲回下列錯誤：No such package `toolchain`: BUILD file not found on package path.在工作區目錄中，為套件建立
toolchain目錄，並在toolchain目錄中建立空白的BUILD檔案。再次執行建構。由於
toolchain套件尚未定義clang_suite目標，因此 Bazel 會擲回以下錯誤：No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILD在
toolchain/BUILD檔案中，定義空白檔案群組，如下所示：package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")再次執行版本。Bazel 會擲回下列錯誤：
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel 發現
--crosstool_top標記指向的規則未提供必要的ToolchainInfo提供者。因此，您需要將--crosstool_top指向提供ToolchainInfo的規則，也就是cc_toolchain_suite規則。在toolchain/BUILD檔案中，將空白檔案群組替換為以下內容：cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains屬性會自動將--cpu(以及指定時則為--compiler) 的值對應至cc_toolchain。您尚未定義任何cc_toolchain目標，而 Bazel 只會抱怨這個問題。再次執行版本。Bazel 會擲回下列錯誤：
Rule '//toolchain:k8_toolchain' does not exist接著，您需要為
cc_toolchain_suite.toolchains屬性中的每個值定義cc_toolchain目標。請將以下內容新增至toolchain/BUILD檔案：filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )再次執行建構。Bazel 會擲回下列錯誤：
Rule '//toolchain:k8_toolchain_config' does not exist接下來，請在
toolchain/BUILD檔案中新增「:k8_toolchain_config」目標：filegroup(name = "k8_toolchain_config")再次執行版本。Bazel 會擲回以下錯誤：
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfo是用於設定 C++ 工具鍊的提供者。如要修正這個錯誤，請建立含有以下內容的toolchain/cc_toolchain_config.bzl檔案，將CcToolchainConfigInfo提供給 Bazel 的 Starlark 規則：def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()會建立所需的提供者CcToolchainConfigInfo。如要使用cc_toolchain_config規則，請在toolchains/BUILD中新增載入陳述式：load(":cc_toolchain_config.bzl", "cc_toolchain_config")並將「k8_toolchain_config」檔案群組替換為
cc_toolchain_config規則的宣告：cc_toolchain_config(name = "k8_toolchain_config")再次執行版本。Bazel 會擲回以下錯誤：
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`此時，Bazel 已取得足夠的資訊，可嘗試建構程式碼，但仍不清楚要使用哪些工具來完成必要的建構動作。您將修改 Starlark 規則實作，告訴 Bazel 要使用哪些工具。為此，您需要使用
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl中的 tool_path() 建構函式：# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )確認
/usr/bin/clang和/usr/bin/ld是系統的正確路徑。再次執行建構。Bazel 會擲回下列錯誤：
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel 必須知道要在哪裡搜尋已納入的標頭。解決這個問題的方法有很多，例如使用
cc_binary的includes屬性，但這裡是透過cc_common.create_cc_toolchain_config_info的cxx_builtin_include_directories參數，在工具鏈層級解決這個問題。請注意，如果您使用的是其他版本的clang，包含路徑就會有所不同。這些路徑也可能因分佈情形而異。修改
toolchain/cc_toolchain_config.bzl中的傳回值，如下所示：return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )再次執行建構指令，您會看到類似以下的錯誤訊息：
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'這是因為連結器缺少 C++ 標準程式庫，且找不到其符號。解決這個問題的方法有很多，例如使用
cc_binary的linkopts屬性。這裡的解決方法是確保使用工具鏈的任何目標都不需要指定這個旗標。將下列程式碼複製到
cc_toolchain_config.bzl：# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )執行
bazel build --config=clang_config //main:hello-world時，系統應會進行最終建構。
檢查成果
在本教學課程中，您已瞭解如何設定基本的 C++ 工具鍊，但工具鍊比這個簡單的範例更強大。
重點如下：
- 您必須在指令列中指定 --crosstool_top 旗標，該旗標應指向 cc_toolchain_suite
- 您可以使用 .bazelrc 檔案建立特定設定的捷徑
- cc_toolchain_suite 可以為不同的 CPU 和編譯器列出 cc_toolchains。
您可以使用 --cpu 等指令列旗標來區分。- 您必須讓工具鏈知道工具所在位置。在這個教學課程中，有一個簡化的版本可讓您從系統存取工具。如果您想瞭解這種獨立方式，請參閱這裡的工作區的相關說明。您的工具可能來自不同的工作區，因此您必須將他們的檔案提供給 cc_toolchain，並指定以 compiler_files 等屬性為目標的依附元件。tool_paths 也需要變更。- 您可以建立功能，自訂應將哪些標記傳遞至不同的動作，無論是連結或任何其他類型的動作皆可。
延伸閱讀
詳情請參閱「C++ 工具鏈設定」