Nền tảng

Báo cáo vấn đề Xem nguồn Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

Bazel có thể tạo và kiểm thử mã trên nhiều loại phần cứng, hệ điều hành và cấu hình hệ thống, bằng cách sử dụng nhiều phiên bản công cụ tạo như trình liên kết và trình biên dịch. Để giúp quản lý sự phức tạp này, Bazel có khái niệm về các ràng buộc và nền tảng. Ràng buộc là một phương diện mà môi trường bản dựng hoặc môi trường sản xuất có thể khác nhau, chẳng hạn như cấu trúc CPU, sự hiện diện hoặc vắng mặt của GPU hoặc phiên bản của trình biên dịch do hệ thống cài đặt. Nền tảng là một tập hợp các lựa chọn được đặt tên cho những ràng buộc này, thể hiện các tài nguyên cụ thể có sẵn trong một số môi trường.

Việc mô hình hoá môi trường dưới dạng một nền tảng giúp Bazel tự động chọn chuỗi công cụ thích hợp cho các thao tác xây dựng. Bạn cũng có thể kết hợp các nền tảng với quy tắc config_setting để ghi các thuộc tính có thể định cấu hình.

Bazel nhận ra 3 vai trò mà một nền tảng có thể đảm nhận:

  • Máy chủ – nền tảng mà chính Bazel chạy trên đó.
  • Thực thi – một nền tảng mà trên đó các công cụ tạo thực thi các thao tác tạo để tạo ra các đầu ra trung gian và đầu ra cuối cùng.
  • Mục tiêu – một nền tảng mà đầu ra cuối cùng sẽ nằm và thực thi.

Bazel hỗ trợ các trường hợp xây dựng sau đây liên quan đến nền tảng:

  • Bản dựng một nền tảng (mặc định) – nền tảng lưu trữ, thực thi và mục tiêu đều giống nhau. Ví dụ: tạo một tệp thực thi Linux trên Ubuntu chạy trên CPU Intel x64.

  • Bản dựng biên dịch chéo – nền tảng lưu trữ và thực thi giống nhau, nhưng nền tảng đích khác nhau. Ví dụ: tạo một ứng dụng iOS trên macOS chạy trên MacBook Pro.

  • Bản dựng đa nền tảng – nền tảng lưu trữ, thực thi và mục tiêu đều khác nhau.

Xác định các quy tắc ràng buộc và nền tảng

Không gian của các lựa chọn có thể có cho nền tảng được xác định bằng cách sử dụng các quy tắc constraint_setting và constraint_value trong các tệp BUILD. constraint_setting tạo một phương diện mới, trong khi constraint_value tạo một giá trị mới cho một phương diện nhất định; cùng nhau, chúng xác định hiệu quả một enum và các giá trị có thể có của enum đó. Ví dụ: đoạn mã sau đây của tệp BUILD giới thiệu một ràng buộc cho phiên bản glibc của hệ thống với 2 giá trị có thể có.

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

Bạn có thể xác định các ràng buộc và giá trị của chúng trên nhiều gói trong không gian làm việc. Chúng được tham chiếu theo nhãn và chịu sự kiểm soát thông thường về khả năng hiển thị. Nếu chế độ hiển thị cho phép, bạn có thể mở rộng chế độ cài đặt ràng buộc hiện có bằng cách xác định giá trị của riêng bạn cho chế độ cài đặt đó.

Quy tắc platform giới thiệu một nền tảng mới với một số lựa chọn về giá trị ràng buộc. Sau đây là cách tạo một nền tảng có tên là linux_x86 và cho biết nền tảng này mô tả mọi môi trường chạy hệ điều hành Linux trên một cấu trúc x86_64 có phiên bản glibc là 2.25. (Xem phần bên dưới để biết thêm về các ràng buộc tích hợp của Bazel.)

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

Các ràng buộc và nền tảng thường hữu ích

Để duy trì tính nhất quán của hệ sinh thái, nhóm Bazel duy trì một kho lưu trữ với các định nghĩa về ràng buộc cho những cấu trúc CPU và hệ điều hành phổ biến nhất. Tất cả đều nằm trong https://github.com/bazelbuild/platforms.

Bazel đi kèm với định nghĩa nền tảng đặc biệt sau: @local_config_platform//:host. Đây là giá trị nền tảng máy chủ được tự động phát hiện – biểu thị nền tảng được tự động phát hiện cho hệ thống mà Bazel đang chạy.

Chỉ định nền tảng cho bản dựng

Bạn có thể chỉ định nền tảng đích và nền tảng lưu trữ cho một bản dựng bằng các cờ dòng lệnh sau:

  • --host_platform – mặc định là @local_config_platform//:host
    • @local_config_platform là một quy tắc kho lưu trữ phát hiện hệ điều hành và CPU của máy chủ, đồng thời ghi mục tiêu nền tảng.
    • Thao tác này cũng tạo ra @local_config_platform//:constraintz.bzl, cho phép hiển thị một mảng có tên là HOST_CONSTRAINTS. Mảng này có thể được dùng trong các tệp BUILD và Starlark khác.
  • --platforms – mặc định là nền tảng lưu trữ
    • Điều này có nghĩa là khi không có cờ nào khác được đặt, @local_config_platform//:host là nền tảng mục tiêu.
    • Nếu bạn đặt --host_platform nhưng không đặt --platforms, thì giá trị của --host_platform sẽ là cả nền tảng lưu trữ và nền tảng mục tiêu.

Bỏ qua các mục tiêu không tương thích

Khi tạo cho một nền tảng mục tiêu cụ thể, bạn nên bỏ qua những mục tiêu sẽ không bao giờ hoạt động trên nền tảng đó. Ví dụ: trình điều khiển thiết bị Windows của bạn có thể sẽ tạo ra nhiều lỗi trình biên dịch khi tạo trên máy Linux bằng //.... Sử dụng thuộc tính target_compatible_with để cho Bazel biết những ràng buộc về nền tảng mục tiêu mà mã của bạn có.

Cách sử dụng đơn giản nhất của thuộc tính này là hạn chế một mục tiêu cho một nền tảng duy nhất. Mục tiêu sẽ không được tạo cho bất kỳ nền tảng nào không đáp ứng tất cả các ràng buộc. Ví dụ sau đây hạn chế win_driver_lib.cc đối với Windows 64 bit.

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib chỉ tương thích với việc tạo bằng Windows 64 bit và không tương thích với mọi thứ khác. Tính không tương thích là tính chất bắc cầu. Mọi mục tiêu phụ thuộc gián tiếp vào một mục tiêu không tương thích đều được coi là không tương thích.

Khi nào mục tiêu bị bỏ qua?

Các mục tiêu sẽ bị bỏ qua khi được coi là không tương thích và được đưa vào bản dựng như một phần của quá trình mở rộng mẫu mục tiêu. Ví dụ: hai lệnh gọi sau đây sẽ bỏ qua mọi mục tiêu không tương thích được tìm thấy trong quá trình mở rộng mẫu mục tiêu.

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

Các kiểm thử không tương thích trong test_suite cũng sẽ bị bỏ qua nếu test_suite được chỉ định trên dòng lệnh bằng --expand_test_suites. Nói cách khác, các mục tiêu test_suite trên dòng lệnh hoạt động giống như :all và .... Việc sử dụng --noexpand_test_suites sẽ ngăn chặn việc mở rộng và khiến các mục tiêu test_suite có các kiểm thử không tương thích cũng không tương thích.

Việc chỉ định rõ ràng một mục tiêu không tương thích trên dòng lệnh sẽ dẫn đến thông báo lỗi và bản dựng không thành công.

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

Các mục tiêu rõ ràng không tương thích sẽ bị bỏ qua một cách âm thầm nếu bạn bật --skip_incompatible_explicit_targets.

Các ràng buộc biểu cảm hơn

Để linh hoạt hơn trong việc thể hiện các quy tắc ràng buộc, hãy dùng @platforms//:incompatible constraint_value mà không nền tảng nào đáp ứng.

Sử dụng select() kết hợp với @platforms//:incompatible để thể hiện các hạn chế phức tạp hơn. Ví dụ: sử dụng nó để triển khai logic OR cơ bản. Sau đây đánh dấu một thư viện tương thích với macOS và Linux, nhưng không tương thích với các nền tảng khác.

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

Bạn có thể diễn giải thông tin trên như sau:

  1. Khi nhắm đến macOS, mục tiêu không có các ràng buộc.
  2. Khi nhắm đến Linux, mục tiêu không có các ràng buộc.
  3. Nếu không, đích đến sẽ có quy tắc ràng buộc @platforms//:incompatible. Vì @platforms//:incompatible không thuộc bất kỳ nền tảng nào, nên mục tiêu được coi là không tương thích.

Để giúp các điều kiện ràng buộc của bạn dễ đọc hơn, hãy sử dụng selects.with_or() của skylib.

Bạn có thể biểu thị khả năng tương thích nghịch đảo theo cách tương tự. Ví dụ sau đây mô tả một thư viện tương thích với mọi thứ ngoại trừ ARM.

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

Phát hiện các mục tiêu không tương thích bằng cách sử dụng bazel cquery

Bạn có thể sử dụng IncompatiblePlatformProvider trong định dạng đầu ra Starlark của bazel cquery để phân biệt các mục tiêu không tương thích với các mục tiêu tương thích.

Bạn có thể dùng tính năng này để lọc ra các mục tiêu không tương thích. Ví dụ dưới đây sẽ chỉ in nhãn cho các mục tiêu tương thích. Các mục tiêu không tương thích sẽ không được in.

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

Vấn đề đã biết

Các mục tiêu không tương thích bỏ qua các hạn chế về khả năng hiển thị.