BazelCon 2024 登録の受け付けを開始しました。

このページは Cloud Translation API によって翻訳されました。

一般的な C++ ビルドのユースケース

7.3 · 7.2 · 7.1 · 7.0 · 6.5

ここでは、Bazel を使用して C++ プロジェクトをビルドする最も一般的なユースケースをいくつか紹介します。まだ行っていない場合は、Bazel の概要: C++ プロジェクトをビルドするチュートリアルを完了して、Bazel で C++ プロジェクトのビルドを開始します。

cc_library ヘッダーファイルと hdrs ヘッダーファイルの詳細については、cc_library をご覧ください。

ターゲットに複数のファイルを含める

glob を使用すると、1 つのターゲットに複数のファイルを含めることができます。例:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

このターゲットを使用して、Bazel は、このターゲットを含む BUILD ファイルと同じディレクトリ（サブディレクトリを除く）で見つかったすべての .cc ファイルと .h ファイルをビルドします。

伝播インクルードの使用

ファイルにヘッダーが含まれている場合、そのファイルをソースとするルール（つまり、srcs、hdrs、または textual_hdrs 属性にそのファイルが含まれているルール）は、含まれているヘッダーのライブラリルールに依存する必要があります。逆に、依存関係として指定する必要があるのは直接依存関係のみです。たとえば、sandwich.h に bread.h が含まれ、bread.h に flour.h が含まれているとします。sandwich.h には flour.h（サンドイッチに小麦粉が欲しい人）が含まれていないため、BUILD ファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここで、sandwich ライブラリは bread ライブラリに依存し、bread ライブラリは flour ライブラリに依存しています。

インクルードパスの追加

ワークスペースのルートでインクルードパスをルート化できない（またはルート化したくない）場合があります。既存のライブラリには、ワークスペース内のパスと一致しないインクルードディレクトリがすでにある場合があります。たとえば、次のようなディレクトリ構造があるとします。

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel では、some_lib.h が legacy/some_lib/include/some_lib.h として含まれていることを前提としていますが、some_lib.cc に "some_lib.h" が含まれていると仮定します。このインクルードパスを有効にするには、legacy/some_lib/BUILD で some_lib/include ディレクトリがインクルードディレクトリであることを指定する必要があります。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

これは、外部依存関係のヘッダーファイルを / 接頭辞で含める必要があるため、特に便利です。

外部ライブラリのインクルード

Google Test を使用しているとします。WORKSPACE ファイルのリポジトリ関数のいずれかを使用して、Google Test をダウンロードし、リポジトリで使用できるようにします。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

次に、gtest.BUILD（Google Test のコンパイルに使用する BUILD ファイル）を作成します。Google Test には、cc_library ルールを複雑にするいくつかの「特別な」要件があります。

googletest-release-1.10.0/src/gtest-all.cc: googletest-release-1.10.0/src/ 内の他のすべてのファイルを #include します。コンパイル対象から除外して、シンボルが重複している場合にリンクエラーが発生しないようにします。
googletest-release-1.10.0/include/ ディレクトリ（"gtest/gtest.h"）を基準とするヘッダーファイルを使用するため、そのディレクトリをインクルードパスに追加する必要があります。
pthread にリンクする必要があるため、linkopt として追加します。

最終的なルールは次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

これはやや乱雑です。アーカイブの構造の副産物として、すべての先頭に googletest-release-1.10.0 が付きます。strip_prefix 属性を追加すると、http_archive でこの接頭辞を削除できます。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD は次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

これで、cc_ ルールは @gtest//:main に依存できるようになりました。

C++ テストの作成と実行

たとえば、次のようなテスト用 ./test/hello-test.cc を作成できます。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

次に、テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test に公開するには、./main/BUILD の visibility 属性に "//test:__pkg__", を追加する必要があります。

これで、bazel test を使用してテストを実行できます。

bazel test test:hello-test

出力は次のようになります。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

プリコンパイルされたライブラリへの依存関係の追加

コンパイル済みバージョンのみがあるライブラリ（ヘッダーと .so ファイルなど）を使用する場合は、cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

これにより、ワークスペース内の他の C++ ターゲットがこのルールに依存できます。