การลงทะเบียน BazelCon 2024 เปิดให้ลงทะเบียนแล้วในตอนนี้

หน้านี้ได้รับการแปลโดย Cloud Translation API

การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

รายงานปัญหา ดูแหล่งที่มา รุ่น Nightly · 7.4 7.3 · 7.2 · 7.1 · 7.0 · 6.5

หากคุณเพิ่งเริ่มใช้ Bazel ให้เริ่มจากบทแนะนำการสร้าง Android ด้วย Bazel

ภาพรวม

Bazel ทำงานได้ในการกำหนดค่าการสร้างที่หลากหลาย รวมถึงการกำหนดค่าหลายรายการที่ใช้ชุดเครื่องมือ Native Development Kit (NDK) ของ Android ซึ่งหมายความว่าสามารถคอมไพล์กฎ cc_library และ cc_binary ปกติสําหรับ Android ได้โดยตรงภายใน Bazel Bazel ทําเช่นนี้ได้โดยใช้กฎที่เก็บ android_ndk_repository

ข้อกำหนดเบื้องต้น

โปรดตรวจสอบว่าคุณได้ติดตั้ง Android SDK และ NDK แล้ว

หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

ดูข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository ได้ที่รายการในสารานุกรมของ Build

หากคุณใช้ Android NDK เวอร์ชันล่าสุด (r22 ขึ้นไป) ให้ใช้ Starlark ของ android_ndk_repository ทำตามวิธีการในREADME

การเริ่มใช้งานอย่างง่าย

หากต้องการสร้าง C++ สำหรับ Android ให้เพิ่ม cc_library ลงในกฎ android_binary หรือ android_library

ตัวอย่างเช่น ไฟล์ BUILD ต่อไปนี้สําหรับแอป Android

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้ให้กราฟเป้าหมายดังต่อไปนี้

ตัวอย่างผลการแข่ง

รูปที่ 1 สร้างกราฟของโปรเจ็กต์ Android ที่มี cc_library ที่ต้องพึ่งพา

หากต้องการสร้างแอป ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //app/src/main:app

คำสั่ง bazel build จะคอมไพล์ไฟล์ Java, ไฟล์ทรัพยากร Android และกฎ cc_library รวมถึงแพ็กเกจทุกอย่างเป็น APK

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel จะคอมไพล์ cc_libraries ทั้งหมดเป็นไฟล์ออบเจ็กต์ที่แชร์ (.so) ไฟล์เดียว โดยกำหนดเป้าหมายเป็น armeabi-v7a ABI โดยค่าเริ่มต้น หากต้องการเปลี่ยนหรือสร้างสำหรับ ABI หลายรายการพร้อมกัน โปรดดูส่วนการกำหนดค่า ABI เป้าหมาย

ตัวอย่างการตั้งค่า

ตัวอย่างนี้มีอยู่ในที่เก็บตัวอย่าง Basl

ในไฟล์ BUILD.bazel มีการกำหนดเป้าหมาย 3 รายการด้วยกฎ android_binary, android_library และ cc_library

เป้าหมายระดับบนสุด android_binary จะสร้าง APK

เป้าหมาย cc_library มีไฟล์ซอร์ส C++ ไฟล์เดียวที่มีการใช้งานฟังก์ชัน JNI ดังนี้

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

เป้าหมาย android_library จะระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และการพึ่งพาเป้าหมาย cc_library สำหรับตัวอย่างนี้ MainActivity.java จะโหลดไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นเมธอดสำหรับฟังก์ชัน JNI ดังนี้

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า STL

หากต้องการกำหนดค่า C++ STL ให้ใช้ Flag --android_crosstool_top

bazel build //:app --android_crosstool_top=target label

STL ที่พร้อมใช้งานใน@androidndkมีดังนี้

STL	ป้ายกํากับเป้าหมาย
STLport	`@androidndk//:toolchain-stlport`
libc++	`@androidndk//:toolchain-libcpp`
Gnustl	`@androidndk//:toolchain-gnu-libstdcpp`

STL เริ่มต้นสำหรับ r16 หรือต่ำกว่าคือ gnustl สำหรับ r17 ขึ้นไป จะเป็น libc++ ระบบจะตั้งชื่อแทน @androidndk//:default_crosstool เป้าหมายเป็น STL เริ่มต้นที่เกี่ยวข้องเพื่อความสะดวก

โปรดทราบว่าตั้งแต่ r18 เป็นต้นไป STLport และ gnustl จะถูกนําออก ซึ่งจะทำให้ libc++ เป็น STL เพียงรายการเดียวใน NDK

ดูข้อมูลเพิ่มเติมเกี่ยวกับ STL เหล่านี้ได้ในเอกสารประกอบ NDK

การกำหนดค่า ABI เป้าหมาย

หากต้องการกําหนดค่า ABI เป้าหมาย ให้ใช้ Flag --fat_apk_cpu ดังนี้

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

โดยค่าเริ่มต้น Bazel จะสร้างโค้ด Android ดั้งเดิมสําหรับ armeabi-v7a หากต้องการสร้างสำหรับ x86 (เช่น สำหรับโปรแกรมจำลอง) ให้ผ่าน --fat_apk_cpu=x86 หากต้องการสร้าง APK แบบรวมสำหรับสถาปัตยกรรมหลายรายการ คุณสามารถระบุ CPU หลายรายการได้ --fat_apk_cpu=armeabi-v7a,x86

หากระบุ ABI มากกว่า 1 รายการ Bazel จะสร้าง APK ที่มีออบเจ็กต์ที่แชร์สำหรับ ABI แต่ละรายการ

มี ABI ต่อไปนี้ให้ใช้งาน ทั้งนี้ขึ้นอยู่กับการแก้ไข NDK และระดับ Android API

การแก้ไข NDK	ABI
16 ปีหรือต่ำกว่า	armeabi, armeabi-v7a, arm64-v8a, mips, mips64, x86, x86_64
17 ปีขึ้นไป	armeabi-v7a, arm64-v8a, x86, x86_64

ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสารประกอบ NDK

ไม่แนะนำให้ใช้ APK แบบ Multi-ABI Fat กับบิลด์ที่เผยแพร่เนื่องจากจะเพิ่มขนาดของ APK แต่ก็อาจมีประโยชน์สำหรับบิลด์การพัฒนาและ QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

มาตรฐาน C++	ธง
C++98	ค่าเริ่มต้น ไม่ต้องแจ้ง
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และ Linker ด้วย --cxxopt, --copt และ --linkopt ในคู่มือผู้ใช้

นอกจากนี้ คุณยังระบุ Flag คอมไพเลอร์และ linker เป็นแอตทริบิวต์ใน cc_library ได้โดยใช้ copts และ linkopts เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การผสานรวมกับแพลตฟอร์มและเครื่องมือ

รูปแบบการกําหนดค่าของ Bazel กำลังเปลี่ยนไปใช้แพลตฟอร์มและชุดเครื่องมือ หากบิลด์ใช้ Flag --platforms เพื่อเลือกสถาปัตยกรรมหรือระบบปฏิบัติการที่จะสร้าง คุณจะต้องส่ง Flag --extra_toolchains ไปยัง Bazel เพื่อใช้ NDK

เช่น หากต้องการผสานรวมกับ android_arm64_cgo toolchain ที่กฎ Go มีให้ ให้ส่ง --extra_toolchains=@androidndk//:all เพิ่มเติมจาก Flag --platforms

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

คุณยังลงทะเบียนในไฟล์ WORKSPACE โดยตรงได้ด้วย โดยทำดังนี้

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

การลงทะเบียนเครื่องมือเหล่านี้จะบอกให้ Bazel ค้นหาเครื่องมือเหล่านั้นในBUILDไฟล์ (สำหรับ NDK 20) ของ NDK เมื่อแก้ไขข้อจำกัดด้านสถาปัตยกรรมและระบบปฏิบัติการ

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

วิธีการทำงาน: แนะนำการเปลี่ยนการกำหนดค่า Android

กฎ android_binary สามารถขอให้ Bazel สร้างทรัพยากรที่ต้องพึ่งพาในการกําหนดค่าที่เข้ากันได้กับ Android อย่างชัดเจนเพื่อให้การบิลด์ Bazel ทํางานได้โดยไม่ต้องใช้ Flag พิเศษใดๆ ยกเว้น --fat_apk_cpu และ --android_crosstool_top สําหรับการกําหนดค่า ABI และ STL

การกำหนดค่าอัตโนมัตินี้ใช้การเปลี่ยนการกำหนดค่าของ Android ในเบื้องหลัง

กฎที่เข้ากันได้ เช่น android_binary จะเปลี่ยนการกำหนดค่าของข้อกำหนดเป็นการกำหนดค่า Android โดยอัตโนมัติ ดังนั้นจะมีผลเฉพาะกับซับต้นไม้เฉพาะ Android ของบิลด์เท่านั้น ส่วนอื่นๆ ของกราฟการบิลด์จะประมวลผลโดยใช้การกำหนดค่าเป้าหมายระดับบนสุด และอาจประมวลผลเป้าหมายเดียวในการกําหนดค่าทั้ง 2 แบบได้ หากมีเส้นทางผ่านกราฟการสร้างที่รองรับ

เมื่อ Bazel อยู่ในการกำหนดค่าที่เข้ากันได้กับ Android ซึ่งระบุที่ระดับบนสุดหรือเนื่องจากจุดเปลี่ยนที่ระดับสูงกว่า จุดเปลี่ยนที่พบเพิ่มเติมจะไม่แก้ไขการกำหนดค่าเพิ่มเติม

ตําแหน่งในตัวเพียงแห่งเดียวที่ทริกเกอร์การเปลี่ยนไปใช้การกําหนดค่า Android คือแอตทริบิวต์ deps ของ android_binary

ตัวอย่างเช่น หากพยายามสร้างเป้าหมาย android_library ที่มี cc_library ขึ้นต่อกันโดยไม่มี Flag คุณอาจพบข้อผิดพลาดเกี่ยวกับส่วนหัว JNI ที่ขาดหายไป

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

โดยหลักการแล้ว การเปลี่ยนโดยอัตโนมัติเหล่านี้ควรทําให้ Bazel ทําในสิ่งที่ถูกต้องได้ในกรณีส่วนใหญ่ อย่างไรก็ตาม หากเป้าหมายในบรรทัดคำสั่งของ Bazel อยู่ต่ำกว่ากฎการเปลี่ยนผ่านเหล่านี้อยู่แล้ว เช่น นักพัฒนาซอฟต์แวร์ C++ ที่ทดสอบ cc_library ที่เฉพาะเจาะจง จะต้องใช้ --crosstool_top ที่กําหนดเอง

การสร้าง `cc_library` สำหรับ Android โดยไม่ใช้ `android_binary`

หากต้องการสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ให้ใช้ Flag --crosstool_top, --cpu และ --host_crosstool_top

เช่น

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

ในตัวอย่างนี้ ระบบจะสร้างเป้าหมาย cc_library และ cc_binary ระดับบนสุดโดยใช้ชุดเครื่องมือ NDK อย่างไรก็ตาม การดำเนินการนี้จะทำให้เครื่องมือโฮสต์ของ Bazel เองสร้างขึ้นด้วยชุดเครื่องมือ NDK (และสำหรับ Android) เนื่องจากระบบจะคัดลอกชุดเครื่องมือโฮสต์จากชุดเครื่องมือเป้าหมาย วิธีแก้ปัญหานี้คือ ให้ระบุค่าของ --host_crosstool_top เป็น @bazel_tools//tools/cpp:toolchain เพื่อตั้งค่าชุดเครื่องมือ C++ ของโฮสต์อย่างชัดเจน

แนวทางนี้จะส่งผลต่อทั้งโครงสร้างการบิลด์

คุณใส่ Flag เหล่านี้ลงในการกำหนดค่า bazelrc (1 รายการสำหรับ ABI แต่ละรายการ) ได้ในส่วน project/.bazelrc ดังนี้

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

จากนั้น หากต้องการสร้าง cc_library สำหรับ x86 ตัวอย่างเช่น ให้เรียกใช้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ให้ใช้วิธีการนี้กับเป้าหมายระดับล่าง (เช่น cc_library) หรือเมื่อคุณทราบสิ่งที่กําลังสร้างอย่างชัดเจน ให้ใช้การเปลี่ยนการกำหนดค่าอัตโนมัติจาก android_binary สำหรับเป้าหมายระดับสูงซึ่งคุณคาดว่าจะสร้างเป้าหมายจำนวนมากที่คุณไม่ได้ควบคุม

การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

ภาพรวม

ข้อกำหนดเบื้องต้น

การเริ่มใช้งานอย่างง่าย

ตัวอย่างการตั้งค่า

การกำหนดค่า STL

การกำหนดค่า ABI เป้าหมาย

การเลือกมาตรฐาน C++

การผสานรวมกับแพลตฟอร์มและเครื่องมือ

วิธีการทำงาน: แนะนำการเปลี่ยนการกำหนดค่า Android

การสร้าง cc_library สำหรับ Android โดยไม่ใช้ android_binary

การสร้าง `cc_library` สำหรับ Android โดยไม่ใช้ `android_binary`