このページでは、アスペクトの基本的な使い方とメリットについて説明します。また、簡単な例と高度な例も紹介します。
アスペクトを使用すると、追加情報とアクションを使用してビルド依存関係グラフを拡張できます。アスペクトが役立つ一般的なシナリオは次のとおりです。
- Bazel を統合する IDE では、アスペクトを使用してプロジェクトに関する情報を収集できます。
- コード生成ツールは、アスペクトを活用して、ターゲット非依存の方法で入力を実行できます。たとえば、
BUILDファイルでは protobuf ライブラリ定義の階層を指定できます。また、言語固有のルールでは、アスペクトを使用して、特定の言語の protobuf サポートコードを生成するアクションをアタッチできます。
アスペクトの基本
BUILD ファイルには、プロジェクトのソースコードの説明が含まれます。プロジェクトに含まれるソースファイル、それらのファイルからビルドするアーティファクト（ターゲット）、それらのファイル間の依存関係など。Bazel は、この情報を使用してビルドを実行します。つまり、アーティファクトの実行やコンパイラの実行に必要な一連のアクションを特定します。Bazel は、ターゲット間の依存関係グラフを構築し、このグラフを訪問してアクションを収集することで、この処理を行います。
次の BUILD ファイルについて考えてみましょう。
java_library(name = 'W', ...)
java_library(name = 'Y', deps = [':W'], ...)
java_library(name = 'Z', deps = [':W'], ...)
java_library(name = 'Q', ...)
java_library(name = 'T', deps = [':Q'], ...)
java_library(name = 'X', deps = [':Y',':Z'], runtime_deps = [':T'], ...)
この BUILD ファイルは、次の図に示す依存関係グラフを定義します。
図 1. BUILD ファイルの依存関係グラフ。
Bazel は、上記の例のすべてのターゲットについて、対応するルールの実装関数（この場合は「java_library」）を呼び出して、この依存関係グラフを分析します。ルール実装関数は、アーティファクト（.jar ファイルなど）をビルドするアクションを生成し、それらのアーティファクトの場所や名前などの情報を、プロバイダ内のターゲットのリバース依存関係に渡します。
アスペクトは、アクションを生成してプロバイダを返す実装関数を持つという点でルールと似ています。ただし、その強みは、依存関係グラフが構築される方法にあります。アスペクトには実装と、それとともに伝播されるすべての属性のリストが含まれます。「deps」という名前の属性に沿って伝播するアスペクト A について考えてみましょう。このアスペクトをターゲット X に適用することで、アスペクト アプリケーション ノード A（X）が生成されます。適用時に、アスペクト A は X が「deps」属性で参照するすべてのターゲット（A の伝播リスト内のすべての属性）に再帰的に適用されます。
したがって、アスペクト A をターゲット X に適用する単一のアクションにより、次の図に示すターゲットの元の依存関係グラフの「シャドウグラフ」が生成されます。
図 2. アスペクトを使用してグラフを作成する。
シャドウの対象となるエッジは、伝播セット内の属性に沿ったエッジのみであるため、この例では runtime_deps エッジはシャドウされません。アスペクト実装関数は、元のグラフのノードでルール実装が呼び出されるのと同様に、シャドウグラフ内のすべてのノードで呼び出されます。
簡単な例
この例では、ルールと、deps 属性を持つすべての依存関係のソースファイルを再帰的に出力する方法を示します。アスペクトの実装、アスペクトの定義、Bazel コマンドラインからアスペクトを呼び出す方法が示されています。
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
例をパーツに分解して、それぞれを個別に見てみましょう。
アスペクトの定義
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
アスペクト定義はルール定義と似ており、aspect 関数を使用して定義します。
ルールと同様に、アスペクトには実装関数があります。この場合は _print_aspect_impl です。
attr_aspects は、アスペクトが伝播されるルール属性のリストです。この場合、アスペクトは、適用先のルールの deps 属性に沿って伝播されます。
attr_aspects のもう 1 つの一般的な引数は ['*'] です。これは、アスペクトをルールのすべての属性に伝播します。
Aspect の実装
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
アスペクト実装関数は、ルール実装関数に似ています。プロバイダを返します。アクションを生成できます。2 つの引数を取ります。
実装関数は、ctx.rule.attr を介してターゲット ルールの属性にアクセスできます。適用先のターゲットから提供されるプロバイダを（target 引数を介して）調べることができます。
プロバイダのリストを返すには、アスペクトが必要です。この例では、アスペクトが何も提供しないため、空のリストが返されます。
コマンドラインを使用してアスペクトを呼び出す
アスペクトを適用する最も簡単な方法は、コマンドラインから --aspects 引数を使用することです。上記のアスペクトが print.bzl という名前のファイルに定義されているとします。
bazel build //MyExample:example --aspects print.bzl%print_aspect
print_aspect は、ターゲット example と、deps 属性を介して再帰的にアクセスできるすべてのターゲット ルールに適用されます。
--aspects フラグは 1 つの引数を取ります。これは、<extension file label>%<aspect top-level name> の形式でアスペクトを指定します。
高度な例
次の例では、ターゲット内のファイルをカウントし、拡張子でフィルタリングする可能性があるターゲット ルールのアスペクトを使用しています。プロバイダを使用して値を返す方法、パラメータを使用してアスペクトの実装に引数を渡す方法、ルールからアスペクトを呼び出す方法を示します。
file_count.bzl ファイル:
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
BUILD.bazel ファイル:
load('//:file_count.bzl', 'file_count_rule')
cc_library(
name = 'lib',
srcs = [
'lib.h',
'lib.cc',
],
)
cc_binary(
name = 'app',
srcs = [
'app.h',
'app.cc',
'main.cc',
],
deps = ['lib'],
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
アスペクトの定義
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
この例は、アスペクトが deps 属性を介してどのように伝播するかを示しています。
attrs はアスペクトの属性のセットを定義します。パブリック アスペクト属性はパラメータを定義します。この属性は bool、int、string のいずれかのタイプにすることができます。ルールが伝播されるアスペクトの場合、int パラメータと string パラメータには values を指定する必要があります。この例には、値として「*」、「h」、「cc」を指定できる extension というパラメータがあります。
ルールが伝播されるアスペクトの場合、パラメータ値は、同じ名前とタイプを持つルールの属性を使用して、アスペクトをリクエストするルールから取得されます。（file_count_rule の定義を参照）。
コマンドライン アスペクトの場合、パラメータ値は --aspects_parameters フラグを使用して渡すことができます。int パラメータと string パラメータの values 制限は省略できます。
アスペクトには、label 型または label_list 型のプライベート属性を含めることもできます。非公開ラベル属性を使用すると、アスペクトによって生成されたアクションに必要なツールやライブラリへの依存関係を指定できます。このサンプルでは非公開属性が定義されていませんが、次のコード スニペットは、ツールをアスペクトに渡す方法を示しています。
...
attrs = {
'_protoc' : attr.label(
default = Label('//tools:protoc'),
executable = True,
cfg = "exec"
)
}
...
Aspect の実装
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
ルール実装関数と同様に、アスペクト実装関数は依存関係にアクセスできるプロバイダの構造体を返します。
この例では、1 つのフィールド count を持つプロバイダとして FileCountInfo が定義されています。fields 属性を使用してプロバイダのフィールドを明示的に定義することをおすすめします。
アスペクト アプリケーション A(X) のプロバイダのセットとは、ターゲット X のルールの実装とアスペクト A の実装から得られるプロバイダの集合です。ルールの実装が伝播するプロバイダは、アスペクトが適用される前に作成および固定され、アスペクトから変更することはできません。ターゲットとそれに適用されるアスペクトがそれぞれ同じタイプのプロバイダを提供している場合、エラーになります。ただし、OutputGroupInfo（ルールとアスペクトで異なる出力グループが指定されている限り、マージされます）と InstrumentedFilesInfo（アスペクトから取得されます）は例外です。つまり、アスペクト実装が DefaultInfo を返すことはありません。
パラメータと非公開属性は ctx の属性で渡されます。この例では、extension パラメータを参照して、カウントするファイルを決定します。
返されるプロバイダの場合、アスペクトが伝播される属性の値（attr_aspects リストから）は、アスペクトの適用結果に置き換えられます。たとえば、ターゲット X の依存関係に Y と Z がある場合、A(X) の ctx.rule.attr.deps は [A(Y), A(Z)] になります。この例の ctx.rule.attr.deps は、アスペクトが適用された元のターゲットの「依存関係」にアスペクトを適用した結果であるターゲット オブジェクトです。
この例では、アスペクトはターゲットの依存関係から FileCountInfo プロバイダにアクセスし、一時的なファイルの総数を蓄積します。
ルールからアスペクトを呼び出す
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
ルールの実装は、ctx.attr.deps を介して FileCountInfo にアクセスする方法を示しています。
ルール定義は、パラメータ（extension）を定義し、デフォルト値（*）を指定する方法を示しています。「cc」、「h」、「*」のいずれでもないデフォルト値を指定すると、アスペクト定義のパラメータに制限が設定されているためエラーになります。
ターゲット ルールを介してアスペクトを呼び出す
load('//:file_count.bzl', 'file_count_rule')
cc_binary(
name = 'app',
...
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
これは、ルールを介して extension パラメータをアスペクトに渡す方法を示しています。extension パラメータにはルールの実装でデフォルト値があるため、extension はオプション パラメータと見なされます。
file_count ターゲットが作成されると、アスペクト自体が評価され、すべてのターゲットに deps を介して再帰的にアクセスできるようになります。